integration-test/src/test/groovy/org/onap/cps/integration/performance/cps/WritePerfTest.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023-2024 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the 'License');
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an 'AS IS' BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.integration.performance.cps
  22
  23 import java.time.OffsetDateTime
  24 import org.onap.cps.integration.performance.base.CpsPerfTestBase
  25
  26 class WritePerfTest extends CpsPerfTestBase {
  27
  28     static final def WRITE_TEST_ANCHOR = 'writeTestAnchor'
  29
  30     def 'Writing openroadm data has linear time.'() {
  31         given: 'an empty anchor exists for openroadm'
  32             cpsAnchorService.createAnchor(CPS_PERFORMANCE_TEST_DATASPACE, LARGE_SCHEMA_SET, WRITE_TEST_ANCHOR)
  33         and: 'a list of device nodes to add'
  34             def jsonData = generateOpenRoadData(totalNodes)
  35         when: 'device nodes are added'
  36             resourceMeter.start()
  37             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR, jsonData, OffsetDateTime.now())
  38             resourceMeter.stop()
  39         then: 'the operation takes less than #expectedDuration and memory used is within limit'
  40             recordAndAssertResourceUsage("Writing ${totalNodes} devices",
  41                     expectedDuration, resourceMeter.getTotalTimeInSeconds(),
  42                     memoryLimit, resourceMeter.getTotalMemoryUsageInMB())
  43         cleanup:
  44             cpsAnchorService.deleteAnchor(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR)
  45         where:
  46             totalNodes || expectedDuration | memoryLimit
  47             50         || 2                | 100
  48             100        || 4                | 200
  49             200        || 7                | 400
  50             400        || 14               | 500
  51     }
  52
  53     def 'Writing bookstore data has exponential time.'() {
  54         given: 'an anchor containing a bookstore with a single category'
  55             cpsAnchorService.createAnchor(CPS_PERFORMANCE_TEST_DATASPACE, BOOKSTORE_SCHEMA_SET, WRITE_TEST_ANCHOR)
  56             def parentNodeData = '{"bookstore": { "categories": [{ "code": 1, "name": "Test", "books" : [] }] }}'
  57             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR, parentNodeData, OffsetDateTime.now())
  58         and: 'a list of books to add'
  59             def booksData = '{"books":[' + (1..totalBooks).collect {'{ "title": "' + it + '" }' }.join(',') + ']}'
  60         when: 'books are added'
  61             resourceMeter.start()
  62             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR, '/bookstore/categories[@code=1]', booksData, OffsetDateTime.now())
  63             resourceMeter.stop()
  64         then: 'the operation takes less than #expectedDuration and memory used is within limit'
  65             recordAndAssertResourceUsage("Writing ${totalBooks} books",
  66                     expectedDuration, resourceMeter.totalTimeInSeconds,
  67                     memoryLimit, resourceMeter.totalMemoryUsageInMB)
  68         cleanup:
  69             cpsAnchorService.deleteAnchor(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR)
  70         where:
  71             totalBooks || expectedDuration | memoryLimit
  72             800        || 0.5              | 50
  73             1600       || 1.5              | 100
  74             3200       || 6.0              | 150
  75             6400       || 18.0             | 200
  76     }
  77
  78     def 'Writing openroadm list data using saveListElements.'() {
  79         given: 'an anchor and empty container node for openroadm'
  80             cpsAnchorService.createAnchor(CPS_PERFORMANCE_TEST_DATASPACE, LARGE_SCHEMA_SET, WRITE_TEST_ANCHOR)
  81             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR,
  82                     '{ "openroadm-devices": { "openroadm-device": []}}', now)
  83         and: 'a list of device nodes to add'
  84             def innerNode = readResourceDataFile('openroadm/innerNode.json')
  85             def jsonListData = '{ "openroadm-device": [' +
  86                     (1..totalNodes).collect { innerNode.replace('NODE_ID_HERE', it.toString()) }.join(',') +
  87                     ']}'
  88         when: 'device nodes are added'
  89             resourceMeter.start()
  90             cpsDataService.saveListElements(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR, '/openroadm-devices', jsonListData, OffsetDateTime.now())
  91             resourceMeter.stop()
  92         then: 'the operation takes less than #expectedDuration and memory used is within limit'
  93             recordAndAssertResourceUsage("Saving list of ${totalNodes} devices",
  94                     expectedDuration, resourceMeter.totalTimeInSeconds,
  95                     memoryLimit, resourceMeter.totalMemoryUsageInMB)
  96         cleanup:
  97             cpsAnchorService.deleteAnchor(CPS_PERFORMANCE_TEST_DATASPACE, WRITE_TEST_ANCHOR)
  98         where:
  99             totalNodes || expectedDuration | memoryLimit
 100             50         || 2                | 100
 101             100        || 4                | 200
 102             200        || 7                | 400
 103             400        || 14               | 500
 104     }
 105
 106 }