cps-service/src/test/groovy/org/onap/cps/notification/NotificationServiceSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (c) 2021 Bell Canada.
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *         http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.notification
  22
  23 import java.time.OffsetDateTime
  24 import org.onap.cps.config.AsyncConfig
  25 import org.onap.cps.event.model.CpsDataUpdatedEvent
  26 import org.spockframework.spring.SpringBean
  27 import org.spockframework.spring.SpringSpy
  28 import org.springframework.beans.factory.annotation.Autowired
  29 import org.springframework.boot.context.properties.EnableConfigurationProperties
  30 import org.springframework.boot.test.context.SpringBootTest
  31 import org.springframework.scheduling.annotation.EnableAsync
  32 import org.springframework.test.context.ContextConfiguration
  33 import spock.lang.Shared
  34 import spock.lang.Specification
  35
  36 import java.util.concurrent.TimeUnit
  37
  38 @SpringBootTest
  39 @EnableConfigurationProperties
  40 @ContextConfiguration(classes = [NotificationProperties, NotificationService, NotificationErrorHandler, AsyncConfig])
  41 class NotificationServiceSpec extends Specification {
  42
  43     @SpringBean
  44     NotificationPublisher mockNotificationPublisher = Mock()
  45     @SpringBean
  46     CpsDataUpdatedEventFactory mockCpsDataUpdatedEventFactory = Mock()
  47     @SpringSpy
  48     NotificationErrorHandler spyNotificationErrorHandler
  49     @SpringSpy
  50     NotificationProperties spyNotificationProperties
  51
  52     @Autowired
  53     NotificationService objectUnderTest
  54
  55     @Shared
  56     def myDataspacePublishedName = 'my-dataspace-published'
  57     def myAnchorName = 'my-anchorname'
  58     def myObservedTimestamp = OffsetDateTime.now()
  59
  60     def 'Skip sending notification when disabled.'() {
  61         given: 'notification is disabled'
  62             spyNotificationProperties.isEnabled() >> false
  63         when: 'dataUpdatedEvent is received'
  64             objectUnderTest.processDataUpdatedEvent(myDataspacePublishedName, myAnchorName, myObservedTimestamp)
  65         then: 'the notification is not sent'
  66             0 * mockNotificationPublisher.sendNotification(_)
  67     }
  68
  69     def 'Send notification when enabled: #scenario.'() {
  70         given: 'notification is enabled'
  71             spyNotificationProperties.isEnabled() >> true
  72         and: 'event factory can create event successfully'
  73             def cpsDataUpdatedEvent = new CpsDataUpdatedEvent()
  74             mockCpsDataUpdatedEventFactory.createCpsDataUpdatedEvent(dataspaceName, myAnchorName, myObservedTimestamp) >>
  75                 cpsDataUpdatedEvent
  76         when: 'dataUpdatedEvent is received'
  77             def future = objectUnderTest.processDataUpdatedEvent(dataspaceName, myAnchorName, myObservedTimestamp)
  78         and: 'wait for async processing to complete'
  79             future.get(10, TimeUnit.SECONDS)
  80         then: 'async process completed successfully'
  81             future.isDone()
  82         and: 'notification is sent'
  83             expectedSendNotificationCount * mockNotificationPublisher.sendNotification(cpsDataUpdatedEvent)
  84         where:
  85             scenario                               | dataspaceName            || expectedSendNotificationCount
  86             'dataspace name does not match filter' | 'does-not-match-pattern' || 0
  87             'dataspace name matches filter'        | myDataspacePublishedName || 1
  88     }
  89
  90     def 'Error handling in notification service.'() {
  91         given: 'notification is enabled'
  92             spyNotificationProperties.isEnabled() >> true
  93         and: 'event factory can not create event successfully'
  94             mockCpsDataUpdatedEventFactory.createCpsDataUpdatedEvent(myDataspacePublishedName, myAnchorName, myObservedTimestamp) >>
  95                 { throw new Exception("Could not create event") }
  96         when: 'event is sent for processing'
  97             def future = objectUnderTest.processDataUpdatedEvent(myDataspacePublishedName, myAnchorName, myObservedTimestamp)
  98         and: 'wait for async processing to complete'
  99             future.get(10, TimeUnit.SECONDS)
 100         then: 'async process completed successfully'
 101             future.isDone()
 102         and: 'error is handled and not thrown to caller'
 103             notThrown Exception
 104             1 * spyNotificationErrorHandler.onException(_, _, _, _)
 105     }
 106
 107 }