cps-rest/src/test/groovy/org/onap/cps/rest/exceptions/CpsRestExceptionHandlerSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (C) 2020 Pantheon.tech
   4  *  Copyright (C) 2021 Nordix Foundation
   5  *  Modifications Copyright (C) 2021 Bell Canada.
   6  *  ================================================================================
   7  *  Licensed under the Apache License, Version 2.0 (the "License");
   8  *  you may not use this file except in compliance with the License.
   9  *  You may obtain a copy of the License at
  10  *
  11  *        http://www.apache.org/licenses/LICENSE-2.0
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.rest.exceptions
  23
  24 import static org.springframework.http.HttpStatus.BAD_REQUEST
  25 import static org.springframework.http.HttpStatus.CONFLICT
  26 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  27 import static org.springframework.http.HttpStatus.NOT_FOUND
  28 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  29
  30 import groovy.json.JsonSlurper
  31 import org.modelmapper.ModelMapper
  32 import org.onap.cps.api.CpsAdminService
  33 import org.onap.cps.api.CpsDataService
  34 import org.onap.cps.api.CpsModuleService
  35 import org.onap.cps.api.CpsQueryService
  36 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  37 import org.onap.cps.spi.exceptions.CpsException
  38 import org.onap.cps.spi.exceptions.CpsPathException
  39 import org.onap.cps.spi.exceptions.DataInUseException
  40 import org.onap.cps.spi.exceptions.DataValidationException
  41 import org.onap.cps.spi.exceptions.ModelValidationException
  42 import org.onap.cps.spi.exceptions.NotFoundInDataspaceException
  43 import org.onap.cps.spi.exceptions.SchemaSetInUseException
  44 import org.spockframework.spring.SpringBean
  45 import org.springframework.beans.factory.annotation.Autowired
  46 import org.springframework.beans.factory.annotation.Value
  47 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  48 import org.springframework.test.web.servlet.MockMvc
  49 import spock.lang.Shared
  50 import spock.lang.Specification
  51 import spock.lang.Unroll
  52
  53 @WebMvcTest
  54 class CpsRestExceptionHandlerSpec extends Specification {
  55
  56     @SpringBean
  57     CpsAdminService mockCpsAdminService = Mock()
  58
  59     @SpringBean
  60     CpsModuleService mockCpsModuleService = Mock()
  61
  62     @SpringBean
  63     CpsDataService mockCpsDataService = Mock()
  64
  65     @SpringBean
  66     CpsQueryService mockCpsQueryService = Mock()
  67
  68     @SpringBean
  69     ModelMapper modelMapper = Mock()
  70
  71     @Autowired
  72     MockMvc mvc
  73
  74     @Value('${rest.api.cps-base-path}')
  75     def basePath
  76
  77     @Shared
  78     def errorMessage = 'some error message'
  79     @Shared
  80     def errorDetails = 'some error details'
  81     @Shared
  82     def dataspaceName = 'MyDataSpace'
  83     @Shared
  84     def existingObjectName = 'MyAdminObject'
  85
  86
  87     def 'Get request with runtime exception returns HTTP Status Internal Server Error'() {
  88         when: 'runtime exception is thrown by the service'
  89             setupTestException(new IllegalStateException(errorMessage))
  90             def response = performTestRequest()
  91         then: 'an HTTP Internal Server Error response is returned with correct message and details'
  92             assertTestResponse(response, INTERNAL_SERVER_ERROR, errorMessage, null)
  93     }
  94
  95     def 'Get request with generic CPS exception returns HTTP Status Internal Server Error'() {
  96         when: 'generic CPS exception is thrown by the service'
  97             setupTestException(new CpsException(errorMessage, errorDetails))
  98             def response = performTestRequest()
  99         then: 'an HTTP Internal Server Error response is returned with correct message and details'
 100             assertTestResponse(response, INTERNAL_SERVER_ERROR, errorMessage, errorDetails)
 101     }
 102
 103     def 'Get request with no data found CPS exception returns HTTP Status Not Found'() {
 104         when: 'no data found CPS exception is thrown by the service'
 105             def dataspaceName = 'MyDataSpace'
 106             def descriptionOfObject = 'Description'
 107             setupTestException(new NotFoundInDataspaceException(dataspaceName, descriptionOfObject))
 108             def response = performTestRequest()
 109         then: 'an HTTP Not Found response is returned with correct message and details'
 110             assertTestResponse(response, NOT_FOUND, 'Object not found',
 111                     'Description does not exist in dataspace MyDataSpace.')
 112     }
 113
 114     def 'Request with an object already defined exception returns HTTP Status Conflict.'() {
 115         when: 'AlreadyDefinedException exception is thrown by the service'
 116             setupTestException(new AlreadyDefinedException("Anchor", existingObjectName, dataspaceName, new Throwable()))
 117             def response = performTestRequest()
 118         then: 'a HTTP conflict response is returned with correct message an details'
 119             assertTestResponse(response, CONFLICT,
 120                     "Already defined exception",
 121                     "Anchor with name ${existingObjectName} already exists for ${dataspaceName}.")
 122     }
 123
 124     @Unroll
 125     def 'Get request with a #exceptionThrown.class.simpleName returns HTTP Status Bad Request'() {
 126         when: 'CPS validation exception is thrown by the service'
 127             setupTestException(exceptionThrown)
 128             def response = performTestRequest()
 129         then: 'an HTTP Bad Request response is returned with correct message and details'
 130             assertTestResponse(response, BAD_REQUEST, errorMessage, errorDetails)
 131         where: 'the following exceptions are thrown'
 132             exceptionThrown << [new ModelValidationException(errorMessage, errorDetails, null),
 133                                 new DataValidationException(errorMessage, errorDetails, null),
 134                                 new CpsPathException(errorMessage, errorDetails)]
 135     }
 136
 137     @Unroll
 138     def 'Delete request with a #exceptionThrown.class.simpleName returns HTTP Status Conflict'() {
 139         when: 'CPS validation exception is thrown by the service'
 140             setupTestException(exceptionThrown)
 141             def response = performTestRequest()
 142         then: 'an HTTP Conflict response is returned with correct message and details'
 143             assertTestResponse(response, CONFLICT, exceptionThrown.getMessage(), exceptionThrown.getDetails())
 144         where: 'the following exceptions are thrown'
 145             exceptionThrown << [new DataInUseException(dataspaceName, existingObjectName),
 146                                 new SchemaSetInUseException(dataspaceName, existingObjectName)]
 147     }
 148
 149     /*
 150      * NB. The test uses 'get anchors' endpoint and associated service method invocation
 151      * to test the exception handling. The endpoint chosen is not a subject of test.
 152      */
 153     def setupTestException(exception) {
 154         mockCpsAdminService.getAnchors(_) >> { throw exception }
 155     }
 156
 157     def performTestRequest() {
 158         return mvc.perform(
 159                 get("$basePath/v1/dataspaces/dataspace-name/anchors"))
 160                 .andReturn().response
 161     }
 162
 163     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 164         assert response.status == expectedStatus.value()
 165         def content = new JsonSlurper().parseText(response.contentAsString)
 166         assert content['status'] == expectedStatus.toString()
 167         assert content['message'] == expectedErrorMessage
 168         assert expectedErrorDetails == null || content['details'] == expectedErrorDetails
 169     }
 170 }