cps-rest/src/test/groovy/org/onap/cps/rest/controller/AdminRestControllerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2020 Pantheon.tech
   4  *  Modifications Copyright (C) 2020, 2021 Bell Canada. All rights reserved.
   5  *  Copyright (C) 2021 Nordix Foundation
   6  *  ================================================================================
   7  *  Licensed under the Apache License, Version 2.0 (the "License");
   8  *  you may not use this file except in compliance with the License.
   9  *  You may obtain a copy of the License at
  10  *
  11  *        http://www.apache.org/licenses/LICENSE-2.0
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.rest.controller
  23
  24 import static org.onap.cps.spi.CascadeDeleteAllowed.CASCADE_DELETE_PROHIBITED
  25 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.delete
  26 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  27 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.multipart
  28 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  29
  30 import org.modelmapper.ModelMapper
  31 import org.onap.cps.api.CpsAdminService
  32 import org.onap.cps.api.CpsDataService
  33 import org.onap.cps.api.CpsModuleService
  34 import org.onap.cps.api.CpsQueryService
  35 import org.onap.cps.spi.exceptions.DataspaceAlreadyDefinedException
  36 import org.onap.cps.spi.exceptions.SchemaSetInUseException
  37 import org.onap.cps.spi.model.Anchor
  38 import org.onap.cps.spi.model.SchemaSet
  39 import org.spockframework.spring.SpringBean
  40 import org.springframework.beans.factory.annotation.Autowired
  41 import org.springframework.beans.factory.annotation.Value
  42 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  43 import org.springframework.http.HttpStatus
  44 import org.springframework.http.MediaType
  45 import org.springframework.mock.web.MockMultipartFile
  46 import org.springframework.test.web.servlet.MockMvc
  47 import org.springframework.util.LinkedMultiValueMap
  48 import org.springframework.util.MultiValueMap
  49 import spock.lang.Specification
  50 import spock.lang.Unroll
  51
  52 @WebMvcTest
  53 class AdminRestControllerSpec extends Specification {
  54
  55     @SpringBean
  56     CpsModuleService mockCpsModuleService = Mock()
  57
  58     @SpringBean
  59     CpsAdminService mockCpsAdminService = Mock()
  60
  61     @SpringBean
  62     CpsDataService mockCpsDataService = Mock()
  63
  64     @SpringBean
  65     CpsQueryService mockCpsQueryService = Mock()
  66
  67     @SpringBean
  68     ModelMapper modelMapper = Mock()
  69
  70     @Autowired
  71     MockMvc mvc
  72
  73     @Value('${rest.api.cps-base-path}')
  74     def basePath
  75
  76     def dataspaceName = 'my_dataspace'
  77     def anchor = new Anchor(name: 'my_anchor')
  78     def anchorList = [anchor]
  79     def anchorName = 'my_anchor'
  80     def schemaSetName = 'my_schema_set'
  81
  82     def 'Create new dataspace.'() {
  83         given: 'an endpoint'
  84             def createDataspaceEndpoint = "$basePath/v1/dataspaces";
  85         when: 'post is invoked'
  86             def response =
  87                     mvc.perform(
  88                             post(createDataspaceEndpoint)
  89                                     .param('dataspace-name', dataspaceName))
  90                             .andReturn().response
  91         then: 'service method is invoked with expected parameters'
  92             1 * mockCpsAdminService.createDataspace(dataspaceName)
  93         and: 'dataspace is create successfully'
  94             response.status == HttpStatus.CREATED.value()
  95     }
  96
  97     def 'Create dataspace over existing with same name.'() {
  98         given: 'an endpoint'
  99             def createDataspaceEndpoint = "$basePath/v1/dataspaces";
 100         and: 'the service method throws an exception indicating the dataspace is already defined'
 101             def thrownException = new DataspaceAlreadyDefinedException("", new RuntimeException())
 102             mockCpsAdminService.createDataspace(dataspaceName) >> { throw thrownException }
 103         when: 'post is invoked'
 104             def response =
 105                     mvc.perform(
 106                             post(createDataspaceEndpoint)
 107                                     .param('dataspace-name', dataspaceName))
 108                             .andReturn().response
 109         then: 'dataspace creation fails'
 110             response.status == HttpStatus.BAD_REQUEST.value()
 111     }
 112
 113     def 'Create schema set from yang file.'() {
 114         def yangResourceMapCapture
 115         given: 'single yang file'
 116             def multipartFile = createMultipartFile("filename.yang", "content")
 117         and: 'an endpoint'
 118             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets"
 119         when: 'file uploaded with schema set create request'
 120             def response =
 121                     mvc.perform(
 122                             multipart(schemaSetEndpoint)
 123                                     .file(multipartFile)
 124                                     .param('schema-set-name', schemaSetName))
 125                             .andReturn().response
 126         then: 'associated service method is invoked with expected parameters'
 127             1 * mockCpsModuleService.createSchemaSet(dataspaceName, schemaSetName, _) >>
 128                     { args -> yangResourceMapCapture = args[2] }
 129             yangResourceMapCapture['filename.yang'] == 'content'
 130         and: 'response code indicates success'
 131             response.status == HttpStatus.CREATED.value()
 132     }
 133
 134     def 'Create schema set from zip archive.'() {
 135         def yangResourceMapCapture
 136         given: 'zip archive with multiple .yang files inside'
 137             def multipartFile = createZipMultipartFileFromResource("/yang-files-set.zip")
 138         and: 'an endpoint'
 139             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets"
 140         when: 'file uploaded with schema set create request'
 141             def response =
 142                     mvc.perform(
 143                             multipart(schemaSetEndpoint)
 144                                     .file(multipartFile)
 145                                     .param('schema-set-name', schemaSetName))
 146                             .andReturn().response
 147         then: 'associated service method is invoked with expected parameters'
 148             1 * mockCpsModuleService.createSchemaSet(dataspaceName, schemaSetName, _) >>
 149                     { args -> yangResourceMapCapture = args[2] }
 150             yangResourceMapCapture['assembly.yang'] == "fake assembly content 1\n"
 151             yangResourceMapCapture['component.yang'] == "fake component content 1\n"
 152         and: 'response code indicates success'
 153             response.status == HttpStatus.CREATED.value()
 154     }
 155
 156     @Unroll
 157     def 'Create schema set from zip archive having #caseDescriptor.'() {
 158         given: 'an endpoint'
 159             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets"
 160         when: 'zip archive having #caseDescriptor is uploaded with create schema set request'
 161             def response =
 162                     mvc.perform(
 163                             multipart(schemaSetEndpoint)
 164                                     .file(multipartFile)
 165                                     .param('schema-set-name', schemaSetName))
 166                             .andReturn().response
 167         then: 'create schema set rejected'
 168             response.status == HttpStatus.BAD_REQUEST.value()
 169         where: 'following cases are tested'
 170             caseDescriptor                        | multipartFile
 171             'no .yang files inside'               | createZipMultipartFileFromResource("/no-yang-files.zip")
 172             'multiple .yang files with same name' | createZipMultipartFileFromResource("/yang-files-multiple-sets.zip")
 173     }
 174
 175     def 'Create schema set from file with unsupported filename extension.'() {
 176         given: 'file with unsupported filename extension (.doc)'
 177             def multipartFile = createMultipartFile("filename.doc", "content")
 178         and: 'an endpoint'
 179             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets"
 180         when: 'file uploaded with schema set create request'
 181             def response =
 182                     mvc.perform(
 183                             multipart(schemaSetEndpoint)
 184                                     .file(multipartFile)
 185                                     .param('schema-set-name', schemaSetName))
 186                             .andReturn().response
 187         then: 'create schema set rejected'
 188             response.status == HttpStatus.BAD_REQUEST.value()
 189     }
 190
 191     @Unroll
 192     def 'Create schema set from #fileType file with IOException occurrence on processing.'() {
 193         given: 'an endpoint'
 194             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets"
 195         when: 'file uploaded with schema set create request'
 196             def multipartFile = createMultipartFileForIOException(fileType)
 197             def response =
 198                     mvc.perform(
 199                             multipart(schemaSetEndpoint)
 200                                     .file(multipartFile)
 201                                     .param('schema-set-name', schemaSetName))
 202                             .andReturn().response
 203         then: 'the error response returned indicating internal server error occurrence'
 204             response.status == HttpStatus.INTERNAL_SERVER_ERROR.value()
 205         where: 'following file types are used'
 206             fileType << ['YANG', 'ZIP']
 207     }
 208
 209     def 'Delete schema set.'() {
 210         given: 'an endpoint'
 211             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets/$schemaSetName"
 212         when: 'delete schema set endpoint is invoked'
 213             def response = mvc.perform(delete(schemaSetEndpoint)).andReturn().response
 214         then: 'associated service method is invoked with expected parameters'
 215             1 * mockCpsModuleService.deleteSchemaSet(dataspaceName, schemaSetName, CASCADE_DELETE_PROHIBITED)
 216         and: 'response code indicates success'
 217             response.status == HttpStatus.NO_CONTENT.value()
 218     }
 219
 220     def 'Delete schema set which is in use.'() {
 221         given: 'service method throws an exception indicating the schema set is in use'
 222             def thrownException = new SchemaSetInUseException(dataspaceName, schemaSetName)
 223             mockCpsModuleService.deleteSchemaSet(dataspaceName, schemaSetName, CASCADE_DELETE_PROHIBITED) >>
 224                     { throw thrownException }
 225         and: 'an endpoint'
 226             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets/$schemaSetName"
 227         when: 'delete schema set endpoint is invoked'
 228             def response = mvc.perform(delete(schemaSetEndpoint)).andReturn().response
 229         then: 'schema set deletion fails with conflict response code'
 230             response.status == HttpStatus.CONFLICT.value()
 231     }
 232
 233     def 'Get existing schema set.'() {
 234         given: 'service method returns a new schema set'
 235             mockCpsModuleService.getSchemaSet(dataspaceName, schemaSetName) >>
 236                     new SchemaSet(name: schemaSetName, dataspaceName: dataspaceName)
 237         and: 'an endpoint'
 238             def schemaSetEndpoint = "$basePath/v1/dataspaces/$dataspaceName/schema-sets/$schemaSetName"
 239         when: 'get schema set API is invoked'
 240             def response = mvc.perform(get(schemaSetEndpoint)).andReturn().response
 241         then: 'the correct schema set is returned'
 242             response.status == HttpStatus.OK.value()
 243             response.getContentAsString().contains(schemaSetName)
 244     }
 245
 246     def 'Create Anchor.'() {
 247         given: 'request parameters'
 248             def requestParams = new LinkedMultiValueMap<>()
 249             requestParams.add('schema-set-name', schemaSetName)
 250             requestParams.add('anchor-name', anchorName)
 251         and: 'an endpoint'
 252             def anchorEndpoint = "$basePath/v1/dataspaces/$dataspaceName/anchors"
 253         when: 'post is invoked'
 254             def response =
 255                     mvc.perform(
 256                             post(anchorEndpoint).contentType(MediaType.APPLICATION_JSON)
 257                                     .params(requestParams as MultiValueMap))
 258                             .andReturn().response
 259         then: 'anchor is created successfully'
 260             1 * mockCpsAdminService.createAnchor(dataspaceName, schemaSetName, anchorName)
 261             response.status == HttpStatus.CREATED.value()
 262             response.getContentAsString().contains(anchorName)
 263     }
 264
 265     def 'Get existing anchor.'() {
 266         given: 'service method returns a list of anchors'
 267             mockCpsAdminService.getAnchors(dataspaceName) >> anchorList
 268         and: 'an endpoint'
 269             def anchorEndpoint = "$basePath/v1/dataspaces/$dataspaceName/anchors"
 270         when: 'get all anchors API is invoked'
 271             def response = mvc.perform(get(anchorEndpoint)).andReturn().response
 272         then: 'the correct anchor is returned'
 273             response.status == HttpStatus.OK.value()
 274             response.getContentAsString().contains(anchorName)
 275     }
 276
 277     def 'Get existing anchor by dataspace and anchor name.'() {
 278         given: 'service method returns an anchor'
 279             mockCpsAdminService.getAnchor(dataspaceName, anchorName) >>
 280                     new Anchor(name: anchorName, dataspaceName: dataspaceName, schemaSetName: schemaSetName)
 281         and: 'an endpoint'
 282             def anchorEndpoint = "$basePath/v1/dataspaces/$dataspaceName/anchors/$anchorName"
 283         when: 'get anchor API is invoked'
 284             def response = mvc.perform(get(anchorEndpoint)).andReturn().response
 285             def responseContent = response.getContentAsString()
 286         then: 'the correct anchor is returned'
 287             response.status == HttpStatus.OK.value()
 288             responseContent.contains(anchorName)
 289             responseContent.contains(dataspaceName)
 290             responseContent.contains(schemaSetName)
 291     }
 292
 293     def createMultipartFile(filename, content) {
 294         return new MockMultipartFile("file", filename, "text/plain", content.getBytes())
 295     }
 296
 297     def createZipMultipartFileFromResource(resourcePath) {
 298         return new MockMultipartFile("file", "test.zip", "application/zip",
 299                 getClass().getResource(resourcePath).getBytes())
 300     }
 301
 302     def createMultipartFileForIOException(extension) {
 303         def multipartFile = Mock(MockMultipartFile)
 304         multipartFile.getOriginalFilename() >> "TEST." + extension
 305         multipartFile.getBytes() >> { throw new IOException() }
 306         multipartFile.getInputStream() >> { throw new IOException() }
 307         return multipartFile
 308     }
 309 }