cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/utils/DmiServiceUrlBuilderSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.utils
  22
  23 import org.onap.cps.ncmp.api.inventory.CmHandleState
  24
  25 import static org.onap.cps.ncmp.api.impl.operations.DmiOperations.DataStoreEnum.PASSTHROUGH_RUNNING
  26
  27 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  28 import org.onap.cps.ncmp.api.impl.config.NcmpConfiguration
  29 import org.onap.cps.ncmp.api.impl.utils.DmiServiceUrlBuilder
  30 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  31 import spock.lang.Shared
  32 import spock.lang.Specification
  33
  34 class DmiServiceUrlBuilderSpec extends Specification {
  35
  36     @Shared
  37     YangModelCmHandle yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('dmiServiceName',
  38             'dmiDataServiceName', 'dmiModuleServiceName', CmHandleState.ADVISED , new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id'))
  39
  40     NcmpConfiguration.DmiProperties dmiProperties = new NcmpConfiguration.DmiProperties()
  41
  42     def objectUnderTest = new DmiServiceUrlBuilder(dmiProperties)
  43
  44     def 'Create the dmi service url with #scenario.'() {
  45         given: 'uri variables'
  46             dmiProperties.dmiBasePath = 'dmi'
  47             def uriVars = objectUnderTest.populateUriVariables(yangModelCmHandle,
  48                     "cmHandle", PASSTHROUGH_RUNNING)
  49         and: 'query params'
  50                             def uriQueries = objectUnderTest.populateQueryParams(resourceId,
  51                     'optionsParamInQuery', topic)
  52         when: 'a dmi datastore service url is generated'
  53             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  54         then: 'service url is generated as expected'
  55             assert dmiServiceUrl == expectedDmiServiceUrl
  56         where: 'the following parameters are used'
  57             scenario                       | topic               | resourceId   || expectedDmiServiceUrl
  58             'With valid resourceId'        | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  59             'With Empty resourceId'        | 'topicParamInQuery' | ''           || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?options=optionsParamInQuery&topic=topicParamInQuery'
  60             'With Empty dmi base path'     | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  61             'With Empty topicParamInQuery' | ''                  | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery'
  62     }
  63
  64     def 'Populate dmi data store url #scenario.'() {
  65         given: 'uri variables are created'
  66             dmiProperties.dmiBasePath = dmiBasePath
  67             def uriVars = objectUnderTest.populateUriVariables(yangModelCmHandle,
  68                     "cmHandle", PASSTHROUGH_RUNNING)
  69         and: 'null query params'
  70             def uriQueries = objectUnderTest.populateQueryParams(null,
  71                     null, null)
  72         when: 'a dmi datastore service url is generated'
  73             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  74         then: 'the created dmi service url matches the expected'
  75             assert dmiServiceUrl == expectedDmiServiceUrl
  76         where: 'the following parameters are used'
  77             scenario               | decription                                | dmiBasePath || expectedDmiServiceUrl
  78             'with base path  / '   | 'Invalid base path as it starts with /'   | '/dmi'      || 'dmiServiceName//dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  79             'without base path / ' | 'Valid path as it does not starts with /' | 'dmi'       || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  80     }
  81 }