cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/event/lcm/LcmEventsServiceSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  * Copyright (C) 2022-2023 Nordix Foundation
   4  * ================================================================================
   5  * Licensed under the Apache License, Version 2.0 (the "License");
   6  * you may not use this file except in compliance with the License.
   7  * You may obtain a copy of the License at
   8  *
   9  *       http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  * Unless required by applicable law or agreed to in writing, software
  12  * distributed under the License is distributed on an "AS IS" BASIS,
  13  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  * See the License for the specific language governing permissions and
  15  * limitations under the License.
  16  *
  17  * SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.event.lcm
  22
  23 import org.onap.cps.ncmp.api.impl.event.EventsPublisher
  24 import org.onap.ncmp.cmhandle.event.lcm.LcmEvent
  25 import org.springframework.kafka.KafkaException
  26 import spock.lang.Specification
  27
  28 class LcmEventsServiceSpec extends Specification {
  29
  30     def mockLcmEventsPublisher = Mock(EventsPublisher)
  31
  32     def objectUnderTest = new LcmEventsService(mockLcmEventsPublisher)
  33
  34     def 'Create and Publish lcm event where events are #scenario'() {
  35         given: 'a cm handle id and Lcm Event'
  36             def cmHandleId = 'test-cm-handle-id'
  37             def lcmEvent = new LcmEvent(eventId: UUID.randomUUID().toString(), eventCorrelationId: cmHandleId)
  38         and: 'notificationsEnabled is #notificationsEnabled and it will be true as default'
  39             objectUnderTest.notificationsEnabled = notificationsEnabled
  40         when: 'service is called to publish lcm event'
  41             objectUnderTest.publishLcmEvent('test-cm-handle-id', lcmEvent)
  42         then: 'publisher is called #expectedTimesMethodCalled times'
  43             expectedTimesMethodCalled * mockLcmEventsPublisher.publishEvent(_, cmHandleId, lcmEvent)
  44         where: 'the following values are used'
  45             scenario   | notificationsEnabled || expectedTimesMethodCalled
  46             'enabled'  | true                 || 1
  47             'disabled' | false                || 0
  48     }
  49
  50     def 'Unable to send message'(){
  51         given: 'a cm handle id and Lcm Event and notification enabled'
  52             def cmHandleId = 'test-cm-handle-id'
  53             def lcmEvent = new LcmEvent(eventId: UUID.randomUUID().toString(), eventCorrelationId: cmHandleId)
  54             objectUnderTest.notificationsEnabled = true
  55         when: 'publisher set to throw an exception'
  56             mockLcmEventsPublisher.publishEvent(*_) >> { throw new KafkaException('publishing failed')}
  57         and: 'an event is publised'
  58             objectUnderTest.publishLcmEvent(cmHandleId, lcmEvent)
  59         then: 'the exception is just logged and not bubbled up'
  60             noExceptionThrown()
  61     }
  62
  63 }