cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/NetworkCmProxyDataServiceImplRegistrationSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021-2022 Nordix Foundation
   4  *  Modifications Copyright (C) 2022 Bell Canada
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.api.impl
  23
  24 import com.fasterxml.jackson.databind.ObjectMapper
  25 import org.onap.cps.ncmp.api.NetworkCmProxyCmHandlerQueryService
  26 import org.onap.cps.api.CpsDataService
  27 import org.onap.cps.api.CpsModuleService
  28 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  29 import org.onap.cps.ncmp.api.impl.operations.DmiDataOperations
  30 import org.onap.cps.ncmp.api.inventory.InventoryPersistence
  31 import org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse
  32 import org.onap.cps.ncmp.api.models.DmiPluginRegistration
  33 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  34 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  35 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  36 import org.onap.cps.spi.exceptions.DataValidationException
  37 import org.onap.cps.spi.exceptions.SchemaSetNotFoundException
  38 import org.onap.cps.utils.JsonObjectMapper
  39 import spock.lang.Shared
  40 import spock.lang.Specification
  41
  42 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_DOES_NOT_EXIST
  43 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_ALREADY_EXIST
  44 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_INVALID_ID
  45 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.UNKNOWN_ERROR
  46 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.Status
  47 import static org.onap.cps.spi.CascadeDeleteAllowed.CASCADE_DELETE_ALLOWED
  48
  49 class NetworkCmProxyDataServiceImplRegistrationSpec extends Specification {
  50
  51     @Shared
  52     def ncmpServiceCmHandle = new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id')
  53
  54     @Shared
  55     def cmHandlesArray = ['cmHandle001']
  56
  57     def mockCpsDataService = Mock(CpsDataService)
  58     def mockCpsModuleService = Mock(CpsModuleService)
  59     def spiedJsonObjectMapper = Spy(new JsonObjectMapper(new ObjectMapper()))
  60     def mockDmiDataOperations = Mock(DmiDataOperations)
  61     def mockNetworkCmProxyDataServicePropertyHandler = Mock(NetworkCmProxyDataServicePropertyHandler)
  62     def mockInventoryPersistence = Mock(InventoryPersistence)
  63     def stubbedNetworkCmProxyCmHandlerQueryService = Stub(NetworkCmProxyCmHandlerQueryService)
  64     def noTimestamp = null
  65     def objectUnderTest = getObjectUnderTest()
  66
  67     def 'DMI Registration: Create, Update & Delete operations are processed in the right order'() {
  68         given: 'a registration with operations of all three types'
  69             def dmiRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
  70             dmiRegistration.setCreatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-1', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  71             dmiRegistration.setUpdatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-2', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  72             dmiRegistration.setRemovedCmHandles(['cmhandle-2'])
  73         when: 'registration is processed'
  74             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiRegistration)
  75             // Spock validated invocation order between multiple then blocks
  76         then: 'cm-handles are removed first'
  77             1 * objectUnderTest.parseAndRemoveCmHandlesInDmiRegistration(*_)
  78         then: 'cm-handles are created'
  79             1 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(*_)
  80         then: 'cm-handles are updated'
  81             1 * mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(*_)
  82     }
  83
  84     def 'DMI Registration: Response from all operations types are in response'() {
  85         given: 'a registration with operations of all three types'
  86             def dmiRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
  87             dmiRegistration.setCreatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-1', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  88             dmiRegistration.setUpdatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-2', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  89             dmiRegistration.setRemovedCmHandles(['cmhandle-2'])
  90         and: 'update cm-handles can be processed successfully'
  91             def updateResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-2')]
  92             mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(*_) >> updateResponses
  93         and: 'create cm-handles can be processed successfully'
  94             def createdResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-1')]
  95             objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(*_) >> createdResponses
  96         and: 'delete cm-handles can be processed successfully'
  97             def removeResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-3')]
  98             objectUnderTest.parseAndRemoveCmHandlesInDmiRegistration(*_) >> removeResponses
  99         when: 'registration is processed'
 100             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiRegistration)
 101         then: 'response has values from all operations'
 102             response.getRemovedCmHandles() == removeResponses
 103             response.getCreatedCmHandles() == createdResponses
 104             response.getUpdatedCmHandles() == updateResponses
 105
 106
 107     }
 108
 109     def 'Create CM-handle Validation: Registration with valid Service names: #scenario'() {
 110         given: 'a registration '
 111             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: dmiPlugin, dmiModelPlugin: dmiModelPlugin,
 112                 dmiDataPlugin: dmiDataPlugin)
 113             dmiPluginRegistration.createdCmHandles = [ncmpServiceCmHandle]
 114         when: 'update registration and sync module is called with correct DMI plugin information'
 115             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 116         then: 'create cm handles registration and sync modules is called with the correct plugin information'
 117             1 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(dmiPluginRegistration)
 118         where:
 119             scenario                          | dmiPlugin  | dmiModelPlugin | dmiDataPlugin
 120             'combined DMI plugin'             | 'service1' | ''             | ''
 121             'data & model DMI plugins'        | ''         | 'service1'     | 'service2'
 122             'data & model using same service' | ''         | 'service1'     | 'service1'
 123     }
 124
 125     def 'Create CM-handle Validation: Invalid DMI plugin service name with #scenario'() {
 126         given: 'a registration '
 127             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: dmiPlugin, dmiModelPlugin: dmiModelPlugin,
 128                 dmiDataPlugin: dmiDataPlugin)
 129             dmiPluginRegistration.createdCmHandles = [ncmpServiceCmHandle]
 130         when: 'registration is called with incorrect DMI plugin information'
 131             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 132         then: 'a DMI Request Exception is thrown with correct message details'
 133             def exceptionThrown = thrown(DmiRequestException.class)
 134             assert exceptionThrown.getMessage().contains(expectedMessageDetails)
 135         and: 'registration is not called'
 136             0 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(dmiPluginRegistration)
 137         where:
 138             scenario                         | dmiPlugin  | dmiModelPlugin | dmiDataPlugin || expectedMessageDetails
 139             'empty DMI plugins'              | ''         | ''             | ''            || 'No DMI plugin service names'
 140             'blank DMI plugins'              | ' '        | ' '            | ' '           || 'No DMI plugin service names'
 141             'null DMI plugins'               | null       | null           | null          || 'No DMI plugin service names'
 142             'all DMI plugins'                | 'service1' | 'service2'     | 'service3'    || 'Cannot register combined plugin service name and other service names'
 143             '(combined)DMI and Data Plugin'  | 'service1' | ''             | 'service2'    || 'Cannot register combined plugin service name and other service names'
 144             '(combined)DMI and model Plugin' | 'service1' | 'service2'     | ''            || 'Cannot register combined plugin service name and other service names'
 145             'only model DMI plugin'          | ''         | 'service1'     | ''            || 'Cannot register just a Data or Model plugin service name'
 146             'only data DMI plugin'           | ''         | ''             | 'service1'    || 'Cannot register just a Data or Model plugin service name'
 147     }
 148
 149     def 'Create CM-Handle Successfully: #scenario.'() {
 150         given: 'a registration without cm-handle properties'
 151             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
 152             dmiPluginRegistration.createdCmHandles = [new NcmpServiceCmHandle(cmHandleId: 'cmhandle', dmiProperties: dmiProperties, publicProperties: publicProperties)]
 153         when: 'registration is updated'
 154             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 155         then: 'a successful response is received'
 156             response.getCreatedCmHandles().size() == 1
 157             with(response.getCreatedCmHandles().get(0)) {
 158                 assert it.status == Status.SUCCESS
 159                 assert it.cmHandle == 'cmhandle'
 160             }
 161         and: 'save list elements is invoked with the expected parameters'
 162             interaction {
 163                 1 * mockCpsDataService.saveListElements('NCMP-Admin', 'ncmp-dmi-registry',
 164                     '/dmi-registry', _, noTimestamp) >> {
 165                     args -> {
 166                         assert args[3].startsWith('{"cm-handles":[{"id":"cmhandle","dmi-service-name":"my-server","state":{"cm-handle-state":"ADVISED","last-update-time":"20')
 167                         assert args[3].contains(expectedDmiProperties)
 168                         assert args[3].contains(expectedPublicProperties)
 169                     }
 170                 }
 171             }
 172         where:
 173             scenario                          | dmiProperties            | publicProperties               || expectedDmiProperties                      | expectedPublicProperties
 174             'with dmi & public properties'    | ['dmi-key': 'dmi-value'] | ['public-key': 'public-value'] || '[{"name":"dmi-key","value":"dmi-value"}]' | '[{"name":"public-key","value":"public-value"}]'
 175             'with only public properties'     | [:]                      | ['public-key': 'public-value'] || '[]'                                       | '[{"name":"public-key","value":"public-value"}]'
 176             'with only dmi properties'        | ['dmi-key': 'dmi-value'] | [:]                            || '[{"name":"dmi-key","value":"dmi-value"}]' | '[]'
 177             'without dmi & public properties' | [:]                      | [:]                            || '[]'                                       | '[]'
 178
 179     }
 180
 181     def 'Create CM-Handle Multiple Requests: All cm-handles creation requests are processed'() {
 182         given: 'a registration with three cm-handles to be created'
 183             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 184                 createdCmHandles: [new NcmpServiceCmHandle(cmHandleId: 'cmhandle1'),
 185                                    new NcmpServiceCmHandle(cmHandleId: 'cmhandle2'),
 186                                    new NcmpServiceCmHandle(cmHandleId: 'cmhandle3')])
 187         and: 'cm-handle creation is successful for 1st and 3rd; failed for 2nd'
 188             mockCpsDataService.saveListElements(_, _, _, _, _) >> {} >> { throw new RuntimeException("Failed") } >> {}
 189         when: 'registration is updated to create cm-handles'
 190             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 191         then: 'a response is received for all cm-handles'
 192             response.getCreatedCmHandles().size() == 3
 193         and: '1st and 3rd cm-handle are created successfully'
 194             with(response.getCreatedCmHandles().get(0)) {
 195                 assert it.status == Status.SUCCESS
 196                 assert it.cmHandle == 'cmhandle1'
 197             }
 198             with(response.getCreatedCmHandles().get(2)) {
 199                 assert it.status == Status.SUCCESS
 200                 assert it.cmHandle == 'cmhandle3'
 201             }
 202         and: '2nd cm-handle creation fails'
 203             with(response.getCreatedCmHandles().get(1)) {
 204                 assert it.status == Status.FAILURE
 205                 assert it.registrationError == UNKNOWN_ERROR
 206                 assert it.errorText == 'Failed'
 207                 assert it.cmHandle == 'cmhandle2'
 208             }
 209     }
 210
 211     def 'Create CM-Handle Error Handling: Registration fails: #scenario'() {
 212         given: 'a registration without cm-handle properties'
 213             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
 214             dmiPluginRegistration.createdCmHandles = [new NcmpServiceCmHandle(cmHandleId: cmHandleId)]
 215         and: 'cm-handler registration fails: #scenario'
 216             mockCpsDataService.saveListElements(_, _, _, _, _) >> { throw exception }
 217         when: 'registration is updated'
 218             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 219         then: 'a failure response is received'
 220             response.getCreatedCmHandles().size() == 1
 221             with(response.getCreatedCmHandles().get(0)) {
 222                 assert it.status == Status.FAILURE
 223                 assert it.cmHandle ==  cmHandleId
 224                 assert it.registrationError == expectedError
 225                 assert it.errorText == expectedErrorText
 226             }
 227         where:
 228             scenario                                        | cmHandleId             | exception                                               || expectedError           | expectedErrorText
 229             'cm-handle already exist'                       | 'cmhandle'             | new AlreadyDefinedException('', new RuntimeException()) || CM_HANDLE_ALREADY_EXIST | 'cm-handle already exists'
 230             'cm-handle has invalid name'                    | 'cm handle with space' | new DataValidationException("", "")                     || CM_HANDLE_INVALID_ID    | 'cm-handle has an invalid character(s) in id'
 231             'unknown exception while registering cm-handle' | 'cmhandle'             | new RuntimeException('Failed')                          || UNKNOWN_ERROR           | 'Failed'
 232     }
 233
 234     def 'Update CM-Handle: Update Operation Response is added to the response'() {
 235         given: 'a registration to update CmHandles'
 236             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 237                 updatedCmHandles: [{}])
 238         and: 'cm-handle updates can be processed successfully'
 239             def updateOperationResponse = [CmHandleRegistrationResponse.createSuccessResponse('cm-handle-1'),
 240                                            CmHandleRegistrationResponse.createFailureResponse('cm-handle-2', new Exception("Failed")),
 241                                            CmHandleRegistrationResponse.createFailureResponse('cm-handle-3', CM_HANDLE_DOES_NOT_EXIST),
 242                                            CmHandleRegistrationResponse.createFailureResponse('cm handle 4', CM_HANDLE_INVALID_ID)]
 243             mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(_) >> updateOperationResponse
 244         when: 'registration is updated'
 245             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 246         then: 'the response contains updateOperationResponse'
 247             assert response.getUpdatedCmHandles().size() == 4
 248             assert response.getUpdatedCmHandles().containsAll(updateOperationResponse)
 249     }
 250
 251     def 'Remove CmHandle Successfully: #scenario'() {
 252         given: 'a registration'
 253             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 254                 removedCmHandles: ['cmhandle'])
 255         and: '#scenario'
 256             mockCpsModuleService.deleteSchemaSet(_, 'cmhandle', CASCADE_DELETE_ALLOWED) >>
 257                 { if (!schemaSetExist) { throw new SchemaSetNotFoundException("", "") } }
 258         when: 'registration is updated to delete cmhandle'
 259             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 260         then: 'delete list or list element is called'
 261             1 * mockCpsDataService.deleteListOrListElement(_, _, _, _)
 262         and: 'successful response is received'
 263             assert response.getRemovedCmHandles().size() == 1
 264             with(response.getRemovedCmHandles().get(0)) {
 265                 assert it.status == Status.SUCCESS
 266                 assert it.cmHandle == 'cmhandle'
 267             }
 268         where:
 269             scenario                                            | schemaSetExist
 270             'schema-set exists and can be deleted successfully' | true
 271             'schema-set does not exist'                         | false
 272     }
 273
 274     def 'Remove CmHandle: All cm-handles delete requests are processed'() {
 275         given: 'a registration with three cm-handles to be deleted'
 276             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 277                 removedCmHandles: ['cmhandle1', 'cmhandle2', 'cmhandle3'])
 278         and: 'cm-handle deletion is successful for 1st and 3rd; failed for 2nd'
 279             mockCpsDataService.deleteListOrListElement(_, _, _, _) >> {} >> { throw new RuntimeException("Failed") } >> {}
 280         when: 'registration is updated to delete cmhandles'
 281             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 282         then: 'a response is received for all cm-handles'
 283             response.getRemovedCmHandles().size() == 3
 284         and: '1st and 3rd cm-handle deletes successfully'
 285             with(response.getRemovedCmHandles().get(0)) {
 286                 assert it.status == Status.SUCCESS
 287                 assert it.cmHandle == 'cmhandle1'
 288             }
 289             with(response.getRemovedCmHandles().get(2)) {
 290                 assert it.status == Status.SUCCESS
 291                 assert it.cmHandle == 'cmhandle3'
 292             }
 293         and: '2nd cm-handle deletion fails'
 294             with(response.getRemovedCmHandles().get(1)) {
 295                 assert it.status == Status.FAILURE
 296                 assert it.registrationError == UNKNOWN_ERROR
 297                 assert it.errorText == 'Failed'
 298                 assert it.cmHandle == 'cmhandle2'
 299             }
 300     }
 301
 302     def 'Remove CmHandle Error Handling: Schema Set Deletion failed'() {
 303         given: 'a registration'
 304             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 305                 removedCmHandles: ['cmhandle'])
 306         and: 'schema set deletion failed with unknown error'
 307             mockCpsModuleService.deleteSchemaSet(_, _, _) >> { throw new RuntimeException('Failed') }
 308         when: 'registration is updated to delete cmhandle'
 309             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 310         then: 'no exception is thrown'
 311             noExceptionThrown()
 312         and: 'cm-handle is not deleted'
 313             0 * mockCpsDataService.deleteListOrListElement(_, _, _, _)
 314         and: 'a failure response is received'
 315             assert response.getRemovedCmHandles().size() == 1
 316             with(response.getRemovedCmHandles().get(0)) {
 317                 assert it.status == Status.FAILURE
 318                 assert it.cmHandle == 'cmhandle'
 319                 assert it.errorText == 'Failed'
 320                 assert it.registrationError == UNKNOWN_ERROR
 321             }
 322     }
 323
 324     def 'Remove CmHandle Error Handling: #scenario'() {
 325         given: 'a registration'
 326             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 327                 removedCmHandles: ['cmhandle'])
 328         and: 'cm-handle deletion throws exception'
 329             mockCpsDataService.deleteListOrListElement(_, _, _, _) >> { throw deleteListElementException }
 330         when: 'registration is updated to delete cmhandle'
 331             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 332         then: 'no exception is thrown'
 333             noExceptionThrown()
 334         and: 'a failure response is received'
 335             assert response.getRemovedCmHandles().size() == 1
 336             with(response.getRemovedCmHandles().get(0)) {
 337                 assert it.status == Status.FAILURE
 338                 assert it.cmHandle == 'cmhandle'
 339                 assert it.registrationError == expectedError
 340                 assert it.errorText == expectedErrorText
 341             }
 342         where:
 343             scenario                     | cmHandleId             | deleteListElementException                ||  expectedError           | expectedErrorText
 344             'cm-handle does not exist'   | 'cmhandle'             | new DataNodeNotFoundException("", "", "") || CM_HANDLE_DOES_NOT_EXIST | 'cm-handle does not exist'
 345             'cm-handle has invalid name' | 'cm handle with space' | new DataValidationException("", "")       || CM_HANDLE_INVALID_ID     | 'cm-handle has an invalid character(s) in id'
 346             'an unexpected exception'    | 'cmhandle'             | new RuntimeException("Failed")            || UNKNOWN_ERROR            | 'Failed'
 347     }
 348
 349     def getObjectUnderTest() {
 350         return Spy(new NetworkCmProxyDataServiceImpl(mockCpsDataService, spiedJsonObjectMapper, mockDmiDataOperations,
 351             mockCpsModuleService, mockNetworkCmProxyDataServicePropertyHandler, mockInventoryPersistence, stubbedNetworkCmProxyCmHandlerQueryService))
 352     }
 353 }