cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/mapper/CmHandleStateMapperSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  * Copyright (C) 2022 Nordix Foundation
   4  * ================================================================================
   5  * Licensed under the Apache License, Version 2.0 (the "License");
   6  * you may not use this file except in compliance with the License.
   7  * You may obtain a copy of the License at
   8  *
   9  *       http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  * Unless required by applicable law or agreed to in writing, software
  12  * distributed under the License is distributed on an "AS IS" BASIS,
  13  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  * See the License for the specific language governing permissions and
  15  * limitations under the License.
  16  *
  17  * SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.rest.mapper
  22
  23 import org.mapstruct.factory.Mappers
  24 import org.onap.cps.ncmp.api.inventory.CmHandleState
  25 import org.onap.cps.ncmp.api.inventory.CompositeStateBuilder
  26 import org.onap.cps.ncmp.api.inventory.LockReasonCategory
  27 import org.onap.cps.ncmp.rest.model.CmHandleCompositeState
  28 import org.onap.cps.ncmp.api.inventory.DataStoreSyncState
  29 import spock.lang.Specification
  30
  31 import java.time.OffsetDateTime
  32 import java.time.ZoneOffset
  33 import java.time.format.DateTimeFormatter
  34
  35 class CmHandleStateMapperSpec extends Specification {
  36
  37     def formattedDateAndTime = DateTimeFormatter.ofPattern("yyyy-MM-dd'T'HH:mm:ss.SSSZ")
  38         .format(OffsetDateTime.of(2022, 12, 31, 20, 30, 40, 1, ZoneOffset.UTC))
  39     def objectUnderTest = Mappers.getMapper(CmHandleStateMapper)
  40
  41     def 'Composite State to CmHandleCompositeState'() {
  42         given: 'a composite state model'
  43             def compositeState = new CompositeStateBuilder()
  44                 .withCmHandleState(CmHandleState.ADVISED)
  45                 .withLastUpdatedTime(formattedDateAndTime.toString())
  46                 .withLockReason(LockReasonCategory.LOCKED_MODULE_SYNC_FAILED, 'locked details')
  47                 .withOperationalDataStores(DataStoreSyncState.SYNCHRONIZED, formattedDateAndTime).build()
  48         compositeState.setDataSyncEnabled(false)
  49         when: 'mapper is called'
  50             def result = objectUnderTest.toCmHandleCompositeStateExternalLockReason(compositeState)
  51         then: 'result is of the correct type'
  52             assert result.class == CmHandleCompositeState.class
  53         and: 'mapped result should have correct values'
  54             assert !result.dataSyncEnabled
  55             assert result.lastUpdateTime == formattedDateAndTime
  56             assert result.lockReason.reason == 'LOCKED_MISBEHAVING'
  57             assert result.lockReason.details == 'locked details'
  58             assert result.cmHandleState == 'ADVISED'
  59             assert result.dataSyncState.operational.getSyncState() != null
  60     }
  61
  62     def 'Handling null state.'() {
  63         expect: 'converting null returns null'
  64             objectUnderTest.toDataStores(null) == null
  65     }
  66
  67     def 'Internal to External Lock Reason Mapping of #scenario'() {
  68         given: 'a LOCKED composite state with locked reason of #scenario'
  69             def compositeState = new CompositeStateBuilder()
  70                 .withCmHandleState(CmHandleState.LOCKED)
  71                 .withLockReason(lockReason, '').build()
  72         when: 'the composite state is mapped to a CMHandle composite state'
  73             def result = objectUnderTest.toCmHandleCompositeStateExternalLockReason(compositeState)
  74         then: 'the composite state contains the expected lock Reason and details'
  75             result.getLockReason().getReason() == expectedExternalLockReason
  76         where:
  77             scenario                    | lockReason                                   || expectedExternalLockReason
  78             'LOCKED_MODULE_SYNC_FAILED' | LockReasonCategory.LOCKED_MODULE_SYNC_FAILED || 'LOCKED_MISBEHAVING'
  79             'null value'                | null                                         || null
  80     }
  81
  82 }