cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/exceptions/NetworkCmProxyRestExceptionHandlerSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modification Copyright (C) 2021-2022 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.rest.exceptions
  22
  23 import groovy.json.JsonSlurper
  24 import org.onap.cps.ncmp.api.NetworkCmProxyDataService
  25 import org.onap.cps.ncmp.api.impl.exception.NcmpException
  26 import org.onap.cps.spi.exceptions.CpsException
  27 import org.spockframework.spring.SpringBean
  28 import org.springframework.beans.factory.annotation.Autowired
  29 import org.springframework.beans.factory.annotation.Value
  30 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  31 import org.springframework.test.web.servlet.MockMvc
  32 import spock.lang.Shared
  33 import spock.lang.Specification
  34
  35 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  36 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  37
  38 @WebMvcTest
  39 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  40
  41     @Autowired
  42     MockMvc mvc
  43
  44     @SpringBean
  45     NetworkCmProxyDataService mockNetworkCmProxyDataService = Mock()
  46
  47     @Value('${rest.api.ncmp-base-path}')
  48     def basePath
  49
  50     def dataNodeBaseEndpoint
  51
  52     @Shared
  53     def errorMessage = 'some error message'
  54     @Shared
  55     def errorDetails = 'some error details'
  56
  57     def setup() {
  58         dataNodeBaseEndpoint = "$basePath/v1"
  59     }
  60
  61     def 'Get request with generic #scenario exception returns HTTP Status Internal Server Error.'() {
  62         when: 'generic CPS exception is thrown by the service'
  63             setupTestException(exception)
  64             def response = performTestRequest()
  65         then: 'an HTTP Internal Server Error response is returned with correct message and details'
  66             assertTestResponse(response, INTERNAL_SERVER_ERROR, errorMessage, expectedErrorDetails)
  67         where:
  68             scenario | exception                                     || expectedErrorDetails
  69             'CPS'    | new CpsException(errorMessage, errorDetails)  || errorDetails
  70             'NCMP'   | new NcmpException(errorMessage, errorDetails) || null
  71             'other'  | new IllegalStateException(errorMessage)       || null
  72     }
  73
  74     def setupTestException(exception){
  75         mockNetworkCmProxyDataService.getYangResourcesModuleReferences('testCmHandle')>>
  76                 { throw exception}
  77     }
  78
  79     def performTestRequest(){
  80         return mvc.perform(get("$dataNodeBaseEndpoint/ch/testCmHandle/modules")).andReturn().response
  81     }
  82
  83     static void assertTestResponse(response, expectedStatus , expectedErrorMessage , expectedErrorDetails) {
  84         assert response.status == expectedStatus.value()
  85         def content = new JsonSlurper().parseText(response.contentAsString)
  86         assert content['status'] == expectedStatus.toString()
  87         assert content['message'] == expectedErrorMessage
  88         assert expectedErrorDetails == null || content['details'] == expectedErrorDetails
  89     }
  90 }