cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/exceptions/NetworkCmProxyRestExceptionHandlerSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modification Copyright (C) 2021-2022 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.exceptions
  23
  24 import groovy.json.JsonSlurper
  25 import org.modelmapper.ModelMapper
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.NetworkCmProxyDataService
  28 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  29 import org.onap.cps.ncmp.api.impl.exception.ServerNcmpException
  30 import org.onap.cps.ncmp.rest.controller.RestInputMapper
  31 import org.onap.cps.spi.exceptions.CpsException
  32 import org.onap.cps.spi.exceptions.DataValidationException
  33 import org.onap.cps.utils.JsonObjectMapper
  34 import org.spockframework.spring.SpringBean
  35 import org.springframework.beans.factory.annotation.Autowired
  36 import org.springframework.beans.factory.annotation.Value
  37 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  38 import org.springframework.http.MediaType
  39 import org.springframework.test.web.servlet.MockMvc
  40 import spock.lang.Shared
  41 import spock.lang.Specification
  42
  43 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  44 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  45 import static org.springframework.http.HttpStatus.BAD_REQUEST
  46 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  47 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  48 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  49
  50 @WebMvcTest
  51 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  52
  53     @Autowired
  54     MockMvc mvc
  55
  56     @SpringBean
  57     NetworkCmProxyDataService mockNetworkCmProxyDataService = Mock()
  58
  59     @SpringBean
  60     ModelMapper modelMapper = Stub()
  61
  62     @SpringBean
  63     JsonObjectMapper jsonObjectMapper = Stub()
  64
  65     @SpringBean
  66     RestInputMapper restInputMapper = Mock()
  67
  68     @Value('${rest.api.ncmp-base-path}')
  69     def basePathNcmp
  70
  71     @Value('${rest.api.ncmp-inventory-base-path}')
  72     def basePathNcmpInventory
  73
  74     def dataNodeBaseEndpointNcmp
  75     def dataNodeBaseEndpointNcmpInventory
  76
  77     @Shared
  78     def errorMessage = 'some error message'
  79     @Shared
  80     def errorDetails = 'some error details'
  81
  82     def setup() {
  83         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
  84         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
  85     }
  86
  87     def 'Get request with generic #scenario exception returns correct HTTP Status.'() {
  88         when: 'an exception is thrown by the service'
  89             setupTestException(exception, NCMP)
  90             def response = performTestRequest(NCMP)
  91         then: 'an HTTP response is returned with correct message and details'
  92             assertTestResponse(response, expectedErrorCode, errorMessage, expectedErrorDetails)
  93         where:
  94             scenario      | exception                                           || expectedErrorDetails | expectedErrorCode
  95             'CPS'         | new CpsException(errorMessage, errorDetails)        || errorDetails         | INTERNAL_SERVER_ERROR
  96             'NCMP-server' | new ServerNcmpException(errorMessage, errorDetails) || null                 | INTERNAL_SERVER_ERROR
  97             'NCMP-client' | new DmiRequestException(errorMessage, errorDetails) || null                 | BAD_REQUEST
  98             'other'       | new IllegalStateException(errorMessage)             || null                 | INTERNAL_SERVER_ERROR
  99     }
 100
 101     def 'Post request with exception returns correct HTTP Status.'() {
 102         given: 'the service throws data validation exception'
 103             def exception = new DataValidationException(errorMessage, errorDetails)
 104             setupTestException(exception, NCMPINVENTORY)
 105         when: 'the HTTP request is made'
 106             def response = performTestRequest(NCMPINVENTORY)
 107         then: 'an HTTP response is returned with correct message and details'
 108             assertTestResponse(response, BAD_REQUEST, errorMessage, errorDetails)
 109     }
 110
 111     def setupTestException(exception, apiType) {
 112         if (NCMP == apiType) {
 113             mockNetworkCmProxyDataService.getYangResourcesModuleReferences(*_) >> { throw exception }
 114         }
 115         mockNetworkCmProxyDataService.updateDmiRegistrationAndSyncModule(*_) >> { throw exception }
 116     }
 117
 118     def performTestRequest(apiType) {
 119         if (NCMP == apiType) {
 120             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 121         }
 122         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 123         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 124     }
 125
 126     static void assertTestResponse(response, expectedStatus , expectedErrorMessage , expectedErrorDetails) {
 127         assert response.status == expectedStatus.value()
 128         def content = new JsonSlurper().parseText(response.contentAsString)
 129         assert content['status'] == expectedStatus.toString()
 130         assert content['message'] == expectedErrorMessage
 131         assert expectedErrorDetails == null || content['details'] == expectedErrorDetails
 132     }
 133
 134     enum ApiType {
 135         NCMP,
 136         NCMPINVENTORY;
 137     }
 138 }