cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/exceptions/NetworkCmProxyRestExceptionHandlerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2022 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.exceptions
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.NetworkCmProxyDataService
  28 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  29 import org.onap.cps.ncmp.api.impl.exception.HttpClientRequestException
  30 import org.onap.cps.ncmp.api.impl.exception.ServerNcmpException
  31 import org.onap.cps.ncmp.rest.controller.NcmpRestInputMapper
  32 import org.onap.cps.ncmp.rest.mapper.RestOutputCmHandleStateMapper
  33 import org.onap.cps.ncmp.rest.executor.CpsNcmpTaskExecutor
  34 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  35 import org.onap.cps.spi.exceptions.CpsException
  36 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  37 import org.onap.cps.spi.exceptions.DataValidationException
  38 import org.onap.cps.utils.JsonObjectMapper
  39 import org.spockframework.spring.SpringBean
  40 import org.springframework.beans.factory.annotation.Autowired
  41 import org.springframework.beans.factory.annotation.Value
  42 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  43 import org.springframework.http.HttpStatus
  44 import org.springframework.http.MediaType
  45 import org.springframework.test.web.servlet.MockMvc
  46 import spock.lang.Shared
  47 import spock.lang.Specification
  48
  49 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  50 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  51 import static org.springframework.http.HttpStatus.BAD_REQUEST
  52 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  53 import static org.springframework.http.HttpStatus.NOT_FOUND
  54 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  55 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  56
  57 @WebMvcTest
  58 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  59
  60     @Autowired
  61     MockMvc mvc
  62
  63     @SpringBean
  64     NetworkCmProxyDataService mockNetworkCmProxyDataService = Mock()
  65
  66     @SpringBean
  67     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  68
  69     @SpringBean
  70     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  71
  72     @SpringBean
  73     RestOutputCmHandleStateMapper restOutputCmHandleStateMapper = Mappers.getMapper(RestOutputCmHandleStateMapper)
  74
  75     @SpringBean
  76     CpsNcmpTaskExecutor stubbedCpsTaskExecutor = Stub()
  77
  78     @SpringBean
  79     DeprecationHelper stubbedDeprecationHelper = Stub()
  80
  81     @Value('${rest.api.ncmp-base-path}')
  82     def basePathNcmp
  83
  84     @Value('${rest.api.ncmp-inventory-base-path}')
  85     def basePathNcmpInventory
  86
  87     def dataNodeBaseEndpointNcmp
  88     def dataNodeBaseEndpointNcmpInventory
  89
  90     @Shared
  91     def sampleErrorMessage = 'some error message'
  92     @Shared
  93     def sampleErrorDetails = 'some error details'
  94
  95     def setup() {
  96         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
  97         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
  98     }
  99
 100     def 'Get request with generic #scenario exception returns correct HTTP Status with #scenario'() {
 101         when: 'an exception is thrown by the service'
 102             setupTestException(exception, NCMP)
 103             def response = performTestRequest(NCMP)
 104         then: 'an HTTP response is returned with correct message and details'
 105             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 106         where:
 107             scenario              | exception                                                        || expectedErrorDetails | expectedErrorMessage | expectedErrorCode
 108             'CPS'                 | new CpsException(sampleErrorMessage, sampleErrorDetails)         || sampleErrorDetails   | sampleErrorMessage   | INTERNAL_SERVER_ERROR
 109             'NCMP-server'         | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)  || null                 | sampleErrorMessage   | INTERNAL_SERVER_ERROR
 110             'NCMP-client'         | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)  || null                 | sampleErrorMessage   | BAD_REQUEST
 111             'DataNode Validation' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || null                 | 'DataNode not found' | NOT_FOUND
 112             'other'               | new IllegalStateException(sampleErrorMessage)                    || null                 | sampleErrorMessage   | INTERNAL_SERVER_ERROR
 113             'Data Node Not Found' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || 'DataNode not found' | 'DataNode not found' | NOT_FOUND
 114     }
 115
 116     def 'Post request with exception returns correct HTTP Status.'() {
 117         given: 'the service throws data validation exception'
 118             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 119             setupTestException(exception, NCMPINVENTORY)
 120         when: 'the HTTP request is made'
 121             def response = performTestRequest(NCMPINVENTORY)
 122         then: 'an HTTP response is returned with correct message and details'
 123             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 124     }
 125
 126     def 'Failing DMI Request - passthrough scenario'() {
 127         given: 'failing DMI request'
 128             setupTestException(new HttpClientRequestException('Error Message Details NCMP', 'Bad Request from DMI', 400) , NCMP)
 129         when: 'the DMI request is executed'
 130             def response = performTestRequest(NCMP)
 131         then: 'NCMP service responds with 502 Bad Gateway status'
 132             response.status == HttpStatus.BAD_GATEWAY.value()
 133         and: 'the NCMP response also contains the original DMI response details'
 134             response.contentAsString.contains('400')
 135             response.contentAsString.contains('Bad Request from DMI')
 136     }
 137
 138     def setupTestException(exception, apiType) {
 139         if (NCMP == apiType) {
 140             mockNetworkCmProxyDataService.getYangResourcesModuleReferences(*_) >> { throw exception }
 141         }
 142         mockNetworkCmProxyDataService.updateDmiRegistrationAndSyncModule(*_) >> { throw exception }
 143     }
 144
 145     def performTestRequest(apiType) {
 146         if (NCMP == apiType) {
 147             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 148         }
 149         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 150         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 151     }
 152
 153     static void assertTestResponse(response, expectedStatus , expectedErrorMessage , expectedErrorDetails) {
 154         assert response.status == expectedStatus.value()
 155         def content = new JsonSlurper().parseText(response.contentAsString)
 156         assert content['status'].toString().contains(expectedStatus.toString())
 157         assert content['message'].toString().contains(expectedErrorMessage)
 158         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 159     }
 160
 161     enum ApiType {
 162         NCMP,
 163         NCMPINVENTORY;
 164     }
 165 }