gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2025 OpenInfra Foundation Europe. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.impl.NetworkCmProxyInventoryFacadeImpl
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  39 import org.onap.cps.ncmp.rest.provmns.exception.InvalidPathException
  40 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  41 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  42 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  43 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  44 import org.onap.cps.api.exceptions.AlreadyDefinedException
  45 import org.onap.cps.api.exceptions.CpsException
  46 import org.onap.cps.api.exceptions.DataNodeNotFoundException
  47 import org.onap.cps.api.exceptions.DataValidationException
  48 import org.onap.cps.ncmp.rest.util.RestOutputCmHandleMapper
  49 import org.onap.cps.utils.JsonObjectMapper
  50 import org.spockframework.spring.SpringBean
  51 import org.springframework.beans.factory.annotation.Autowired
  52 import org.springframework.beans.factory.annotation.Value
  53 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  54 import org.springframework.http.MediaType
  55 import org.springframework.test.web.servlet.MockMvc
  56 import spock.lang.Shared
  57 import spock.lang.Specification
  58
  59 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  60 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  61 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  62 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  63 import static org.springframework.http.HttpStatus.BAD_REQUEST
  64 import static org.springframework.http.HttpStatus.CONFLICT
  65 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  66 import static org.springframework.http.HttpStatus.NOT_FOUND
  67 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  68 import static org.springframework.http.HttpStatus.UNPROCESSABLE_ENTITY
  69 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  70 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  71
  72 @WebMvcTest
  73 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  74
  75     @Autowired
  76     MockMvc mvc
  77
  78     @SpringBean
  79     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  80
  81     @SpringBean
  82     NetworkCmProxyInventoryFacadeImpl mockNetworkCmProxyInventoryFacade = Mock()
  83
  84     @SpringBean
  85     InventoryPersistence mockInventoryPersistence = Mock()
  86
  87     @SpringBean
  88     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  89
  90     @SpringBean
  91     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  92
  93     @SpringBean
  94     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  95
  96     @SpringBean
  97     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
  98
  99     @SpringBean
 100     DeprecationHelper stubbedDeprecationHelper = Stub()
 101
 102     @SpringBean
 103     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 104
 105     @SpringBean
 106     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 107
 108     @SpringBean
 109     DataJobControllerForTest stubbedDataJobControllerForTest = Stub()
 110
 111     @SpringBean
 112     RestOutputCmHandleMapper mockRestOutputCmHandleMapper = Mock()
 113
 114     @Value('${rest.api.ncmp-base-path}')
 115     def basePathNcmp
 116
 117     @Value('${rest.api.ncmp-inventory-base-path}')
 118     def basePathNcmpInventory
 119
 120     def dataNodeBaseEndpointNcmp
 121     def dataNodeBaseEndpointNcmpInventory
 122
 123     @Shared
 124     def sampleErrorMessage = 'some error message'
 125     @Shared
 126     def sampleErrorDetails = 'some error details'
 127
 128     def setup() {
 129         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 130         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 131     }
 132
 133     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 134         when: 'an exception is thrown by the service'
 135             setupTestException(exception, NCMP)
 136             def response = performTestRequest(NCMP)
 137         then: 'an HTTP response is returned with correct message and details'
 138             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 139         where:
 140             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 141             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 142             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 143             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 144             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 145             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 146             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 147             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 148             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 149             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 150             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 151             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 152             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 153             'Invalid Path'          | new InvalidPathException("some invalid path")                             || UNPROCESSABLE_ENTITY  | 'not a valid path'          | 'some invalid path not a valid path'
 154     }
 155
 156     def 'Post request with exception returns correct HTTP Status.'() {
 157         given: 'the service throws data validation exception'
 158             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 159             setupTestException(exception, NCMPINVENTORY)
 160         when: 'the HTTP request is made'
 161             def response = performTestRequest(NCMPINVENTORY)
 162         then: 'an HTTP response is returned with correct message and details'
 163             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 164     }
 165
 166     def 'Failing DMI Request - passthrough scenario'() {
 167         given: 'failing DMI request'
 168             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 169         when: 'the DMI request is executed'
 170             def response = performTestRequest(NCMP)
 171         then: 'NCMP service responds with 502 Bad Gateway status'
 172             response.status == BAD_GATEWAY.value()
 173         and: 'the NCMP response also contains the original DMI response details'
 174             response.contentAsString.contains('400')
 175             response.contentAsString.contains('Bad Request from DMI')
 176     }
 177
 178     def setupTestException(exception, apiType) {
 179         if (NCMP == apiType) {
 180             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 181         }
 182         mockNetworkCmProxyInventoryFacade.updateDmiRegistration(*_) >> { throw exception }
 183     }
 184
 185     def performTestRequest(apiType) {
 186         if (NCMP == apiType) {
 187             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 188         }
 189         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 190         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 191     }
 192
 193     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 194         assert response.status == expectedStatus.value()
 195         def content = new JsonSlurper().parseText(response.contentAsString)
 196         assert content['status'].toString().contains(expectedStatus.toString())
 197         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 198         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 199     }
 200
 201     enum ApiType { NCMP,  NCMPINVENTORY  }
 202 }