gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2024 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.api.inventory.NetworkCmProxyInventoryFacade
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.data.policyexecutor.PolicyExecutor
  39 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  40 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  41 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  42 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  43 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  44 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  45 import org.onap.cps.spi.exceptions.CpsException
  46 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  47 import org.onap.cps.spi.exceptions.DataValidationException
  48 import org.onap.cps.utils.JsonObjectMapper
  49 import org.spockframework.spring.SpringBean
  50 import org.springframework.beans.factory.annotation.Autowired
  51 import org.springframework.beans.factory.annotation.Value
  52 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  53 import org.springframework.http.MediaType
  54 import org.springframework.test.web.servlet.MockMvc
  55 import spock.lang.Shared
  56 import spock.lang.Specification
  57
  58 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  59 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  60 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  61 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  62 import static org.springframework.http.HttpStatus.BAD_REQUEST
  63 import static org.springframework.http.HttpStatus.CONFLICT
  64 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  65 import static org.springframework.http.HttpStatus.NOT_FOUND
  66 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  67 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  68 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  69
  70 @WebMvcTest
  71 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  72
  73     @Autowired
  74     MockMvc mvc
  75
  76     @SpringBean
  77     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  78
  79     @SpringBean
  80     NetworkCmProxyInventoryFacade mockNetworkCmProxyInventoryFacade = Mock()
  81
  82     @SpringBean
  83     InventoryPersistence mockInventoryPersistence = Mock()
  84
  85     @SpringBean
  86     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  87
  88     @SpringBean
  89     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  90
  91     @SpringBean
  92     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  93
  94     @SpringBean
  95     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
  96
  97     @SpringBean
  98     DeprecationHelper stubbedDeprecationHelper = Stub()
  99
 100     @SpringBean
 101     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 102
 103     @SpringBean
 104     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 105
 106     @Value('${rest.api.ncmp-base-path}')
 107     def basePathNcmp
 108
 109     @Value('${rest.api.ncmp-inventory-base-path}')
 110     def basePathNcmpInventory
 111
 112     def dataNodeBaseEndpointNcmp
 113     def dataNodeBaseEndpointNcmpInventory
 114
 115     @Shared
 116     def sampleErrorMessage = 'some error message'
 117     @Shared
 118     def sampleErrorDetails = 'some error details'
 119
 120     def setup() {
 121         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 122         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 123     }
 124
 125     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 126         when: 'an exception is thrown by the service'
 127             setupTestException(exception, NCMP)
 128             def response = performTestRequest(NCMP)
 129         then: 'an HTTP response is returned with correct message and details'
 130             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 131         where:
 132             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 133             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 134             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 135             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 136             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 137             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 138             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 139             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 140             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 141             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 142             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 143             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 144             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 145     }
 146
 147     def 'Post request with exception returns correct HTTP Status.'() {
 148         given: 'the service throws data validation exception'
 149             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 150             setupTestException(exception, NCMPINVENTORY)
 151         when: 'the HTTP request is made'
 152             def response = performTestRequest(NCMPINVENTORY)
 153         then: 'an HTTP response is returned with correct message and details'
 154             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 155     }
 156
 157     def 'Failing DMI Request - passthrough scenario'() {
 158         given: 'failing DMI request'
 159             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 160         when: 'the DMI request is executed'
 161             def response = performTestRequest(NCMP)
 162         then: 'NCMP service responds with 502 Bad Gateway status'
 163             response.status == BAD_GATEWAY.value()
 164         and: 'the NCMP response also contains the original DMI response details'
 165             response.contentAsString.contains('400')
 166             response.contentAsString.contains('Bad Request from DMI')
 167     }
 168
 169     def setupTestException(exception, apiType) {
 170         if (NCMP == apiType) {
 171             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 172         }
 173         mockNetworkCmProxyInventoryFacade.updateDmiRegistrationAndSyncModule(*_) >> { throw exception }
 174     }
 175
 176     def performTestRequest(apiType) {
 177         if (NCMP == apiType) {
 178             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 179         }
 180         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 181         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 182     }
 183
 184     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 185         assert response.status == expectedStatus.value()
 186         def content = new JsonSlurper().parseText(response.contentAsString)
 187         assert content['status'].toString().contains(expectedStatus.toString())
 188         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 189         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 190     }
 191
 192     enum ApiType { NCMP,  NCMPINVENTORY  }
 193 }