gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2025 OpenInfra Foundation Europe. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.impl.NetworkCmProxyInventoryFacadeImpl
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.data.policyexecutor.PolicyExecutor
  39 import org.onap.cps.ncmp.impl.dmi.DmiRestClient
  40 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  41 import org.onap.cps.ncmp.impl.utils.AlternateIdMatcher
  42 import org.onap.cps.ncmp.api.exceptions.ProvMnSException
  43 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  44 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  45 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  46 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  47 import org.onap.cps.api.exceptions.AlreadyDefinedException
  48 import org.onap.cps.api.exceptions.CpsException
  49 import org.onap.cps.api.exceptions.DataNodeNotFoundException
  50 import org.onap.cps.api.exceptions.DataValidationException
  51 import org.onap.cps.ncmp.impl.provmns.ParametersBuilder
  52 import org.onap.cps.ncmp.rest.util.RestOutputCmHandleMapper
  53 import org.onap.cps.utils.JsonObjectMapper
  54 import org.spockframework.spring.SpringBean
  55 import org.springframework.beans.factory.annotation.Autowired
  56 import org.springframework.beans.factory.annotation.Value
  57 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  58 import org.springframework.http.MediaType
  59 import org.springframework.test.web.servlet.MockMvc
  60 import spock.lang.Shared
  61 import spock.lang.Specification
  62
  63 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  64 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  65 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  66 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  67 import static org.springframework.http.HttpStatus.BAD_REQUEST
  68 import static org.springframework.http.HttpStatus.CONFLICT
  69 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  70 import static org.springframework.http.HttpStatus.NOT_FOUND
  71 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  72 import static org.springframework.http.HttpStatus.UNPROCESSABLE_ENTITY
  73 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  74 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  75
  76 @WebMvcTest
  77 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  78
  79     @Autowired
  80     MockMvc mvc
  81
  82     @SpringBean
  83     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  84
  85     @SpringBean
  86     NetworkCmProxyInventoryFacadeImpl mockNetworkCmProxyInventoryFacade = Mock()
  87
  88     @SpringBean
  89     InventoryPersistence mockInventoryPersistence = Mock()
  90
  91     @SpringBean
  92     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  93
  94     @SpringBean
  95     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  96
  97     @SpringBean
  98     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  99
 100     @SpringBean
 101     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
 102
 103     @SpringBean
 104     DeprecationHelper stubbedDeprecationHelper = Stub()
 105
 106     @SpringBean
 107     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 108
 109     @SpringBean
 110     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 111
 112     @SpringBean
 113     DataJobControllerForTest stubbedDataJobControllerForTest = Stub()
 114
 115     @SpringBean
 116     RestOutputCmHandleMapper mockRestOutputCmHandleMapper = Mock()
 117
 118     @SpringBean
 119     ParametersBuilder mockProvMnSParametersMapper = Mock()
 120
 121     @SpringBean
 122     ProvMnsController mockProvMnsController = Mock()
 123
 124     @SpringBean
 125     AlternateIdMatcher alternateIdMatcher = Mock()
 126
 127     @SpringBean
 128     DmiRestClient dmiRestClient = Mock()
 129
 130     @SpringBean
 131     PolicyExecutor policyExecutor = Mock()
 132
 133     @Value('${rest.api.ncmp-base-path}')
 134     def basePathNcmp
 135
 136     @Value('${rest.api.ncmp-inventory-base-path}')
 137     def basePathNcmpInventory
 138
 139     def dataNodeBaseEndpointNcmp
 140     def dataNodeBaseEndpointNcmpInventory
 141
 142     @Shared
 143     def sampleErrorMessage = 'some error message'
 144     @Shared
 145     def sampleErrorDetails = 'some error details'
 146
 147     def setup() {
 148         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 149         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 150     }
 151
 152     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 153         when: 'an exception is thrown by the service'
 154             setupTestException(exception, NCMP)
 155             def response = performTestRequest(NCMP)
 156         then: 'an HTTP response is returned with correct message and details'
 157             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 158         where:
 159             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 160             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 161             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 162             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 163             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 164             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 165             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 166             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 167             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 168             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 169             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 170             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 171             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 172             'Invalid Path'          | new ProvMnSException('not a valid path' ,'some details')                  || UNPROCESSABLE_ENTITY  | 'not a valid path'          | 'some details'
 173     }
 174
 175     def 'Post request with exception returns correct HTTP Status.'() {
 176         given: 'the service throws data validation exception'
 177             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 178             setupTestException(exception, NCMPINVENTORY)
 179         when: 'the HTTP request is made'
 180             def response = performTestRequest(NCMPINVENTORY)
 181         then: 'an HTTP response is returned with correct message and details'
 182             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 183     }
 184
 185     def 'Failing DMI Request - passthrough scenario'() {
 186         given: 'failing DMI request'
 187             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 188         when: 'the DMI request is executed'
 189             def response = performTestRequest(NCMP)
 190         then: 'NCMP service responds with 502 Bad Gateway status'
 191             response.status == BAD_GATEWAY.value()
 192         and: 'the NCMP response also contains the original DMI response details'
 193             response.contentAsString.contains('400')
 194             response.contentAsString.contains('Bad Request from DMI')
 195     }
 196
 197     def setupTestException(exception, apiType) {
 198         if (NCMP == apiType) {
 199             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 200         }
 201         mockNetworkCmProxyInventoryFacade.updateDmiRegistration(*_) >> { throw exception }
 202     }
 203
 204     def performTestRequest(apiType) {
 205         if (NCMP == apiType) {
 206             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 207         }
 208         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 209         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 210     }
 211
 212     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 213         assert response.status == expectedStatus.value()
 214         def content = new JsonSlurper().parseText(response.contentAsString)
 215         assert content['status'].toString().contains(expectedStatus.toString())
 216         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 217         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 218     }
 219
 220     enum ApiType { NCMP,  NCMPINVENTORY  }
 221 }