gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2025 OpenInfra Foundation Europe. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.impl.NetworkCmProxyInventoryFacadeImpl
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.data.policyexecutor.PolicyExecutor
  39 import org.onap.cps.ncmp.impl.dmi.DmiRestClient
  40 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  41 import org.onap.cps.ncmp.impl.utils.AlternateIdMatcher
  42 import org.onap.cps.ncmp.rest.provmns.exception.InvalidPathException
  43 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  44 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  45 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  46 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  47 import org.onap.cps.api.exceptions.AlreadyDefinedException
  48 import org.onap.cps.api.exceptions.CpsException
  49 import org.onap.cps.api.exceptions.DataNodeNotFoundException
  50 import org.onap.cps.api.exceptions.DataValidationException
  51 import org.onap.cps.ncmp.rest.util.ProvMnSParametersMapper
  52 import org.onap.cps.ncmp.rest.util.RestOutputCmHandleMapper
  53 import org.onap.cps.utils.JsonObjectMapper
  54 import org.spockframework.spring.SpringBean
  55 import org.springframework.beans.factory.annotation.Autowired
  56 import org.springframework.beans.factory.annotation.Value
  57 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  58 import org.springframework.http.MediaType
  59 import org.springframework.test.web.servlet.MockMvc
  60 import spock.lang.Shared
  61 import spock.lang.Specification
  62
  63 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  64 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  65 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  66 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  67 import static org.springframework.http.HttpStatus.BAD_REQUEST
  68 import static org.springframework.http.HttpStatus.CONFLICT
  69 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  70 import static org.springframework.http.HttpStatus.NOT_FOUND
  71 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  72 import static org.springframework.http.HttpStatus.UNPROCESSABLE_ENTITY
  73 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  74 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  75
  76 @WebMvcTest
  77 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  78
  79     @Autowired
  80     MockMvc mvc
  81
  82     @SpringBean
  83     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  84
  85     @SpringBean
  86     NetworkCmProxyInventoryFacadeImpl mockNetworkCmProxyInventoryFacade = Mock()
  87
  88     @SpringBean
  89     InventoryPersistence mockInventoryPersistence = Mock()
  90
  91     @SpringBean
  92     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  93
  94     @SpringBean
  95     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  96
  97     @SpringBean
  98     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  99
 100     @SpringBean
 101     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
 102
 103     @SpringBean
 104     DeprecationHelper stubbedDeprecationHelper = Stub()
 105
 106     @SpringBean
 107     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 108
 109     @SpringBean
 110     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 111
 112     @SpringBean
 113     DataJobControllerForTest stubbedDataJobControllerForTest = Stub()
 114
 115     @SpringBean
 116     RestOutputCmHandleMapper mockRestOutputCmHandleMapper = Mock()
 117
 118     @SpringBean
 119     ProvMnSParametersMapper provMnSParametersMapper = Mock()
 120
 121     @SpringBean
 122     AlternateIdMatcher alternateIdMatcher = Mock()
 123
 124     @SpringBean
 125     DmiRestClient dmiRestClient = Mock()
 126
 127     @SpringBean
 128     PolicyExecutor policyExecutor = Mock()
 129
 130     @Value('${rest.api.ncmp-base-path}')
 131     def basePathNcmp
 132
 133     @Value('${rest.api.ncmp-inventory-base-path}')
 134     def basePathNcmpInventory
 135
 136     def dataNodeBaseEndpointNcmp
 137     def dataNodeBaseEndpointNcmpInventory
 138
 139     @Shared
 140     def sampleErrorMessage = 'some error message'
 141     @Shared
 142     def sampleErrorDetails = 'some error details'
 143
 144     def setup() {
 145         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 146         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 147     }
 148
 149     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 150         when: 'an exception is thrown by the service'
 151             setupTestException(exception, NCMP)
 152             def response = performTestRequest(NCMP)
 153         then: 'an HTTP response is returned with correct message and details'
 154             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 155         where:
 156             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 157             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 158             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 159             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 160             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 161             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 162             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 163             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 164             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 165             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 166             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 167             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 168             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 169             'Invalid Path'          | new InvalidPathException("some invalid path")                             || UNPROCESSABLE_ENTITY  | 'not a valid path'          | 'some invalid path not a valid path'
 170     }
 171
 172     def 'Post request with exception returns correct HTTP Status.'() {
 173         given: 'the service throws data validation exception'
 174             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 175             setupTestException(exception, NCMPINVENTORY)
 176         when: 'the HTTP request is made'
 177             def response = performTestRequest(NCMPINVENTORY)
 178         then: 'an HTTP response is returned with correct message and details'
 179             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 180     }
 181
 182     def 'Failing DMI Request - passthrough scenario'() {
 183         given: 'failing DMI request'
 184             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 185         when: 'the DMI request is executed'
 186             def response = performTestRequest(NCMP)
 187         then: 'NCMP service responds with 502 Bad Gateway status'
 188             response.status == BAD_GATEWAY.value()
 189         and: 'the NCMP response also contains the original DMI response details'
 190             response.contentAsString.contains('400')
 191             response.contentAsString.contains('Bad Request from DMI')
 192     }
 193
 194     def setupTestException(exception, apiType) {
 195         if (NCMP == apiType) {
 196             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 197         }
 198         mockNetworkCmProxyInventoryFacade.updateDmiRegistration(*_) >> { throw exception }
 199     }
 200
 201     def performTestRequest(apiType) {
 202         if (NCMP == apiType) {
 203             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 204         }
 205         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 206         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 207     }
 208
 209     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 210         assert response.status == expectedStatus.value()
 211         def content = new JsonSlurper().parseText(response.contentAsString)
 212         assert content['status'].toString().contains(expectedStatus.toString())
 213         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 214         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 215     }
 216
 217     enum ApiType { NCMP,  NCMPINVENTORY  }
 218 }