gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2025 OpenInfra Foundation Europe. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.impl.NetworkCmProxyInventoryFacadeImpl
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  39 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  40 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  41 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  42 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  43 import org.onap.cps.api.exceptions.AlreadyDefinedException
  44 import org.onap.cps.api.exceptions.CpsException
  45 import org.onap.cps.api.exceptions.DataNodeNotFoundException
  46 import org.onap.cps.api.exceptions.DataValidationException
  47 import org.onap.cps.utils.JsonObjectMapper
  48 import org.spockframework.spring.SpringBean
  49 import org.springframework.beans.factory.annotation.Autowired
  50 import org.springframework.beans.factory.annotation.Value
  51 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  52 import org.springframework.http.MediaType
  53 import org.springframework.test.web.servlet.MockMvc
  54 import spock.lang.Shared
  55 import spock.lang.Specification
  56
  57 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  58 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  59 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  60 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  61 import static org.springframework.http.HttpStatus.BAD_REQUEST
  62 import static org.springframework.http.HttpStatus.CONFLICT
  63 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  64 import static org.springframework.http.HttpStatus.NOT_FOUND
  65 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  66 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  67 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  68
  69 @WebMvcTest
  70 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  71
  72     @Autowired
  73     MockMvc mvc
  74
  75     @SpringBean
  76     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  77
  78     @SpringBean
  79     NetworkCmProxyInventoryFacadeImpl mockNetworkCmProxyInventoryFacade = Mock()
  80
  81     @SpringBean
  82     InventoryPersistence mockInventoryPersistence = Mock()
  83
  84     @SpringBean
  85     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  86
  87     @SpringBean
  88     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  89
  90     @SpringBean
  91     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  92
  93     @SpringBean
  94     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
  95
  96     @SpringBean
  97     DeprecationHelper stubbedDeprecationHelper = Stub()
  98
  99     @SpringBean
 100     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 101
 102     @SpringBean
 103     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 104
 105     @SpringBean
 106     DataJobControllerForTest stubbedDataJobControllerForTest = Stub()
 107
 108     @Value('${rest.api.ncmp-base-path}')
 109     def basePathNcmp
 110
 111     @Value('${rest.api.ncmp-inventory-base-path}')
 112     def basePathNcmpInventory
 113
 114     def dataNodeBaseEndpointNcmp
 115     def dataNodeBaseEndpointNcmpInventory
 116
 117     @Shared
 118     def sampleErrorMessage = 'some error message'
 119     @Shared
 120     def sampleErrorDetails = 'some error details'
 121
 122     def setup() {
 123         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 124         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 125     }
 126
 127     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 128         when: 'an exception is thrown by the service'
 129             setupTestException(exception, NCMP)
 130             def response = performTestRequest(NCMP)
 131         then: 'an HTTP response is returned with correct message and details'
 132             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 133         where:
 134             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 135             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 136             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 137             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 138             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 139             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 140             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 141             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 142             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 143             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 144             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 145             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 146             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 147     }
 148
 149     def 'Post request with exception returns correct HTTP Status.'() {
 150         given: 'the service throws data validation exception'
 151             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 152             setupTestException(exception, NCMPINVENTORY)
 153         when: 'the HTTP request is made'
 154             def response = performTestRequest(NCMPINVENTORY)
 155         then: 'an HTTP response is returned with correct message and details'
 156             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 157     }
 158
 159     def 'Failing DMI Request - passthrough scenario'() {
 160         given: 'failing DMI request'
 161             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 162         when: 'the DMI request is executed'
 163             def response = performTestRequest(NCMP)
 164         then: 'NCMP service responds with 502 Bad Gateway status'
 165             response.status == BAD_GATEWAY.value()
 166         and: 'the NCMP response also contains the original DMI response details'
 167             response.contentAsString.contains('400')
 168             response.contentAsString.contains('Bad Request from DMI')
 169     }
 170
 171     def setupTestException(exception, apiType) {
 172         if (NCMP == apiType) {
 173             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 174         }
 175         mockNetworkCmProxyInventoryFacade.updateDmiRegistration(*_) >> { throw exception }
 176     }
 177
 178     def performTestRequest(apiType) {
 179         if (NCMP == apiType) {
 180             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 181         }
 182         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 183         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 184     }
 185
 186     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 187         assert response.status == expectedStatus.value()
 188         def content = new JsonSlurper().parseText(response.contentAsString)
 189         assert content['status'].toString().contains(expectedStatus.toString())
 190         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 191         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 192     }
 193
 194     enum ApiType { NCMP,  NCMPINVENTORY  }
 195 }