gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2025 OpenInfra Foundation Europe. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.controller
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.data.exceptions.InvalidOperationException
  28 import org.onap.cps.ncmp.api.data.exceptions.OperationNotSupportedException
  29 import org.onap.cps.ncmp.api.exceptions.DmiClientRequestException
  30 import org.onap.cps.ncmp.api.exceptions.DmiRequestException
  31 import org.onap.cps.ncmp.api.exceptions.PayloadTooLargeException
  32 import org.onap.cps.ncmp.api.exceptions.PolicyExecutorException
  33 import org.onap.cps.ncmp.api.exceptions.ServerNcmpException
  34 import org.onap.cps.ncmp.impl.NetworkCmProxyInventoryFacadeImpl
  35 import org.onap.cps.ncmp.impl.data.NcmpCachedResourceRequestHandler
  36 import org.onap.cps.ncmp.impl.data.NcmpPassthroughResourceRequestHandler
  37 import org.onap.cps.ncmp.impl.data.NetworkCmProxyFacade
  38 import org.onap.cps.ncmp.impl.dmi.DmiRestClient
  39 import org.onap.cps.ncmp.impl.inventory.InventoryPersistence
  40 import org.onap.cps.ncmp.impl.utils.AlternateIdMatcher
  41 import org.onap.cps.ncmp.rest.provmns.exception.InvalidPathException
  42 import org.onap.cps.ncmp.rest.util.CmHandleStateMapper
  43 import org.onap.cps.ncmp.rest.util.DataOperationRequestMapper
  44 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  45 import org.onap.cps.ncmp.rest.util.NcmpRestInputMapper
  46 import org.onap.cps.api.exceptions.AlreadyDefinedException
  47 import org.onap.cps.api.exceptions.CpsException
  48 import org.onap.cps.api.exceptions.DataNodeNotFoundException
  49 import org.onap.cps.api.exceptions.DataValidationException
  50 import org.onap.cps.ncmp.rest.util.ProvMnSParametersMapper
  51 import org.onap.cps.ncmp.rest.util.RestOutputCmHandleMapper
  52 import org.onap.cps.utils.JsonObjectMapper
  53 import org.spockframework.spring.SpringBean
  54 import org.springframework.beans.factory.annotation.Autowired
  55 import org.springframework.beans.factory.annotation.Value
  56 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  57 import org.springframework.http.MediaType
  58 import org.springframework.test.web.servlet.MockMvc
  59 import spock.lang.Shared
  60 import spock.lang.Specification
  61
  62 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  63 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  64 import static org.onap.cps.ncmp.rest.controller.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  65 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  66 import static org.springframework.http.HttpStatus.BAD_REQUEST
  67 import static org.springframework.http.HttpStatus.CONFLICT
  68 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  69 import static org.springframework.http.HttpStatus.NOT_FOUND
  70 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  71 import static org.springframework.http.HttpStatus.UNPROCESSABLE_ENTITY
  72 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  73 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  74
  75 @WebMvcTest
  76 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  77
  78     @Autowired
  79     MockMvc mvc
  80
  81     @SpringBean
  82     NetworkCmProxyFacade mockNetworkCmProxyFacade = Mock()
  83
  84     @SpringBean
  85     NetworkCmProxyInventoryFacadeImpl mockNetworkCmProxyInventoryFacade = Mock()
  86
  87     @SpringBean
  88     InventoryPersistence mockInventoryPersistence = Mock()
  89
  90     @SpringBean
  91     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  92
  93     @SpringBean
  94     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  95
  96     @SpringBean
  97     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  98
  99     @SpringBean
 100     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
 101
 102     @SpringBean
 103     DeprecationHelper stubbedDeprecationHelper = Stub()
 104
 105     @SpringBean
 106     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
 107
 108     @SpringBean
 109     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
 110
 111     @SpringBean
 112     DataJobControllerForTest stubbedDataJobControllerForTest = Stub()
 113
 114     @SpringBean
 115     RestOutputCmHandleMapper mockRestOutputCmHandleMapper = Mock()
 116
 117     @SpringBean
 118     ProvMnSParametersMapper provMnSParametersMapper = Mock()
 119
 120     @SpringBean
 121     AlternateIdMatcher alternateIdMatcher = Mock()
 122
 123     @SpringBean
 124     DmiRestClient dmiRestClient = Mock()
 125
 126     @Value('${rest.api.ncmp-base-path}')
 127     def basePathNcmp
 128
 129     @Value('${rest.api.ncmp-inventory-base-path}')
 130     def basePathNcmpInventory
 131
 132     def dataNodeBaseEndpointNcmp
 133     def dataNodeBaseEndpointNcmpInventory
 134
 135     @Shared
 136     def sampleErrorMessage = 'some error message'
 137     @Shared
 138     def sampleErrorDetails = 'some error details'
 139
 140     def setup() {
 141         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 142         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 143     }
 144
 145     def 'Get request with #scenario exception returns correct HTTP Status with #scenario exception'() {
 146         when: 'an exception is thrown by the service'
 147             setupTestException(exception, NCMP)
 148             def response = performTestRequest(NCMP)
 149         then: 'an HTTP response is returned with correct message and details'
 150             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 151         where:
 152             scenario                | exception                                                                 || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 153             'CPS'                   | new CpsException(sampleErrorMessage, sampleErrorDetails)                  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 154             'NCMP-server'           | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)           || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 155             'DMI Request'           | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)           || BAD_REQUEST           | sampleErrorMessage          | null
 156             'Invalid Operation'     | new InvalidOperationException('some reason')                              || BAD_REQUEST           | 'some reason'               | null
 157             'Unsupported Operation' | new OperationNotSupportedException('not yet')                             || BAD_REQUEST           | 'not yet'                   | null
 158             'DataNode Validation'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | null
 159             'other'                 | new IllegalStateException(sampleErrorMessage)                             || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 160             'Data Node Not Found'   | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName')          || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 161             'Existing entry'        | new AlreadyDefinedException('name',null)                                  || CONFLICT              | 'Already defined exception' | 'name already exists'
 162             'Existing entries'      | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName')          || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 163             'Operation too large'   | new PayloadTooLargeException(sampleErrorMessage)                          || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 164             'Policy Executor'       | new PolicyExecutorException(sampleErrorMessage, sampleErrorDetails, null) || CONFLICT              | sampleErrorMessage          | sampleErrorDetails
 165             'Invalid Path'          | new InvalidPathException("some invalid path")                             || UNPROCESSABLE_ENTITY  | 'not a valid path'          | 'some invalid path not a valid path'
 166     }
 167
 168     def 'Post request with exception returns correct HTTP Status.'() {
 169         given: 'the service throws data validation exception'
 170             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 171             setupTestException(exception, NCMPINVENTORY)
 172         when: 'the HTTP request is made'
 173             def response = performTestRequest(NCMPINVENTORY)
 174         then: 'an HTTP response is returned with correct message and details'
 175             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 176     }
 177
 178     def 'Failing DMI Request - passthrough scenario'() {
 179         given: 'failing DMI request'
 180             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 181         when: 'the DMI request is executed'
 182             def response = performTestRequest(NCMP)
 183         then: 'NCMP service responds with 502 Bad Gateway status'
 184             response.status == BAD_GATEWAY.value()
 185         and: 'the NCMP response also contains the original DMI response details'
 186             response.contentAsString.contains('400')
 187             response.contentAsString.contains('Bad Request from DMI')
 188     }
 189
 190     def setupTestException(exception, apiType) {
 191         if (NCMP == apiType) {
 192             mockNetworkCmProxyInventoryFacade.getYangResourcesModuleReferences(*_) >> { throw exception }
 193         }
 194         mockNetworkCmProxyInventoryFacade.updateDmiRegistration(*_) >> { throw exception }
 195     }
 196
 197     def performTestRequest(apiType) {
 198         if (NCMP == apiType) {
 199             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 200         }
 201         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 202         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 203     }
 204
 205     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 206         assert response.status == expectedStatus.value()
 207         def content = new JsonSlurper().parseText(response.contentAsString)
 208         assert content['status'].toString().contains(expectedStatus.toString())
 209         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 210         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 211     }
 212
 213     enum ApiType { NCMP,  NCMPINVENTORY  }
 214 }