gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2024 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.exceptions
  23
  24 import static org.springframework.http.HttpStatus.BAD_GATEWAY
  25 import static org.springframework.http.HttpStatus.BAD_REQUEST
  26 import static org.springframework.http.HttpStatus.CONFLICT
  27 import static org.springframework.http.HttpStatus.INTERNAL_SERVER_ERROR
  28 import static org.springframework.http.HttpStatus.NOT_FOUND
  29 import static org.springframework.http.HttpStatus.PAYLOAD_TOO_LARGE
  30 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  31 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  32 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  33 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  34 import static org.onap.cps.ncmp.api.NcmpResponseStatus.UNABLE_TO_READ_RESOURCE_DATA
  35
  36 import groovy.json.JsonSlurper
  37 import org.mapstruct.factory.Mappers
  38 import org.onap.cps.TestUtils
  39 import org.onap.cps.ncmp.api.NetworkCmProxyDataService
  40 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  41 import org.onap.cps.ncmp.api.impl.exception.DmiClientRequestException
  42 import org.onap.cps.ncmp.api.impl.exception.ServerNcmpException
  43 import org.onap.cps.ncmp.rest.controller.NcmpRestInputMapper
  44 import org.onap.cps.ncmp.rest.controller.handlers.NcmpCachedResourceRequestHandler
  45 import org.onap.cps.ncmp.rest.controller.handlers.NcmpPassthroughResourceRequestHandler
  46 import org.onap.cps.ncmp.rest.mapper.CmHandleStateMapper
  47 import org.onap.cps.ncmp.rest.mapper.DataOperationRequestMapper
  48 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  49 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  50 import org.onap.cps.spi.exceptions.CpsException
  51 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  52 import org.onap.cps.spi.exceptions.DataValidationException
  53 import org.onap.cps.utils.JsonObjectMapper
  54 import org.spockframework.spring.SpringBean
  55 import org.springframework.beans.factory.annotation.Autowired
  56 import org.springframework.beans.factory.annotation.Value
  57 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  58 import org.springframework.http.MediaType
  59 import org.springframework.test.web.servlet.MockMvc
  60 import spock.lang.Shared
  61 import spock.lang.Specification
  62
  63 @WebMvcTest
  64 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  65
  66     @Autowired
  67     MockMvc mvc
  68
  69     @SpringBean
  70     NetworkCmProxyDataService mockNetworkCmProxyDataService = Mock()
  71
  72     @SpringBean
  73     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  74
  75     @SpringBean
  76     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  77
  78     @SpringBean
  79     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  80
  81     @SpringBean
  82     DataOperationRequestMapper dataOperationRequestMapper = Mappers.getMapper(DataOperationRequestMapper)
  83
  84     @SpringBean
  85     DeprecationHelper stubbedDeprecationHelper = Stub()
  86
  87     @SpringBean
  88     NcmpCachedResourceRequestHandler stubbedNcmpCachedResourceRequestHandler = Stub()
  89
  90     @SpringBean
  91     NcmpPassthroughResourceRequestHandler StubbedNcmpPassthroughResourceRequestHandler = Stub()
  92
  93     @Value('${rest.api.ncmp-base-path}')
  94     def basePathNcmp
  95
  96     @Value('${rest.api.ncmp-inventory-base-path}')
  97     def basePathNcmpInventory
  98
  99     def dataNodeBaseEndpointNcmp
 100     def dataNodeBaseEndpointNcmpInventory
 101
 102     @Shared
 103     def sampleErrorMessage = 'some error message'
 104     @Shared
 105     def sampleErrorDetails = 'some error details'
 106
 107     def setup() {
 108         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 109         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 110     }
 111
 112     def 'Get request with #scenario exception returns correct HTTP Status with #scenario'() {
 113         when: 'an exception is thrown by the service'
 114             setupTestException(exception, NCMP)
 115             def response = performTestRequest(NCMP)
 116         then: 'an HTTP response is returned with correct message and details'
 117             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 118         where:
 119             scenario              | exception                                                        || expectedErrorCode     | expectedErrorMessage        | expectedErrorDetails
 120             'CPS'                 | new CpsException(sampleErrorMessage, sampleErrorDetails)         || INTERNAL_SERVER_ERROR | sampleErrorMessage          | sampleErrorDetails
 121             'NCMP-server'         | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)  || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 122             'NCMP-client'         | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)  || BAD_REQUEST           | sampleErrorMessage          | null
 123             'DataNode Validation' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || NOT_FOUND             | 'DataNode not found'        | null
 124             'other'               | new IllegalStateException(sampleErrorMessage)                    || INTERNAL_SERVER_ERROR | sampleErrorMessage          | null
 125             'Data Node Not Found' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || NOT_FOUND             | 'DataNode not found'        | 'DataNode not found'
 126             'Existing entry'      | new AlreadyDefinedException('name',null)                         || CONFLICT              | 'Already defined exception' | 'name already exists'
 127             'Existing entries'    | AlreadyDefinedException.forDataNodes(['A', 'B'], 'myAnchorName') || CONFLICT              | 'Already defined exception' | '2 data node(s) already exist'
 128             'Operation too large' | new PayloadTooLargeException(sampleErrorMessage)                 || PAYLOAD_TOO_LARGE     | sampleErrorMessage          | 'Check logs'
 129     }
 130
 131     def 'Post request with exception returns correct HTTP Status.'() {
 132         given: 'the service throws data validation exception'
 133             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 134             setupTestException(exception, NCMPINVENTORY)
 135         when: 'the HTTP request is made'
 136             def response = performTestRequest(NCMPINVENTORY)
 137         then: 'an HTTP response is returned with correct message and details'
 138             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 139     }
 140
 141     def 'Failing DMI Request - passthrough scenario'() {
 142         given: 'failing DMI request'
 143             setupTestException(new DmiClientRequestException(400, 'Error Message Details NCMP', 'Bad Request from DMI', UNABLE_TO_READ_RESOURCE_DATA), NCMP)
 144         when: 'the DMI request is executed'
 145             def response = performTestRequest(NCMP)
 146         then: 'NCMP service responds with 502 Bad Gateway status'
 147             response.status == BAD_GATEWAY.value()
 148         and: 'the NCMP response also contains the original DMI response details'
 149             response.contentAsString.contains('400')
 150             response.contentAsString.contains('Bad Request from DMI')
 151     }
 152
 153     def setupTestException(exception, apiType) {
 154         if (NCMP == apiType) {
 155             mockNetworkCmProxyDataService.getYangResourcesModuleReferences(*_) >> { throw exception }
 156         }
 157         mockNetworkCmProxyDataService.updateDmiRegistrationAndSyncModule(*_) >> { throw exception }
 158     }
 159
 160     def performTestRequest(apiType) {
 161         if (NCMP == apiType) {
 162             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 163         }
 164         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 165         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 166     }
 167
 168     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 169         assert response.status == expectedStatus.value()
 170         def content = new JsonSlurper().parseText(response.contentAsString)
 171         assert content['status'].toString().contains(expectedStatus.toString())
 172         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 173         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 174     }
 175
 176     enum ApiType {
 177         NCMP,
 178         NCMPINVENTORY;
 179     }
 180 }