gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022-2024 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.impl.inventory
  23
  24 import com.hazelcast.config.Config
  25 import com.hazelcast.core.Hazelcast
  26 import com.hazelcast.instance.impl.HazelcastInstanceFactory
  27 import org.onap.cps.api.CpsDataService
  28 import org.onap.cps.api.CpsQueryService
  29 import org.onap.cps.impl.utils.CpsValidator
  30 import org.onap.cps.ncmp.api.inventory.models.TrustLevel
  31 import org.onap.cps.ncmp.impl.inventory.models.CmHandleState
  32 import org.onap.cps.api.model.DataNode
  33 import spock.lang.Specification
  34
  35 import static org.onap.cps.ncmp.impl.inventory.NcmpPersistence.NCMP_DATASPACE_NAME
  36 import static org.onap.cps.ncmp.impl.inventory.NcmpPersistence.NCMP_DMI_REGISTRY_ANCHOR
  37 import static org.onap.cps.ncmp.impl.inventory.NcmpPersistence.NCMP_DMI_REGISTRY_PARENT
  38 import static org.onap.cps.api.parameters.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  39 import static org.onap.cps.api.parameters.FetchDescendantsOption.OMIT_DESCENDANTS
  40
  41 class CmHandleQueryServiceImplSpec extends Specification {
  42
  43     def mockCpsQueryService = Mock(CpsQueryService)
  44     def mockCpsDataService = Mock(CpsDataService)
  45     def trustLevelPerDmiPlugin = HazelcastInstanceFactory.getOrCreateHazelcastInstance(new Config('hazelcastInstanceName')).getMap('trustLevelPerDmiPlugin')
  46     def trustLevelPerCmHandleId = HazelcastInstanceFactory.getOrCreateHazelcastInstance(new Config('hazelcastInstanceName')).getMap('trustLevelPerCmHandleId')
  47     def mockCpsValidator = Mock(CpsValidator)
  48
  49     def objectUnderTest = new CmHandleQueryServiceImpl(mockCpsDataService, mockCpsQueryService, trustLevelPerDmiPlugin, trustLevelPerCmHandleId, mockCpsValidator)
  50     def static sampleDataNodes = [new DataNode(xpath: "/dmi-registry/cm-handles[@id='ch-1']"),
  51                                   new DataNode(xpath: "/dmi-registry/cm-handles[@id='ch-2']")]
  52
  53     def dataNodeWithPrivateField = '//additional-properties[@name=\"Contact3\" and @value=\"newemailforstore3@bookstore.com\"]/ancestor::cm-handles'
  54
  55     def static pnfDemo = createDataNode('PNFDemo')
  56     def static pnfDemo2 = createDataNode('PNFDemo2')
  57     def static pnfDemo3 = createDataNode('PNFDemo3')
  58     def static pnfDemo4 = createDataNode('PNFDemo4')
  59     def static pnfDemo5 = createDataNode('PNFDemo5')
  60
  61     def setup() {
  62         trustLevelPerCmHandleId.put("PNFDemo", TrustLevel.COMPLETE)
  63         trustLevelPerCmHandleId.put("PNFDemo2", TrustLevel.NONE)
  64         trustLevelPerCmHandleId.put("PNFDemo4", TrustLevel.NONE)
  65     }
  66
  67     def cleanupSpec() {
  68         Hazelcast.getHazelcastInstanceByName('hazelcastInstanceName').shutdown()
  69     }
  70
  71     def 'Query CmHandles with public properties query pair.'() {
  72         given: 'the DataNodes queried for a given cpsPath are returned from the persistence service.'
  73             mockResponses()
  74         when: 'a query on cmhandle public properties is performed with a public property pair'
  75             def result = objectUnderTest.queryCmHandlePublicProperties(publicPropertyPairs, outputAlternateId)
  76         then: 'the correct cm handle data objects are returned'
  77             result.containsAll(expectedCmHandleReferences)
  78             result.size() == expectedCmHandleReferences.size()
  79         where: 'the following data is used'
  80             scenario                         | publicPropertyPairs                                                                      | outputAlternateId || expectedCmHandleReferences
  81             'single property matches'        | [Contact: 'newemailforstore@bookstore.com']                                              | false             || ['PNFDemo', 'PNFDemo2', 'PNFDemo4']
  82             'public property does not match' | [wont_match: 'wont_match']                                                               | false             || []
  83             '2 properties, only one match'   | [Contact: 'newemailforstore@bookstore.com', Contact2: 'newemailforstore2@bookstore.com'] | true              || ['alt-PNFDemo4']
  84             '2 properties, no matches'       | [Contact: 'newemailforstore@bookstore.com', Contact2: '']                                | false             || []
  85     }
  86
  87     def 'Query cm handles on trust level'() {
  88         given: 'query properties for trust level COMPLETE'
  89             def trustLevelPropertyQueryPairs = ['trustLevel' : TrustLevel.COMPLETE.toString()]
  90         and: 'the dmi cache has been initialised and "knows" about my-dmi-plugin-identifier'
  91             trustLevelPerDmiPlugin.put('my-dmi-plugin-identifier', TrustLevel.COMPLETE)
  92         and: 'the DataNodes queried for a given cpsPath are returned from the persistence service'
  93             mockResponses()
  94         when: 'the query is run'
  95             def result = objectUnderTest.queryCmHandlesByTrustLevel(trustLevelPropertyQueryPairs, outputAlternateId)
  96         then: 'the result contain trusted cmHandle reference'
  97             assert result.size() == 1
  98             assert result[0] == expectedCmHandleReference
  99         where: 'the following data is used'
 100             senario               | outputAlternateId | expectedCmHandleReference
 101             'output cmHandleId'   |  false            | 'PNFDemo'
 102             'output AlternateId'  |  true             | 'alt-PNFDemo'
 103     }
 104
 105     def 'Query CmHandles using empty public properties query pair.'() {
 106         when: 'a query on CmHandle public properties is executed using an empty map'
 107             def result = objectUnderTest.queryCmHandlePublicProperties([:], false)
 108         then: 'no cm handles are returned'
 109             result.size() == 0
 110     }
 111
 112     def 'Query CmHandles using empty private properties query pair.'() {
 113         when: 'a query on CmHandle private properties is executed using an empty map'
 114             def result = objectUnderTest.queryCmHandleAdditionalProperties([:], false)
 115         then: 'no cm handles are returned'
 116             result.size() == 0
 117     }
 118
 119     def 'Query CmHandles by a private field\'s value.'() {
 120         given: 'a data node exists with a certain additional-property'
 121             mockCpsQueryService.queryDataNodes(_, _, dataNodeWithPrivateField, _) >> [pnfDemo5]
 122         when: 'a query on CmHandle private properties is executed using a map'
 123             def result = objectUnderTest.queryCmHandleAdditionalProperties(['Contact3': 'newemailforstore3@bookstore.com'], false)
 124         then: 'one cm handle is returned'
 125             result.size() == 1
 126     }
 127
 128     def 'Get Ids of CmHandles by state.'() {
 129         given: 'a cm handle state to query'
 130             def cmHandleState = CmHandleState.ADVISED
 131         and: 'the persistence service returns a list of data nodes'
 132             mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 133                 "//state[@cm-handle-state='ADVISED']", OMIT_DESCENDANTS) >> sampleDataNodes
 134         when: 'cm handles are fetched by state'
 135             def result = objectUnderTest.queryCmHandleIdsByState(cmHandleState)
 136         then: 'the returned result matches the result from the persistence service'
 137             assert result.toSet() == ['ch-1', 'ch-2'].toSet()
 138     }
 139
 140     def 'Check the state of a cmHandle when #scenario.'() {
 141         given: 'a cm handle state to compare'
 142             def cmHandleState = state
 143         and: 'the persistence service returns a list of data nodes'
 144             mockCpsDataService.getDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 145                     NCMP_DMI_REGISTRY_PARENT + '/cm-handles[@id=\'some-cm-handle\']/state',
 146                     OMIT_DESCENDANTS) >> [new DataNode(leaves: ['cm-handle-state': 'READY'])]
 147         when: 'cm handles are compared by state'
 148             def result = objectUnderTest.cmHandleHasState('some-cm-handle', cmHandleState)
 149         then: 'the returned result matches the expected result from the persistence service'
 150             result == expectedResult
 151         where:
 152             scenario                           | state                 || expectedResult
 153             'the provided state matches'       | CmHandleState.READY   || true
 154             'the provided state does not match'| CmHandleState.DELETED || false
 155     }
 156
 157     def 'Get Cm Handles state by Cm-Handle Id'() {
 158         given: 'a cm handle state to query'
 159             def cmHandleState = CmHandleState.READY
 160         and: 'cps data service returns a list of data nodes'
 161             mockCpsDataService.getDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 162                     NCMP_DMI_REGISTRY_PARENT + '/cm-handles[@id=\'some-cm-handle\']/state',
 163                     OMIT_DESCENDANTS) >> [new DataNode(leaves: ['cm-handle-state': 'READY'])]
 164         when: 'cm handles are fetched by state and id'
 165             def result = objectUnderTest.getCmHandleState('some-cm-handle')
 166         then: 'the returned result is a list of data nodes returned by cps data service'
 167             assert result == new DataNode(leaves: ['cm-handle-state': 'READY'])
 168     }
 169
 170     def 'Retrieve Cm Handles By Operational Sync State : UNSYNCHRONIZED'() {
 171         given: 'a cm handle state to query'
 172             def cmHandleState = CmHandleState.READY
 173         and: 'cps data service returns a list of data nodes'
 174             mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 175                 '//state/datastores/operational[@sync-state="'+'UNSYNCHRONIZED'+'"]/ancestor::cm-handles', OMIT_DESCENDANTS) >> sampleDataNodes
 176         when: 'cm handles are fetched by the UNSYNCHRONIZED operational sync state'
 177             def result = objectUnderTest.queryCmHandlesByOperationalSyncState(DataStoreSyncState.UNSYNCHRONIZED)
 178         then: 'the returned result is a list of data nodes returned by cps data service'
 179             assert result == sampleDataNodes
 180     }
 181
 182     def 'Retrieve cm handle by cps path '() {
 183         given: 'a cm handle state to query based on the cps path'
 184             def cmHandleDataNode = new DataNode(xpath: "/dmi-registry/cm-handles[@id='ch-1']", leaves: ['id': 'ch-1'])
 185             def cpsPath = "//state[@cm-handle-state='LOCKED']"
 186         and: 'cps data service returns a valid data node for cm handle ancestor'
 187             mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 188                 cpsPath + '/ancestor::cm-handles', INCLUDE_ALL_DESCENDANTS)
 189                 >> Arrays.asList(cmHandleDataNode)
 190         when: 'get cm handles by cps path is invoked'
 191             def result = objectUnderTest.queryCmHandleAncestorsByCpsPath(cpsPath, INCLUDE_ALL_DESCENDANTS)
 192         then: 'the returned result is a list of data nodes returned by cps data service'
 193             assert result.contains(cmHandleDataNode)
 194     }
 195
 196     def 'Retrieve cm handle by cps path querying cm handle directly'() {
 197         given: 'a cm handle to query based on the cps path'
 198             def cmHandleDataNode = new DataNode(xpath: "/dmi-registry/cm-handles[@id='ch-2']", leaves: ['id': 'ch-2'])
 199             def cpsPath = "//cm-handles[@alternate-id='1']"
 200         and: 'cps data service returns a valid data node'
 201             mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR,
 202                     cpsPath, INCLUDE_ALL_DESCENDANTS)
 203                     >> Arrays.asList(cmHandleDataNode)
 204         when: 'get cm handles by cps path is invoked'
 205             def result = objectUnderTest.queryCmHandleAncestorsByCpsPath(cpsPath, INCLUDE_ALL_DESCENDANTS)
 206         then: 'the returned result is a list of data nodes returned by cps data service'
 207             assert result.contains(cmHandleDataNode)
 208     }
 209
 210     def 'Get all cm handles by dmi plugin identifier and alternate id output option where #scenario'() {
 211         given: 'the DataNodes queried for a given cpsPath are returned from the persistence service.'
 212             mockResponses()
 213         when: 'cm Handles are fetched for a given dmi plugin identifier and alternate id output option'
 214             def result = objectUnderTest.getCmHandleReferencesByDmiPluginIdentifier('my-dmi-plugin-identifier', outputAlternateId)
 215         then: 'result is the correct size'
 216             assert result.size() == 3
 217         and: 'result contains the correct cm handles'
 218             assert result.containsAll(expectedResult)
 219         where:
 220             scenario                        | outputAlternateId || expectedResult
 221             'output is for alternate ids'   | true              || ['alt-PNFDemo', 'alt-PNFDemo2', 'alt-PNFDemo4']
 222             'output is for cm handle ids'   | false             || ['PNFDemo', 'PNFDemo2', 'PNFDemo4']
 223     }
 224
 225     def 'Get all alternateIds by dmi plugin identifier'() {
 226         given: 'the DataNodes queried for a given cpsPath are returned from the persistence service.'
 227             mockResponses()
 228         when: 'cm Handles are fetched for a given dmi plugin identifier'
 229             def result = objectUnderTest.getCmHandleReferencesMapByDmiPluginIdentifier('my-dmi-plugin-identifier').values()
 230         then: 'result is the correct size'
 231             assert result.size() == 3
 232         and: 'result contains the correct alternate Ids'
 233             assert result.containsAll('alt-PNFDemo', 'alt-PNFDemo2', 'alt-PNFDemo4')
 234     }
 235
 236     void mockResponses() {
 237         mockCpsQueryService.queryDataNodes(_, _, '//public-properties[@name=\"Contact\" and @value=\"newemailforstore@bookstore.com\"]/ancestor::cm-handles', _) >> [pnfDemo, pnfDemo2, pnfDemo4]
 238         mockCpsQueryService.queryDataNodes(_, _, '//public-properties[@name=\"wont_match\" and @value=\"wont_match\"]/ancestor::cm-handles', _) >> []
 239         mockCpsQueryService.queryDataNodes(_, _, '//public-properties[@name=\"Contact2\" and @value=\"newemailforstore2@bookstore.com\"]/ancestor::cm-handles', _) >> [pnfDemo4]
 240         mockCpsQueryService.queryDataNodes(_, _, '//public-properties[@name=\"Contact2\" and @value=\"\"]/ancestor::cm-handles', _) >> []
 241         mockCpsQueryService.queryDataNodes(_, _, '//state[@cm-handle-state=\"READY\"]/ancestor::cm-handles', _) >> [pnfDemo, pnfDemo3]
 242         mockCpsQueryService.queryDataNodes(_, _, '//state[@cm-handle-state=\"LOCKED\"]/ancestor::cm-handles', _) >> [pnfDemo2, pnfDemo4]
 243         mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR, '/dmi-registry/cm-handles[@dmi-service-name=\'my-dmi-plugin-identifier\']', OMIT_DESCENDANTS) >> [pnfDemo, pnfDemo2]
 244         mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR, '/dmi-registry/cm-handles[@dmi-data-service-name=\'my-dmi-plugin-identifier\']', OMIT_DESCENDANTS) >> [pnfDemo, pnfDemo4]
 245         mockCpsQueryService.queryDataNodes(NCMP_DATASPACE_NAME, NCMP_DMI_REGISTRY_ANCHOR, '/dmi-registry/cm-handles[@dmi-model-service-name=\'my-dmi-plugin-identifier\']', OMIT_DESCENDANTS) >> [pnfDemo2, pnfDemo4]
 246     }
 247
 248     def static createDataNode(dataNodeId) {
 249         return new DataNode(xpath: '/dmi-registry/cm-handles[@id=\'' + dataNodeId + '\']', leaves: ['id':dataNodeId, 'alternate-id':'alt-' + dataNodeId])
 250     }
 251 }