gerrit.onap Code Review - cps.git/blob

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022-2024 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.impl.inventory
  22
  23 import org.onap.cps.cpspath.parser.PathParsingException
  24 import org.onap.cps.ncmp.api.inventory.models.CmHandleQueryServiceParameters
  25 import org.onap.cps.ncmp.impl.inventory.models.YangModelCmHandle
  26 import org.onap.cps.spi.FetchDescendantsOption
  27 import org.onap.cps.spi.exceptions.DataInUseException
  28 import org.onap.cps.spi.exceptions.DataValidationException
  29 import org.onap.cps.spi.model.ConditionProperties
  30 import org.onap.cps.spi.model.DataNode
  31 import spock.lang.Specification
  32
  33 import static org.onap.cps.ncmp.impl.inventory.NcmpPersistence.NCMP_DMI_REGISTRY_PARENT
  34
  35 class ParameterizedCmHandleQueryServiceSpec extends Specification {
  36
  37     def cmHandleQueries = Mock(CmHandleQueryService)
  38     def partiallyMockedCmHandleQueries = Spy(CmHandleQueryService)
  39     def mockInventoryPersistence = Mock(InventoryPersistence)
  40
  41     def dmiRegistry = new DataNode(xpath: NCMP_DMI_REGISTRY_PARENT, childDataNodes: createDataNodeList(['PNFDemo1', 'PNFDemo2', 'PNFDemo3', 'PNFDemo4']))
  42
  43     def objectUnderTest = new ParameterizedCmHandleQueryServiceImpl(cmHandleQueries, mockInventoryPersistence)
  44     def objectUnderTestWithPartiallyMockedQueries = new ParameterizedCmHandleQueryServiceImpl(partiallyMockedCmHandleQueries, mockInventoryPersistence)
  45
  46     def 'Query cm handle ids with cpsPath.'() {
  47         given: 'a cmHandleWithCpsPath condition property'
  48             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
  49             def conditionProperties = createConditionProperties('cmHandleWithCpsPath', [['cpsPath' : '/some/cps/path']])
  50             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
  51         and: 'the query get the cm handle datanodes excluding all descendants returns a datanode'
  52             cmHandleQueries.queryCmHandleAncestorsByCpsPath('/some/cps/path', FetchDescendantsOption.OMIT_DESCENDANTS) >> [new DataNode(leaves: ['id':'some-cmhandle-id'])]
  53         when: 'the query is executed for cm handle ids'
  54             def result = objectUnderTest.queryCmHandleIds(cmHandleQueryParameters)
  55         then: 'the correct expected cm handles ids are returned'
  56             assert result == ['some-cmhandle-id'] as Set
  57     }
  58
  59     def 'Query cm handle where  cps path itself is ancestor axis.'() {
  60         given: 'a cmHandleWithCpsPath condition property'
  61             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
  62             def conditionProperties = createConditionProperties('cmHandleWithCpsPath', [['cpsPath' : '/some/cps/path']])
  63             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
  64         and: 'the query get the cm handle data nodes excluding all descendants returns a datanode'
  65             cmHandleQueries.queryCmHandleAncestorsByCpsPath('/some/cps/path', FetchDescendantsOption.OMIT_DESCENDANTS) >> [new DataNode(leaves: ['id':'some-cmhandle-id'])]
  66         when: 'the query is executed for cm handle ids'
  67             def result = objectUnderTest.queryCmHandleIdsForInventory(cmHandleQueryParameters)
  68         then: 'the correct expected cm handles ids are returned'
  69             assert result == ['some-cmhandle-id'] as Set
  70     }
  71
  72     def 'Cm handle ids query with error: #scenario.'() {
  73         given: 'a cmHandleWithCpsPath condition property'
  74             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
  75             def conditionProperties = createConditionProperties('cmHandleWithCpsPath', [['cpsPath' : '/some/cps/path']])
  76             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
  77         and: 'cmHandleQueries throws a path parsing exception'
  78             cmHandleQueries.queryCmHandleAncestorsByCpsPath('/some/cps/path', FetchDescendantsOption.OMIT_DESCENDANTS) >> { throw thrownException }
  79         when: 'the query is executed for cm handle ids'
  80             objectUnderTest.queryCmHandleIds(cmHandleQueryParameters)
  81         then: 'a data validation exception is thrown'
  82             thrown(expectedException)
  83         where: 'the following data is used'
  84             scenario               | thrownException                                          || expectedException
  85             'PathParsingException' | new PathParsingException('some message', 'some details') || DataValidationException
  86             'any other Exception'  | new DataInUseException('some message', 'some details')   || DataInUseException
  87     }
  88
  89     def 'Cm handle ids cpsPath query for private properties (not allowed).'() {
  90         given: 'a CpsPath condition property for private properties'
  91             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
  92             def conditionProperties = createConditionProperties('cmHandleWithCpsPath', [['cpsPath' : '/additional-properties']])
  93             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
  94         when: 'the query is executed for cm handle ids'
  95             def result = objectUnderTest.queryCmHandleIds(cmHandleQueryParameters)
  96         then: 'empty result is returned'
  97             assert result.isEmpty()
  98     }
  99
 100     def 'Query cm handle ids with module names when #scenario from query.'() {
 101         given: 'a modules condition property'
 102             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 103             def conditionProperties = createConditionProperties('hasAllModules', [['moduleName': 'some-module-name']])
 104             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
 105         when: 'the query is executed for cm handle ids'
 106             def result = objectUnderTest.queryCmHandleIds(cmHandleQueryParameters)
 107         then: 'the inventory service is called with the correct module names'
 108             1 * mockInventoryPersistence.getCmHandleIdsWithGivenModules(['some-module-name']) >> cmHandleIdsFromService
 109         and: 'the correct expected cm handles ids are returned'
 110             assert result.size() == cmHandleIdsFromService.size()
 111             assert result.containsAll(cmHandleIdsFromService)
 112         where: 'the following data is used'
 113             scenario                  | cmHandleIdsFromService
 114             'One anchor returned'     | ['some-cmhandle-id']
 115             'No anchors are returned' | []
 116     }
 117
 118     def 'Query cm handles with some trust level query parameters'() {
 119         given: 'a trust level condition property'
 120             def trustLevelQueryParameters = new CmHandleQueryServiceParameters()
 121             def trustLevelConditionProperties = createConditionProperties('cmHandleWithTrustLevel', [['trustLevel': 'COMPLETE'] as Map])
 122             trustLevelQueryParameters.setCmHandleQueryParameters([trustLevelConditionProperties])
 123         when: 'the query is being executed'
 124             objectUnderTest.queryCmHandleIds(trustLevelQueryParameters)
 125         then: 'the query is being delegated to the cm handle query service with correct parameter'
 126             1 * cmHandleQueries.queryCmHandlesByTrustLevel(['trustLevel': 'COMPLETE'] as Map)
 127     }
 128
 129     def 'Query cm handle details with module names when #scenario from query.'() {
 130         given: 'a modules condition property'
 131             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 132             def conditionProperties = createConditionProperties('hasAllModules', [['moduleName': 'some-module-name']])
 133             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
 134         when: 'the query is executed for cm handle ids'
 135             def result = objectUnderTest.queryCmHandles(cmHandleQueryParameters)
 136         then: 'the inventory service is called with the correct module names'
 137             1 * mockInventoryPersistence.getCmHandleIdsWithGivenModules(['some-module-name']) >> ['ch1']
 138         and: 'the inventory service is called with teh correct if and returns a yang model cm handle'
 139             1 * mockInventoryPersistence.getYangModelCmHandles(['ch1']) >>
 140                 [new YangModelCmHandle(id: 'abc', dmiProperties: [new YangModelCmHandle.Property('name','value')], publicProperties: [])]
 141         and: 'the expected cm handle(s) are returned as Yang Model cm handles'
 142             assert result[0] instanceof YangModelCmHandle
 143             assert result.size() == 1
 144             assert result[0].dmiProperties.size() == 1
 145     }
 146
 147     def 'Query cm handle ids when the query is empty.'() {
 148         given: 'We use an empty query'
 149             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 150         and: 'the inventory persistence returns the dmi registry datanode with just ids'
 151             mockInventoryPersistence.getDataNode(NCMP_DMI_REGISTRY_PARENT, FetchDescendantsOption.DIRECT_CHILDREN_ONLY) >> [dmiRegistry]
 152         when: 'the query is executed for both cm handle ids'
 153             def result = objectUnderTest.queryCmHandleIds(cmHandleQueryParameters)
 154         then: 'the correct expected cm handles are returned'
 155             assert result.containsAll('PNFDemo1', 'PNFDemo2', 'PNFDemo3', 'PNFDemo4')
 156     }
 157
 158     def 'Query cm handle details when the query is empty.'() {
 159         given: 'We use an empty query'
 160             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 161         and: 'the inventory persistence returns the dmi registry datanode with just ids'
 162             mockInventoryPersistence.getDataNode(NCMP_DMI_REGISTRY_PARENT) >> [dmiRegistry]
 163         when: 'the query is executed for both cm handle details'
 164             def result = objectUnderTest.queryCmHandles(cmHandleQueryParameters)
 165         then: 'the correct cm handles are returned'
 166             assert result.size() == 4
 167             assert result.id.containsAll('PNFDemo1', 'PNFDemo2', 'PNFDemo3', 'PNFDemo4')
 168     }
 169
 170     def 'Query CMHandleId with #scenario.' () {
 171         given: 'a query object created with #condition'
 172             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 173             def conditionProperties = createConditionProperties(conditionName, [['some-key': 'some-value']])
 174             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
 175         and: 'the inventoryPersistence returns different CmHandleIds'
 176             partiallyMockedCmHandleQueries.queryCmHandlePublicProperties(*_) >> cmHandlesWithMatchingPublicProperties
 177             partiallyMockedCmHandleQueries.queryCmHandleAdditionalProperties(*_) >> cmHandlesWithMatchingPrivateProperties
 178         when: 'the query executed'
 179             def result = objectUnderTestWithPartiallyMockedQueries.queryCmHandleIdsForInventory(cmHandleQueryParameters)
 180         then: 'the expected number of results are returned.'
 181             assert result.size() == expectedCmHandleIdsSize
 182         where: 'the following data is used'
 183             scenario                                          | conditionName                | cmHandlesWithMatchingPublicProperties | cmHandlesWithMatchingPrivateProperties || expectedCmHandleIdsSize
 184             'all properties, only public matching'            | 'hasAllProperties'           | ['h1', 'h2']                          | null                                   || 2
 185             'all properties, no matching cm handles'          | 'hasAllProperties'           | []                                    | []                                     || 0
 186             'additional properties, some matching cm handles' | 'hasAllAdditionalProperties' | []                                    | ['h1', 'h2']                           || 2
 187             'additional properties, no matching cm handles'   | 'hasAllAdditionalProperties' | null                                  | []                                     || 0
 188     }
 189
 190     def 'Retrieve CMHandleIds by different DMI properties with #scenario.' () {
 191         given: 'a query object created with dmi plugin as condition'
 192             def cmHandleQueryParameters = new CmHandleQueryServiceParameters()
 193             def conditionProperties = createConditionProperties('cmHandleWithDmiPlugin', [['some-key': 'some-value']])
 194             cmHandleQueryParameters.setCmHandleQueryParameters([conditionProperties])
 195         and: 'the inventoryPersistence returns different CmHandleIds'
 196             partiallyMockedCmHandleQueries.getCmHandleIdsByDmiPluginIdentifier(*_) >> cmHandleQueryResult
 197         when: 'the query executed'
 198             def result = objectUnderTestWithPartiallyMockedQueries.queryCmHandleIdsForInventory(cmHandleQueryParameters)
 199         then: 'the expected number of results are returned.'
 200             assert result.size() == expectedCmHandleIdsSize
 201         where: 'the following data is used'
 202             scenario       | cmHandleQueryResult || expectedCmHandleIdsSize
 203             'some matches' | ['h1','h2']         || 2
 204             'no matches'   | []                  || 0
 205     }
 206
 207     def 'Combine two query results where #scenario.'() {
 208         when: 'two query results in the form of a map of NcmpServiceCmHandles are combined into a single query result'
 209             def result = objectUnderTest.combineCmHandleQueryResults(firstQuery, secondQuery)
 210         then: 'the returned result is the same as the expected result'
 211             result == expectedResult
 212         where:
 213             scenario                                                     | firstQuery              | secondQuery             || expectedResult
 214             'two queries with unique and non unique entries exist'       | ['PNFDemo', 'PNFDemo2'] | ['PNFDemo', 'PNFDemo3'] || ['PNFDemo']
 215             'the first query contains entries and second query is empty' | ['PNFDemo', 'PNFDemo2'] | []                      || []
 216             'the second query contains entries and first query is empty' | []                      | ['PNFDemo', 'PNFDemo3'] || []
 217             'the first query contains entries and second query is null'  | ['PNFDemo', 'PNFDemo2'] | null                    || ['PNFDemo', 'PNFDemo2']
 218             'the second query contains entries and first query is null'  | null                    | ['PNFDemo', 'PNFDemo3'] || ['PNFDemo', 'PNFDemo3']
 219             'both queries are empty'                                     | []                      | []                      || []
 220             'both queries are null'                                      | null                    | null                    || null
 221     }
 222
 223     def createConditionProperties(String conditionName, List<Map<String, String>> conditionParameters) {
 224         return new ConditionProperties(conditionName : conditionName, conditionParameters : conditionParameters)
 225     }
 226
 227     def static createDataNodeList(dataNodeIds) {
 228         def dataNodes =[]
 229         dataNodeIds.each{ dataNodes << new DataNode(xpath: "/dmi-registry/cm-handles[@id='${it}']", leaves: ['id':it]) }
 230         return dataNodes
 231     }
 232 }