integration-test/src/test/groovy/org/onap/cps/integration/performance/cps/WritePerfTest.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the 'License');
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an 'AS IS' BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.integration.performance.cps
  22
  23 import java.time.OffsetDateTime
  24 import org.onap.cps.integration.performance.base.CpsPerfTestBase
  25
  26 class WritePerfTest extends CpsPerfTestBase {
  27
  28     def 'Writing openroadm data has linear time.'() {
  29         given: 'an empty anchor exists for openroadm'
  30             cpsAdminService.createAnchor(CPS_PERFORMANCE_TEST_DATASPACE, LARGE_SCHEMA_SET, 'writeAnchor')
  31         and: 'a list of device nodes to add'
  32             def jsonData = generateOpenRoadData(totalNodes)
  33         when: 'device nodes are added'
  34             resourceMeter.start()
  35             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor', jsonData, OffsetDateTime.now())
  36             resourceMeter.stop()
  37             def durationInSeconds = resourceMeter.getTotalTimeInSeconds()
  38         then: 'the operation takes less than #expectedDuration and memory used is within limit'
  39             recordAndAssertResourceUsage("Writing ${totalNodes} devices", expectedDurationInSeconds, durationInSeconds, 400, resourceMeter.getTotalMemoryUsageInMB())
  40         cleanup:
  41             cpsDataService.deleteDataNodes(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor', OffsetDateTime.now())
  42             cpsAdminService.deleteAnchor(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor')
  43         where:
  44             totalNodes || expectedDurationInSeconds
  45             50         ||   3
  46             100        ||   5
  47             200        ||  10
  48             400        ||  20
  49 //          800        ||  40
  50 //          1600       ||  80
  51 //          3200       || 160
  52     }
  53
  54     def 'Writing bookstore data has exponential time.'() {
  55         given: 'an anchor containing a bookstore with a single category'
  56             cpsAdminService.createAnchor(CPS_PERFORMANCE_TEST_DATASPACE, BOOKSTORE_SCHEMA_SET, 'writeAnchor')
  57             def parentNodeData = '{"bookstore": { "categories": [{ "code": 1, "name": "Test", "books" : [] }] }}'
  58             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor', parentNodeData, OffsetDateTime.now())
  59         and: 'a list of books to add'
  60             def booksData = '{"books":[' + (1..totalBooks).collect {'{ "title": "' + it + '" }' }.join(',') + ']}'
  61         when: 'books are added'
  62             resourceMeter.start()
  63             cpsDataService.saveData(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor', '/bookstore/categories[@code=1]', booksData, OffsetDateTime.now())
  64             resourceMeter.stop()
  65             def durationInSeconds = resourceMeter.getTotalTimeInSeconds()
  66         then: 'the operation takes less than #expectedDuration and memory used is within limit'
  67             recordAndAssertResourceUsage("Writing ${totalBooks} books", expectedDuration, durationInSeconds, 400, resourceMeter.getTotalMemoryUsageInMB())
  68         cleanup:
  69             cpsDataService.deleteDataNodes(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor', OffsetDateTime.now())
  70             cpsAdminService.deleteAnchor(CPS_PERFORMANCE_TEST_DATASPACE, 'writeAnchor')
  71         where:
  72             totalBooks || expectedDuration
  73             400        || 0.2
  74             800        || 0.5
  75             1600       || 1
  76             3200       || 3
  77             6400       || 10
  78 //          12800      || 30
  79 //          25600      || 120
  80 //          51200      || 600
  81     }
  82
  83 }