integration-test/src/test/groovy/org/onap/cps/integration/performance/cps/GetPerfTest.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the 'License');
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an 'AS IS' BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.integration.performance.cps
  22
  23 import org.onap.cps.api.CpsDataService
  24 import org.onap.cps.integration.performance.base.CpsPerfTestBase
  25
  26 import static org.onap.cps.spi.FetchDescendantsOption.DIRECT_CHILDREN_ONLY
  27 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  28 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  29
  30 class GetPerfTest extends CpsPerfTestBase {
  31
  32     CpsDataService objectUnderTest
  33
  34     def setup() { objectUnderTest = cpsDataService }
  35
  36     def 'Read top-level node with #scenario.'() {
  37         when: 'get data nodes from 1 anchor'
  38             stopWatch.start()
  39             def result = objectUnderTest.getDataNodes(CPS_PERFORMANCE_TEST_DATASPACE, anchor, '/openroadm-devices', fetchDescendantsOption)
  40             stopWatch.stop()
  41             assert countDataNodesInTree(result) == expectedNumberOfDataNodes
  42             def durationInMillis = stopWatch.getTotalTimeMillis()
  43         then: 'all data is read within #durationLimit ms'
  44             recordAndAssertPerformance("Read datatrees with ${scenario}", durationLimit, durationInMillis)
  45         where: 'the following parameters are used'
  46             scenario             | fetchDescendantsOption  | anchor       || durationLimit | expectedNumberOfDataNodes
  47             'no descendants'     | OMIT_DESCENDANTS        | 'openroadm1' || 100           | 1
  48             'direct descendants' | DIRECT_CHILDREN_ONLY    | 'openroadm2' || 150           | 1 + 50
  49             'all descendants'    | INCLUDE_ALL_DESCENDANTS | 'openroadm3' || 600           | 1 + 50 * 86
  50     }
  51
  52     def 'Read data trees for multiple xpaths'() {
  53         given: 'a collection of xpaths to get'
  54             def xpaths = (1..50).collect { "/openroadm-devices/openroadm-device[@device-id='C201-7-1A-" + it + "']" }
  55         when: 'get data nodes from 1 anchor'
  56             stopWatch.start()
  57             def result = objectUnderTest.getDataNodesForMultipleXpaths(CPS_PERFORMANCE_TEST_DATASPACE, 'openroadm4', xpaths, INCLUDE_ALL_DESCENDANTS)
  58             stopWatch.stop()
  59             assert countDataNodesInTree(result) == 50 * 86
  60             def durationInMillis = stopWatch.getTotalTimeMillis()
  61         then: 'all data is read within 500 ms'
  62             recordAndAssertPerformance("Read datatrees for multiple xpaths", 500, durationInMillis)
  63     }
  64
  65     def 'Read complete data trees using #scenario.'() {
  66         when: 'get data nodes for 5 anchors'
  67             stopWatch.start()
  68             (1..5).each {
  69                 def result = objectUnderTest.getDataNodes(CPS_PERFORMANCE_TEST_DATASPACE, anchorPrefix + it, xpath, INCLUDE_ALL_DESCENDANTS)
  70                 assert countDataNodesInTree(result) == expectedNumberOfDataNodes
  71             }
  72             stopWatch.stop()
  73             def durationInMillis = stopWatch.getTotalTimeMillis()
  74         then: 'all data is read within #durationLimit ms'
  75             recordAndAssertPerformance("Read datatrees using ${scenario}", durationLimit, durationInMillis)
  76         where: 'the following xpaths are used'
  77             scenario                | anchorPrefix | xpath                || durationLimit | expectedNumberOfDataNodes
  78             'bookstore root'        | 'bookstore'  | '/'                  || 300           | 78
  79             'bookstore top element' | 'bookstore'  | '/bookstore'         || 300           | 78
  80             'openroadm root'        | 'openroadm'  | '/'                  || 1200          | 1 + 50 * 86
  81             'openroadm top element' | 'openroadm'  | '/openroadm-devices' || 1200          | 1 + 50 * 86
  82     }
  83
  84 }