integration-test/src/test/groovy/org/onap/cps/integration/functional/CpsQueryServiceIntegrationSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the 'License');
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an 'AS IS' BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.integration.functional
  23
  24 import org.onap.cps.api.CpsQueryService
  25 import org.onap.cps.integration.base.FunctionalSpecBase
  26 import org.onap.cps.spi.FetchDescendantsOption
  27 import org.onap.cps.spi.exceptions.CpsPathException
  28
  29 import static org.onap.cps.spi.FetchDescendantsOption.DIRECT_CHILDREN_ONLY
  30 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  31 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  32
  33 class CpsQueryServiceIntegrationSpec extends FunctionalSpecBase {
  34
  35     CpsQueryService objectUnderTest
  36
  37     def setup() { objectUnderTest = cpsQueryService }
  38
  39     def 'Query bookstore using CPS path where #scenario.'() {
  40         when: 'query data nodes for bookstore container'
  41             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
  42         then: 'the result contains expected number of nodes'
  43             assert result.size() == expectedResultSize
  44         and: 'the result contains the expected leaf values'
  45             result.leaves.forEach( dataNodeLeaves -> {
  46                 expectedLeaves.forEach( (expectedLeafKey,expectedLeafValue) -> {
  47                     assert dataNodeLeaves[expectedLeafKey] == expectedLeafValue
  48                 })
  49             })
  50         where:
  51             scenario                                      | cpsPath                                    || expectedResultSize | expectedLeaves
  52             'the AND condition is used'                   | '//books[@lang="English" and @price=15]'   || 2                  | [lang:"English", price:15]
  53             'the AND is used where result does not exist' | '//books[@lang="English" and @price=1000]' || 0                  | []
  54     }
  55
  56     def 'Cps Path query using combinations of OR operator #scenario.'() {
  57         when: 'a query is executed to get response by the given cps path'
  58             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpspath, OMIT_DESCENDANTS)
  59         then: 'the result contains expected number of nodes'
  60             assert result.size() == expectedResultSize
  61         and: 'the cps-path of queryDataNodes has the expectedLeaves'
  62             assert result.leaves.sort() == expectedLeaves.sort()
  63         where: 'the following data is used'
  64             scenario                                | cpspath                                                          || expectedResultSize | expectedLeaves
  65             'the "OR" condition'                    | '//books[@lang="English" or @price=15]'                          || 6                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  66                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]],
  67                                                                                                                                                 [lang: "English", price: 14, title: "The Light Fantastic", authors: ["Terry Pratchett"], editions: [1986]],
  68                                                                                                                                                 [lang: "English", price: 13, title: "Good Omens", authors: ["Terry Pratchett", "Neil Gaiman"], editions: [2006]],
  69                                                                                                                                                 [lang: "English", price: 12, title: "The Colour of Magic", authors: ["Terry Pratchett"], editions: [1983]],
  70                                                                                                                                                 [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]]]
  71             'the "OR" condition with non-json data' | '//books[@title="xyz" or @price=15]'                             || 2                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  72                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  73             'combination of multiple AND'           | '//books[@lang="English" and @price=15 and @edition=1983]'       || 0                  | []
  74             'combination of multiple OR'            | '//books[ @title="Matilda" or @price=15 or @edition=1983]'       || 3                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  75                                                                                                                                                 [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]],
  76                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  77             'combination of AND/OR'                 | '//books[@edition=1983 and @price=15 or @title="Good Omens"]'    || 1                  | [[lang: "English", price: 13, title: "Good Omens", authors: ["Terry Pratchett", "Neil Gaiman"], editions: [2006]]]
  78             'combination of OR/AND'                 | '//books[@title="Annihilation" or @price=39 and @lang="arabic"]' || 1                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]]]
  79     }
  80
  81     def 'Cps Path query for leaf value(s) with #scenario.'() {
  82         when: 'a query is executed to get a data node by the given cps path'
  83             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, fetchDescendantsOption)
  84         then: 'the correct number of parent nodes are returned'
  85             assert result.size() == expectedNumberOfParentNodes
  86         and: 'the correct total number of data nodes are returned'
  87             assert countDataNodesInTree(result) == expectedTotalNumberOfNodes
  88         where: 'the following data is used'
  89             scenario                               | cpsPath                                                    | fetchDescendantsOption         || expectedNumberOfParentNodes | expectedTotalNumberOfNodes
  90             'string and no descendants'            | '/bookstore/categories[@code="1"]/books[@title="Matilda"]' | OMIT_DESCENDANTS               || 1                           | 1
  91             'integer and descendants'              | '/bookstore/categories[@code="1"]/books[@price=15]'        | INCLUDE_ALL_DESCENDANTS        || 1                           | 1
  92             'no condition and no descendants'      | '/bookstore/categories'                                    | OMIT_DESCENDANTS               || 4                           | 4
  93             'no condition and level 1 descendants' | '/bookstore'                                               | new FetchDescendantsOption(1)  || 1                           | 6
  94             'no condition and level 2 descendants' | '/bookstore'                                               | new FetchDescendantsOption(2)  || 1                           | 17
  95     }
  96
  97     def 'Query for attribute by cps path with cps paths that return no data because of #scenario.'() {
  98         when: 'a query is executed to get data nodes for the given cps path'
  99             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 100         then: 'no data is returned'
 101             assert result.isEmpty()
 102         where: 'following cps queries are performed'
 103             scenario                         | cpsPath
 104             'cps path is incomplete'         | '/bookstore[@title="Matilda"]'
 105             'leaf value does not exist'      | '/bookstore/categories[@code="1"]/books[@title=\'does not exist\']'
 106             'incomplete end of xpath prefix' | '/bookstore/categories/books[@price=15]'
 107     }
 108
 109     def 'Cps Path query using descendant anywhere and #type (further) descendants.'() {
 110         when: 'a query is executed to get a data node by the given cps path'
 111             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '/bookstore/categories[@code="1"]', fetchDescendantsOption)
 112         then: 'the data node has the correct number of children'
 113             assert result[0].childDataNodes.xpath.sort() == expectedChildNodes.sort()
 114         where: 'the following data is used'
 115             type      | fetchDescendantsOption   || expectedChildNodes
 116             'omit'    | OMIT_DESCENDANTS         || []
 117             'include' | INCLUDE_ALL_DESCENDANTS  || ["/bookstore/categories[@code='1']/books[@title='Matilda']",
 118                                                      "/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 119     }
 120
 121     def 'Cps Path query for all books.'() {
 122         when: 'a query is executed to get all books'
 123             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books', OMIT_DESCENDANTS)
 124         then: 'the expected number of books are returned'
 125             assert result.size() == 9
 126     }
 127
 128     def 'Cps Path query using descendant anywhere with #scenario.'() {
 129         when: 'a query is executed to get a data node by the given cps path'
 130             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 131         then: 'xpaths of the retrieved data nodes are as expected'
 132             def bookTitles = result.collect { it.getLeaves().get('title') }
 133             assert bookTitles.sort() == expectedBookTitles.sort()
 134         where: 'the following data is used'
 135             scenario                                 | cpsPath                                     || expectedBookTitles
 136             'string leaf condition'                  | '//books[@title="Matilda"]'                 || ["Matilda"]
 137             'text condition on leaf'                 | '//books/title[text()="Matilda"]'           || ["Matilda"]
 138             'text condition case mismatch'           | '//books/title[text()="matilda"]'           || []
 139             'text condition on int leaf'             | '//books/price[text()="10"]'                || ["Matilda"]
 140             'text condition on leaf-list'            | '//books/authors[text()="Terry Pratchett"]' || ["Good Omens", "The Colour of Magic", "The Light Fantastic"]
 141             'text condition partial match'           | '//books/authors[text()="Terry"]'           || []
 142             'text condition (existing) empty string' | '//books/lang[text()=""]'                   || ["A Book with No Language"]
 143             'text condition on int leaf-list'        | '//books/editions[text()="2000"]'           || ["Matilda"]
 144             'match of leaf containing /'             | '//books[@lang="N/A"]'                      || ["Logarithm tables"]
 145             'text condition on leaf containing /'    | '//books/lang[text()="N/A"]'                || ["Logarithm tables"]
 146             'match of key containing /'              | '//books[@title="Debian GNU/Linux"]'        || ["Debian GNU/Linux"]
 147             'text condition on key containing /'     | '//books/title[text()="Debian GNU/Linux"]'  || ["Debian GNU/Linux"]
 148     }
 149
 150     def 'Query for attribute by cps path using contains condition #scenario.'() {
 151         when: 'a query is executed to get response by the given cps path'
 152             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
 153         then: 'xpaths of the retrieved data nodes are as expected'
 154             def bookTitles = result.collect { it.getLeaves().get('title') }
 155             assert bookTitles.sort() == expectedBookTitles.sort()
 156         where: 'the following data is used'
 157             scenario                                 | cpsPath                           || expectedBookTitles
 158             'contains condition with leaf'           | '//books[contains(@title,"Mat")]' || ["Matilda"]
 159             'contains condition with case-sensitive' | '//books[contains(@title,"Ti")]'  || []
 160             'contains condition with Integer Value'  | '//books[contains(@price,"15")]'  || ["Annihilation", "The Gruffalo"]
 161             'contains condition with No-value'       | '//books[contains(@title,"")]'    || ["A Book with No Language", "Annihilation", "Debian GNU/Linux", "Good Omens", "Logarithm tables", "Matilda", "The Colour of Magic", "The Gruffalo", "The Light Fantastic"]
 162     }
 163
 164     def 'Cps Path query using descendant anywhere with #scenario condition for a container element.'() {
 165         when: 'a query is executed to get a data node by the given cps path'
 166             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 167         then: 'book titles from the retrieved data nodes are as expected'
 168             def bookTitles = result.collect { it.getLeaves().get('title') }
 169             assert bookTitles.sort() == expectedBookTitles.sort()
 170         where: 'the following data is used'
 171             scenario                                                   | cpsPath                                                                || expectedBookTitles
 172             'one leaf'                                                 | '//books[@price=14]'                                                   || ['The Light Fantastic']
 173             'one text'                                                 | '//books/authors[text()="Terry Pratchett"]'                            || ['Good Omens', 'The Colour of Magic', 'The Light Fantastic']
 174             'more than one leaf'                                       | '//books[@price=12 and @lang="English"]'                               || ['The Colour of Magic']
 175             'more than one leaf has "OR" condition'                    | '//books[@lang="English" or @price=15]'                                || ['Annihilation', 'Good Omens', 'Matilda', 'The Colour of Magic', 'The Gruffalo', 'The Light Fantastic']
 176             'more than one leaf has "OR" condition with non-json data' | '//books[@title="xyz" or @price=13]'                                   || ['Good Omens']
 177             'more than one leaf has multiple AND'                      | '//books[@lang="English" and @price=13 and @edition=1983]'             || []
 178             'more than one leaf has multiple OR'                       | '//books[ @title="Matilda" or @price=15 or @edition=2006]'             || ['Annihilation', 'Matilda', 'The Gruffalo']
 179             'leaves reversed in order'                                 | '//books[@lang="English" and @price=12]'                               || ['The Colour of Magic']
 180             'more than one leaf has combination of AND/OR'             | '//books[@edition=1983 and @price=13 or @title="Good Omens"]'          || ['Good Omens']
 181             'more than one leaf has OR/AND'                            | '//books[@title="The Light Fantastic" or @price=11 and @edition=1983]' || ['The Light Fantastic']
 182             'leaf and text'                                            | '//books[@price=14]/authors[text()="Terry Pratchett"]'                 || ['The Light Fantastic']
 183             'leaf and contains'                                        | '//books[contains(@price,"13")]'                                       || ['Good Omens']
 184     }
 185
 186     def 'Cps Path query using descendant anywhere with #scenario condition(s) for a list element.'() {
 187         when: 'a query is executed to get a data node by the given cps path'
 188             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
 189         then: 'xpaths of the retrieved data nodes are as expected'
 190             result.xpath.toList() == ["/bookstore/premises/addresses[@house-number='2' and @street='Main Street']"]
 191         where: 'the following data is used'
 192             scenario                              | cpsPath
 193             'full composite key'                  | '//addresses[@house-number=2 and @street="Main Street"]'
 194             'one partial key leaf'                | '//addresses[@house-number=2]'
 195             'one non key leaf'                    | '//addresses[@county="Kildare"]'
 196             'mix of partial key and non key leaf' | '//addresses[@street="Main Street" and @county="Kildare"]'
 197     }
 198
 199     def 'Query for attribute by cps path of type ancestor with #scenario.'() {
 200         when: 'the given cps path is parsed'
 201             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 202         then: 'the xpaths of the retrieved data nodes are as expected'
 203             assert result.xpath.sort() == expectedXPaths.sort()
 204         where: 'the following data is used'
 205             scenario                                    | cpsPath                                               || expectedXPaths
 206             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 207             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 208             'top ancestor'                              | '//books/ancestor::bookstore'                         || ["/bookstore"]
 209             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 210             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 211             'ancestor with parent'                      | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 212             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 213             'ancestor with parent that does not exist'  | '//books/ancestor::parentDoesNoExist/categories'      || []
 214             'ancestor does not exist'                   | '//books/ancestor::ancestorDoesNotExist'              || []
 215             'ancestor combined with contains condition' | '//books[contains(@title,"Mat")]/ancestor::bookstore' || ["/bookstore"]
 216     }
 217
 218     def 'Query for attribute by cps path of type ancestor with #scenario descendants.'() {
 219         when: 'the given cps path is parsed'
 220             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 221         then: 'the xpaths of the retrieved data nodes are as expected'
 222             assert countDataNodesInTree(result) == expectedNumberOfNodes
 223         where: 'the following data is used'
 224             scenario | fetchDescendantsOption  || expectedNumberOfNodes
 225             'no'     | OMIT_DESCENDANTS        || 1
 226             'direct' | DIRECT_CHILDREN_ONLY    || 6
 227             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 228     }
 229
 230     def 'Cps Path query with syntax error throws a CPS Path Exception.'() {
 231         when: 'trying to execute a query with a syntax (parsing) error'
 232             objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 233         then: 'a cps path exception is thrown'
 234             thrown(CpsPathException)
 235     }
 236
 237     def 'Cps Path query across anchors with #scenario.'() {
 238         when: 'a query is executed to get a data nodes across anchors by the given CpsPath'
 239             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, cpsPath, OMIT_DESCENDANTS)
 240         then: 'the correct dataspace is queried'
 241             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 242         and: 'correct anchors are queried'
 243             assert result.anchorName.toSet() == [BOOKSTORE_ANCHOR_1, BOOKSTORE_ANCHOR_2].toSet()
 244         and: 'the correct number of nodes is returned'
 245             assert result.size() == expectedXpathsPerAnchor.size() * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 246         and: 'the queried nodes have expected xpaths'
 247             assert result.xpath.toSet() == expectedXpathsPerAnchor.toSet()
 248         where: 'the following data is used'
 249             scenario                                    | cpsPath                                               || expectedXpathsPerAnchor
 250             'container node'                            | '/bookstore'                                          || ["/bookstore"]
 251             'list node'                                 | '/bookstore/categories'                               || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 252             'string leaf-condition'                     | '/bookstore[@bookstore-name="Easons"]'                || ["/bookstore"]
 253             'integer leaf-condition'                    | '/bookstore/categories[@code="1"]/books[@price=15]'   || ["/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 254             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 255             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 256             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 257             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 258             'ancestor with parent list element'         | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 259             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 260     }
 261
 262     def 'Cps Path query across anchors with #scenario descendants.'() {
 263         when: 'a query is executed to get a data node by the given cps path'
 264             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '/bookstore', fetchDescendantsOption)
 265         then: 'the correct dataspace was queried'
 266             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 267         and: 'correct number of datanodes are returned'
 268             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 269         where: 'the following data is used'
 270             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 271             'no'     | OMIT_DESCENDANTS        || 1
 272             'direct' | DIRECT_CHILDREN_ONLY    || 6
 273             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 274     }
 275
 276     def 'Cps Path query across anchors with ancestors and #scenario descendants.'() {
 277         when: 'a query is executed to get a data node by the given cps path'
 278             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 279         then: 'the correct dataspace was queried'
 280             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 281         and: 'correct number of datanodes are returned'
 282             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 283         where: 'the following data is used'
 284             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 285             'no'     | OMIT_DESCENDANTS        || 1
 286             'direct' | DIRECT_CHILDREN_ONLY    || 6
 287             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 288     }
 289
 290     def 'Cps Path query across anchors with syntax error throws a CPS Path Exception.'() {
 291         when: 'trying to execute a query with a syntax (parsing) error'
 292             objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 293         then: 'a cps path exception is thrown'
 294             thrown(CpsPathException)
 295     }
 296
 297     def 'Cps Path querys with all descendants including descendants that are list entries: #scenario.'() {
 298         when: 'a query is executed to get a data node by the given cps path'
 299             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
 300         then: 'correct number of datanodes are returned'
 301             assert countDataNodesInTree(result) == expectedNumberOfDataNodes
 302         where:
 303             scenario                              | cpsPath                                 || expectedNumberOfDataNodes
 304             'absolute path all list entries'      | '/bookstore/categories'                 || 13
 305             'absolute path 1 list entry by key'   | '/bookstore/categories[@code="3"]'      || 5
 306             'absolute path 1 list entry by name'  | '/bookstore/categories[@name="Comedy"]' || 5
 307             'relative path all list entries'      | '//categories'                          || 13
 308             'relative path 1 list entry by key'   | '//categories[@code="3"]'               || 5
 309             'relative path 1 list entry by leaf'  | '//categories[@name="Comedy"]'          || 5
 310             'incomplete absolute path'            | '/categories'                           || 0
 311             'incomplete absolute 1 list entry'    | '/categories[@code="3"]'                || 0
 312     }
 313
 314 }