integration-test/src/test/groovy/org/onap/cps/integration/functional/CpsQueryServiceIntegrationSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the 'License');
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an 'AS IS' BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.integration.functional
  23
  24 import org.onap.cps.api.CpsQueryService
  25 import org.onap.cps.integration.base.FunctionalSpecBase
  26 import org.onap.cps.spi.FetchDescendantsOption
  27 import org.onap.cps.spi.exceptions.CpsPathException
  28 import spock.lang.Ignore
  29
  30 import static org.onap.cps.spi.FetchDescendantsOption.DIRECT_CHILDREN_ONLY
  31 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  32 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  33
  34 class CpsQueryServiceIntegrationSpec extends FunctionalSpecBase {
  35
  36     CpsQueryService objectUnderTest
  37
  38     def setup() { objectUnderTest = cpsQueryService }
  39
  40     def 'Query bookstore using CPS path where #scenario.'() {
  41         when: 'query data nodes for bookstore container'
  42             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
  43         then: 'the result contains expected number of nodes'
  44             assert result.size() == expectedResultSize
  45         and: 'the result contains the expected leaf values'
  46             result.leaves.forEach( dataNodeLeaves -> {
  47                 expectedLeaves.forEach( (expectedLeafKey,expectedLeafValue) -> {
  48                     assert dataNodeLeaves[expectedLeafKey] == expectedLeafValue
  49                 })
  50             })
  51         where:
  52             scenario                                      | cpsPath                                    || expectedResultSize | expectedLeaves
  53             'the AND condition is used'                   | '//books[@lang="English" and @price=15]'   || 2                  | [lang:"English", price:15]
  54             'the AND is used where result does not exist' | '//books[@lang="English" and @price=1000]' || 0                  | []
  55     }
  56
  57     def 'Cps Path query using combinations of OR operator #scenario.'() {
  58         when: 'a query is executed to get response by the given cps path'
  59             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpspath, OMIT_DESCENDANTS)
  60         then: 'the result contains expected number of nodes'
  61             assert result.size() == expectedResultSize
  62         and: 'the cps-path of queryDataNodes has the expectedLeaves'
  63             assert result.leaves.sort() == expectedLeaves.sort()
  64             println(expectedLeaves.toArray())
  65         where: 'the following data is used'
  66             scenario                                | cpspath                                                    || expectedResultSize | expectedLeaves
  67             'the "OR" condition'                    | '//books[@lang="English" or @price=15]'                    || 6                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  68                                                                                                                                           [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]],
  69                                                                                                                                           [lang: "English", price: 14, title: "The Light Fantastic", authors: ["Terry Pratchett"], editions: [1986]],
  70                                                                                                                                           [lang: "English", price: 13, title: "Good Omens", authors: ["Terry Pratchett", "Neil Gaiman"], editions: [2006]],
  71                                                                                                                                           [lang: "English", price: 12, title: "The Colour of Magic", authors: ["Terry Pratchett"], editions: [1983]],
  72                                                                                                                                           [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]]]
  73             'the "OR" condition with non-json data' | '//books[@title="xyz" or @price=15]'                       || 2                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  74                                                                                                                                           [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  75             'combination of multiple AND'           | '//books[@lang="English" and @price=15 and @edition=1983]' || 0                  | []
  76             'combination of multiple OR'            | '//books[ @title="Matilda" or @price=15 or @edition=1983]' || 3                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  77                                                                                                                                           [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]],
  78                                                                                                                                           [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  79     }
  80
  81     def 'Cps Path query for leaf value(s) with #scenario.'() {
  82         when: 'a query is executed to get a data node by the given cps path'
  83             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, fetchDescendantsOption)
  84         then: 'the correct number of parent nodes are returned'
  85             assert result.size() == expectedNumberOfParentNodes
  86         and: 'the correct total number of data nodes are returned'
  87             assert countDataNodesInTree(result) == expectedTotalNumberOfNodes
  88         where: 'the following data is used'
  89             scenario                               | cpsPath                                                    | fetchDescendantsOption         || expectedNumberOfParentNodes | expectedTotalNumberOfNodes
  90             'string and no descendants'            | '/bookstore/categories[@code="1"]/books[@title="Matilda"]' | OMIT_DESCENDANTS               || 1                           | 1
  91             'integer and descendants'              | '/bookstore/categories[@code="1"]/books[@price=15]'        | INCLUDE_ALL_DESCENDANTS        || 1                           | 1
  92             'no condition and no descendants'      | '/bookstore/categories'                                    | OMIT_DESCENDANTS               || 4                           | 4
  93             'no condition and level 1 descendants' | '/bookstore'                                               | new FetchDescendantsOption(1)  || 1                           | 6
  94             'no condition and level 2 descendants' | '/bookstore'                                               | new FetchDescendantsOption(2)  || 1                           | 17
  95     }
  96
  97     def 'Query for attribute by cps path with cps paths that return no data because of #scenario.'() {
  98         when: 'a query is executed to get data nodes for the given cps path'
  99             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 100         then: 'no data is returned'
 101             assert result.isEmpty()
 102         where: 'following cps queries are performed'
 103             scenario                         | cpsPath
 104             'cps path is incomplete'         | '/bookstore[@title="Matilda"]'
 105             'leaf value does not exist'      | '/bookstore/categories[@code="1"]/books[@title=\'does not exist\']'
 106             'incomplete end of xpath prefix' | '/bookstore/categories/books[@price=15]'
 107     }
 108
 109     def 'Cps Path query using descendant anywhere and #type (further) descendants.'() {
 110         when: 'a query is executed to get a data node by the given cps path'
 111             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '/bookstore/categories[@code="1"]', fetchDescendantsOption)
 112         then: 'the data node has the correct number of children'
 113             assert result[0].childDataNodes.xpath.sort() == expectedChildNodes.sort()
 114         where: 'the following data is used'
 115             type      | fetchDescendantsOption   || expectedChildNodes
 116             'omit'    | OMIT_DESCENDANTS         || []
 117             'include' | INCLUDE_ALL_DESCENDANTS  || ["/bookstore/categories[@code='1']/books[@title='Matilda']",
 118                                                      "/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 119     }
 120
 121     def 'Cps Path query for all books.'() {
 122         when: 'a query is executed to get all books'
 123             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books', OMIT_DESCENDANTS)
 124         then: 'the expected number of books are returned'
 125             assert result.size() == 9
 126     }
 127
 128     def 'Cps Path query using descendant anywhere with #scenario.'() {
 129         when: 'a query is executed to get a data node by the given cps path'
 130             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 131         then: 'xpaths of the retrieved data nodes are as expected'
 132             def bookTitles = result.collect { it.getLeaves().get('title') }
 133             assert bookTitles.sort() == expectedBookTitles.sort()
 134         where: 'the following data is used'
 135             scenario                                 | cpsPath                                     || expectedBookTitles
 136             'string leaf condition'                  | '//books[@title="Matilda"]'                 || ["Matilda"]
 137             'text condition on leaf'                 | '//books/title[text()="Matilda"]'           || ["Matilda"]
 138             'text condition case mismatch'           | '//books/title[text()="matilda"]'           || []
 139             'text condition on int leaf'             | '//books/price[text()="10"]'                || ["Matilda"]
 140             'text condition on leaf-list'            | '//books/authors[text()="Terry Pratchett"]' || ["Good Omens", "The Colour of Magic", "The Light Fantastic"]
 141             'text condition partial match'           | '//books/authors[text()="Terry"]'           || []
 142             'text condition (existing) empty string' | '//books/lang[text()=""]'                   || ["A Book with No Language"]
 143             'text condition on int leaf-list'        | '//books/editions[text()="2000"]'           || ["Matilda"]
 144             'match of leaf containing /'             | '//books[@lang="N/A"]'                      || ["Logarithm tables"]
 145             'text condition on leaf containing /'    | '//books/lang[text()="N/A"]'                || ["Logarithm tables"]
 146             'match of key containing /'              | '//books[@title="Debian GNU/Linux"]'        || ["Debian GNU/Linux"]
 147             'text condition on key containing /'     | '//books/title[text()="Debian GNU/Linux"]'  || ["Debian GNU/Linux"]
 148     }
 149
 150     def 'Cps Path query using descendant anywhere with #scenario condition for a container element.'() {
 151         when: 'a query is executed to get a data node by the given cps path'
 152             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 153         then: 'book titles from the retrieved data nodes are as expected'
 154             def bookTitles = result.collect { it.getLeaves().get('title') }
 155             assert bookTitles.sort() == expectedBookTitles.sort()
 156         where: 'the following data is used'
 157             scenario                                                   | cpsPath                                                    || expectedBookTitles
 158             'one leaf'                                                 | '//books[@price=14]'                                       || ['The Light Fantastic']
 159             'one text'                                                 | '//books/authors[text()="Terry Pratchett"]'                || ['Good Omens', 'The Colour of Magic', 'The Light Fantastic']
 160             'more than one leaf'                                       | '//books[@price=12 and @lang="English"]'                   || ['The Colour of Magic']
 161             'more than one leaf has "OR" condition'                    | '//books[@lang="English" or @price=15]'                    || ['Annihilation', 'Good Omens', 'Matilda', 'The Colour of Magic', 'The Gruffalo', 'The Light Fantastic']
 162             'more than one leaf has "OR" condition with non-json data' | '//books[@title="xyz" or @price=13]'                       || ['Good Omens']
 163             'more than one leaf has multiple AND'                      | '//books[@lang="English" and @price=13 and @edition=1983]' || []
 164             'more than one leaf has multiple OR'                       | '//books[ @title="Matilda" or @price=15 or @edition=2006]' || ['Annihilation', 'Matilda', 'The Gruffalo']
 165             'leaves reversed in order'                                 | '//books[@lang="English" and @price=12]'                   || ['The Colour of Magic']
 166             'leaf and text'                                            | '//books[@price=14]/authors[text()="Terry Pratchett"]'     || ['The Light Fantastic']
 167     }
 168
 169     def 'Cps Path query using descendant anywhere with #scenario condition(s) for a list element.'() {
 170         when: 'a query is executed to get a data node by the given cps path'
 171             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
 172         then: 'xpaths of the retrieved data nodes are as expected'
 173             result.xpath.toList() == ["/bookstore/premises/addresses[@house-number='2' and @street='Main Street']"]
 174         where: 'the following data is used'
 175             scenario                              | cpsPath
 176             'full composite key'                  | '//addresses[@house-number=2 and @street="Main Street"]'
 177             'one partial key leaf'                | '//addresses[@house-number=2]'
 178             'one non key leaf'                    | '//addresses[@county="Kildare"]'
 179             'mix of partial key and non key leaf' | '//addresses[@street="Main Street" and @county="Kildare"]'
 180     }
 181
 182     def 'Query for attribute by cps path of type ancestor with #scenario.'() {
 183         when: 'the given cps path is parsed'
 184             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 185         then: 'the xpaths of the retrieved data nodes are as expected'
 186             assert result.xpath.sort() == expectedXPaths.sort()
 187         where: 'the following data is used'
 188             scenario                                    | cpsPath                                               || expectedXPaths
 189             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 190             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 191             'top ancestor'                              | '//books/ancestor::bookstore'                         || ["/bookstore"]
 192             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 193             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 194             'ancestor with parent'                      | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 195             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 196             'ancestor with parent that does not exist'  | '//books/ancestor::parentDoesNoExist/categories'      || []
 197             'ancestor does not exist'                   | '//books/ancestor::ancestorDoesNotExist'              || []
 198     }
 199
 200     def 'Query for attribute by cps path of type ancestor with #scenario descendants.'() {
 201         when: 'the given cps path is parsed'
 202             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 203         then: 'the xpaths of the retrieved data nodes are as expected'
 204             assert countDataNodesInTree(result) == expectedNumberOfNodes
 205         where: 'the following data is used'
 206             scenario | fetchDescendantsOption  || expectedNumberOfNodes
 207             'no'     | OMIT_DESCENDANTS        || 1
 208             'direct' | DIRECT_CHILDREN_ONLY    || 6
 209             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 210     }
 211
 212     def 'Cps Path query with syntax error throws a CPS Path Exception.'() {
 213         when: 'trying to execute a query with a syntax (parsing) error'
 214             objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 215         then: 'a cps path exception is thrown'
 216             thrown(CpsPathException)
 217     }
 218
 219     @Ignore
 220     def 'Cps Path query across anchors with #scenario.'() {
 221         when: 'a query is executed to get a data nodes across anchors by the given CpsPath'
 222             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, cpsPath, OMIT_DESCENDANTS)
 223         then: 'the correct dataspace is queried'
 224             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 225         and: 'correct anchors are queried'
 226             assert result.anchorName.toSet() == [BOOKSTORE_ANCHOR_1, BOOKSTORE_ANCHOR_2].toSet()
 227         and: 'the correct number of nodes is returned'
 228             assert result.size() == expectedXpathsPerAnchor.size() * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 229         and: 'the queried nodes have expected xpaths'
 230             assert result.xpath.toSet() == expectedXpathsPerAnchor.toSet()
 231         where: 'the following data is used'
 232             scenario                                    | cpsPath                                               || expectedXpathsPerAnchor
 233             'container node'                            | '/bookstore'                                          || ["/bookstore"]
 234             'list node'                                 | '/bookstore/categories'                               || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 235             'string leaf-condition'                     | '/bookstore[@bookstore-name="Easons"]'                || ["/bookstore"]
 236             'integer leaf-condition'                    | '/bookstore/categories[@code="1"]/books[@price=15]'   || ["/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 237             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 238             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 239             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 240             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 241             'ancestor with parent list element'         | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 242             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 243     }
 244
 245     @Ignore
 246     def 'Cps Path query across anchors with #scenario descendants.'() {
 247         when: 'a query is executed to get a data node by the given cps path'
 248             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '/bookstore', fetchDescendantsOption)
 249         then: 'the correct dataspace was queried'
 250             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 251         and: 'correct number of datanodes are returned'
 252             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 253         where: 'the following data is used'
 254             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 255             'no'     | OMIT_DESCENDANTS        || 1
 256             'direct' | DIRECT_CHILDREN_ONLY    || 6
 257             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 258     }
 259
 260     @Ignore
 261     def 'Cps Path query across anchors with ancestors and #scenario descendants.'() {
 262         when: 'a query is executed to get a data node by the given cps path'
 263             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 264         then: 'the correct dataspace was queried'
 265             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 266         and: 'correct number of datanodes are returned'
 267             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 268         where: 'the following data is used'
 269             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 270             'no'     | OMIT_DESCENDANTS        || 1
 271             'direct' | DIRECT_CHILDREN_ONLY    || 6
 272             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 273     }
 274
 275     def 'Cps Path query across anchors with syntax error throws a CPS Path Exception.'() {
 276         when: 'trying to execute a query with a syntax (parsing) error'
 277             objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 278         then: 'a cps path exception is thrown'
 279             thrown(CpsPathException)
 280     }
 281
 282 }