integration-test/src/test/groovy/org/onap/cps/integration/functional/CpsQueryServiceIntegrationSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the 'License');
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an 'AS IS' BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.integration.functional
  23
  24 import org.onap.cps.api.CpsQueryService
  25 import org.onap.cps.integration.base.FunctionalSpecBase
  26 import org.onap.cps.spi.FetchDescendantsOption
  27 import org.onap.cps.spi.exceptions.CpsPathException
  28 import spock.lang.Ignore
  29
  30 import static org.onap.cps.spi.FetchDescendantsOption.DIRECT_CHILDREN_ONLY
  31 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  32 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  33
  34 class CpsQueryServiceIntegrationSpec extends FunctionalSpecBase {
  35
  36     CpsQueryService objectUnderTest
  37
  38     def setup() { objectUnderTest = cpsQueryService }
  39
  40     def 'Query bookstore using CPS path where #scenario.'() {
  41         when: 'query data nodes for bookstore container'
  42             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
  43         then: 'the result contains expected number of nodes'
  44             assert result.size() == expectedResultSize
  45         and: 'the result contains the expected leaf values'
  46             result.leaves.forEach( dataNodeLeaves -> {
  47                 expectedLeaves.forEach( (expectedLeafKey,expectedLeafValue) -> {
  48                     assert dataNodeLeaves[expectedLeafKey] == expectedLeafValue
  49                 })
  50             })
  51         where:
  52             scenario                                      | cpsPath                                    || expectedResultSize | expectedLeaves
  53             'the AND condition is used'                   | '//books[@lang="English" and @price=15]'   || 2                  | [lang:"English", price:15]
  54             'the AND is used where result does not exist' | '//books[@lang="English" and @price=1000]' || 0                  | []
  55     }
  56
  57     def 'Cps Path query using combinations of OR operator #scenario.'() {
  58         when: 'a query is executed to get response by the given cps path'
  59             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpspath, OMIT_DESCENDANTS)
  60         then: 'the result contains expected number of nodes'
  61             assert result.size() == expectedResultSize
  62         and: 'the cps-path of queryDataNodes has the expectedLeaves'
  63             assert result.leaves.sort() == expectedLeaves.sort()
  64         where: 'the following data is used'
  65             scenario                                | cpspath                                                          || expectedResultSize | expectedLeaves
  66             'the "OR" condition'                    | '//books[@lang="English" or @price=15]'                          || 6                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  67                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]],
  68                                                                                                                                                 [lang: "English", price: 14, title: "The Light Fantastic", authors: ["Terry Pratchett"], editions: [1986]],
  69                                                                                                                                                 [lang: "English", price: 13, title: "Good Omens", authors: ["Terry Pratchett", "Neil Gaiman"], editions: [2006]],
  70                                                                                                                                                 [lang: "English", price: 12, title: "The Colour of Magic", authors: ["Terry Pratchett"], editions: [1983]],
  71                                                                                                                                                 [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]]]
  72             'the "OR" condition with non-json data' | '//books[@title="xyz" or @price=15]'                             || 2                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  73                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  74             'combination of multiple AND'           | '//books[@lang="English" and @price=15 and @edition=1983]'       || 0                  | []
  75             'combination of multiple OR'            | '//books[ @title="Matilda" or @price=15 or @edition=1983]'       || 3                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]],
  76                                                                                                                                                 [lang: "English", price: 10, title: "Matilda", authors: ["Roald Dahl"], editions: [1988, 2000]],
  77                                                                                                                                                 [lang: "English", price: 15, title: "The Gruffalo", authors: ["Julia Donaldson"], editions: [1999]]]
  78             'combination of AND/OR'                 | '//books[@edition=1983 and @price=15 or @title="Good Omens"]'    || 1                  | [[lang: "English", price: 13, title: "Good Omens", authors: ["Terry Pratchett", "Neil Gaiman"], editions: [2006]]]
  79             'combination of OR/AND'                 | '//books[@title="Annihilation" or @price=39 and @lang="arabic"]' || 1                  | [[lang: "English", price: 15, title: "Annihilation", authors: ["Jeff VanderMeer"], editions: [2014]]]
  80     }
  81
  82     def 'Cps Path query for leaf value(s) with #scenario.'() {
  83         when: 'a query is executed to get a data node by the given cps path'
  84             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, fetchDescendantsOption)
  85         then: 'the correct number of parent nodes are returned'
  86             assert result.size() == expectedNumberOfParentNodes
  87         and: 'the correct total number of data nodes are returned'
  88             assert countDataNodesInTree(result) == expectedTotalNumberOfNodes
  89         where: 'the following data is used'
  90             scenario                               | cpsPath                                                    | fetchDescendantsOption         || expectedNumberOfParentNodes | expectedTotalNumberOfNodes
  91             'string and no descendants'            | '/bookstore/categories[@code="1"]/books[@title="Matilda"]' | OMIT_DESCENDANTS               || 1                           | 1
  92             'integer and descendants'              | '/bookstore/categories[@code="1"]/books[@price=15]'        | INCLUDE_ALL_DESCENDANTS        || 1                           | 1
  93             'no condition and no descendants'      | '/bookstore/categories'                                    | OMIT_DESCENDANTS               || 4                           | 4
  94             'no condition and level 1 descendants' | '/bookstore'                                               | new FetchDescendantsOption(1)  || 1                           | 6
  95             'no condition and level 2 descendants' | '/bookstore'                                               | new FetchDescendantsOption(2)  || 1                           | 17
  96     }
  97
  98     def 'Query for attribute by cps path with cps paths that return no data because of #scenario.'() {
  99         when: 'a query is executed to get data nodes for the given cps path'
 100             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 101         then: 'no data is returned'
 102             assert result.isEmpty()
 103         where: 'following cps queries are performed'
 104             scenario                         | cpsPath
 105             'cps path is incomplete'         | '/bookstore[@title="Matilda"]'
 106             'leaf value does not exist'      | '/bookstore/categories[@code="1"]/books[@title=\'does not exist\']'
 107             'incomplete end of xpath prefix' | '/bookstore/categories/books[@price=15]'
 108     }
 109
 110     def 'Cps Path query using descendant anywhere and #type (further) descendants.'() {
 111         when: 'a query is executed to get a data node by the given cps path'
 112             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '/bookstore/categories[@code="1"]', fetchDescendantsOption)
 113         then: 'the data node has the correct number of children'
 114             assert result[0].childDataNodes.xpath.sort() == expectedChildNodes.sort()
 115         where: 'the following data is used'
 116             type      | fetchDescendantsOption   || expectedChildNodes
 117             'omit'    | OMIT_DESCENDANTS         || []
 118             'include' | INCLUDE_ALL_DESCENDANTS  || ["/bookstore/categories[@code='1']/books[@title='Matilda']",
 119                                                      "/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 120     }
 121
 122     def 'Cps Path query for all books.'() {
 123         when: 'a query is executed to get all books'
 124             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books', OMIT_DESCENDANTS)
 125         then: 'the expected number of books are returned'
 126             assert result.size() == 9
 127     }
 128
 129     def 'Cps Path query using descendant anywhere with #scenario.'() {
 130         when: 'a query is executed to get a data node by the given cps path'
 131             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 132         then: 'xpaths of the retrieved data nodes are as expected'
 133             def bookTitles = result.collect { it.getLeaves().get('title') }
 134             assert bookTitles.sort() == expectedBookTitles.sort()
 135         where: 'the following data is used'
 136             scenario                                 | cpsPath                                     || expectedBookTitles
 137             'string leaf condition'                  | '//books[@title="Matilda"]'                 || ["Matilda"]
 138             'text condition on leaf'                 | '//books/title[text()="Matilda"]'           || ["Matilda"]
 139             'text condition case mismatch'           | '//books/title[text()="matilda"]'           || []
 140             'text condition on int leaf'             | '//books/price[text()="10"]'                || ["Matilda"]
 141             'text condition on leaf-list'            | '//books/authors[text()="Terry Pratchett"]' || ["Good Omens", "The Colour of Magic", "The Light Fantastic"]
 142             'text condition partial match'           | '//books/authors[text()="Terry"]'           || []
 143             'text condition (existing) empty string' | '//books/lang[text()=""]'                   || ["A Book with No Language"]
 144             'text condition on int leaf-list'        | '//books/editions[text()="2000"]'           || ["Matilda"]
 145             'match of leaf containing /'             | '//books[@lang="N/A"]'                      || ["Logarithm tables"]
 146             'text condition on leaf containing /'    | '//books/lang[text()="N/A"]'                || ["Logarithm tables"]
 147             'match of key containing /'              | '//books[@title="Debian GNU/Linux"]'        || ["Debian GNU/Linux"]
 148             'text condition on key containing /'     | '//books/title[text()="Debian GNU/Linux"]'  || ["Debian GNU/Linux"]
 149     }
 150
 151     def 'Query for attribute by cps path using contains condition #scenario.'() {
 152         when: 'a query is executed to get response by the given cps path'
 153             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 154         then: 'the cps-path of queryDataNodes has expected number of nodes'
 155             assert result.size() == expectedResultsize
 156         and: 'xpaths of the retrieved data nodes are as expected'
 157             def bookTitles = result.collect { it.getLeaves().get('title') }
 158             assert bookTitles.sort() == expectedBookTitles.sort()
 159         where: 'the following data is used'
 160             scenario                                 | cpsPath                           | expectedResultsize || expectedBookTitles
 161             'contains condition with leaf'           | '//books[contains(@title,"Mat")]' | 1                  || ["Matilda"]
 162             'contains condition with case-sensitive' | '//books[contains(@title,"Ti")]'  | 0                  || []
 163             'contains condition with Integer Value'  | '//books[contains(@price,"15")]'  | 2                  || ["Annihilation", "The Gruffalo"]
 164             'contains condition with No-value'       | '//books[contains(@title,"")]'    | 9                  || ["A Book with No Language", "Annihilation", "Debian GNU/Linux", "Good Omens", "Logarithm tables", "Matilda", "The Colour of Magic", "The Gruffalo", "The Light Fantastic"]
 165     }
 166
 167     def 'Cps Path query using descendant anywhere with #scenario condition for a container element.'() {
 168         when: 'a query is executed to get a data node by the given cps path'
 169             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 170         then: 'book titles from the retrieved data nodes are as expected'
 171             def bookTitles = result.collect { it.getLeaves().get('title') }
 172             assert bookTitles.sort() == expectedBookTitles.sort()
 173         where: 'the following data is used'
 174             scenario                                                   | cpsPath                                                                || expectedBookTitles
 175             'one leaf'                                                 | '//books[@price=14]'                                                   || ['The Light Fantastic']
 176             'one text'                                                 | '//books/authors[text()="Terry Pratchett"]'                            || ['Good Omens', 'The Colour of Magic', 'The Light Fantastic']
 177             'more than one leaf'                                       | '//books[@price=12 and @lang="English"]'                               || ['The Colour of Magic']
 178             'more than one leaf has "OR" condition'                    | '//books[@lang="English" or @price=15]'                                || ['Annihilation', 'Good Omens', 'Matilda', 'The Colour of Magic', 'The Gruffalo', 'The Light Fantastic']
 179             'more than one leaf has "OR" condition with non-json data' | '//books[@title="xyz" or @price=13]'                                   || ['Good Omens']
 180             'more than one leaf has multiple AND'                      | '//books[@lang="English" and @price=13 and @edition=1983]'             || []
 181             'more than one leaf has multiple OR'                       | '//books[ @title="Matilda" or @price=15 or @edition=2006]'             || ['Annihilation', 'Matilda', 'The Gruffalo']
 182             'leaves reversed in order'                                 | '//books[@lang="English" and @price=12]'                               || ['The Colour of Magic']
 183             'more than one leaf has combination of AND/OR'             | '//books[@edition=1983 and @price=13 or @title="Good Omens"]'          || ['Good Omens']
 184             'more than one leaf has OR/AND'                            | '//books[@title="The Light Fantastic" or @price=11 and @edition=1983]' || ['The Light Fantastic']
 185             'leaf and text'                                            | '//books[@price=14]/authors[text()="Terry Pratchett"]'                 || ['The Light Fantastic']
 186             'leaf and contains'                                        | '//books[contains(@price,"13")]'                                       || ['Good Omens']
 187     }
 188
 189     def 'Cps Path query using descendant anywhere with #scenario condition(s) for a list element.'() {
 190         when: 'a query is executed to get a data node by the given cps path'
 191             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, INCLUDE_ALL_DESCENDANTS)
 192         then: 'xpaths of the retrieved data nodes are as expected'
 193             result.xpath.toList() == ["/bookstore/premises/addresses[@house-number='2' and @street='Main Street']"]
 194         where: 'the following data is used'
 195             scenario                              | cpsPath
 196             'full composite key'                  | '//addresses[@house-number=2 and @street="Main Street"]'
 197             'one partial key leaf'                | '//addresses[@house-number=2]'
 198             'one non key leaf'                    | '//addresses[@county="Kildare"]'
 199             'mix of partial key and non key leaf' | '//addresses[@street="Main Street" and @county="Kildare"]'
 200     }
 201
 202     def 'Query for attribute by cps path of type ancestor with #scenario.'() {
 203         when: 'the given cps path is parsed'
 204             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, cpsPath, OMIT_DESCENDANTS)
 205         then: 'the xpaths of the retrieved data nodes are as expected'
 206             assert result.xpath.sort() == expectedXPaths.sort()
 207         where: 'the following data is used'
 208             scenario                                    | cpsPath                                               || expectedXPaths
 209             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 210             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 211             'top ancestor'                              | '//books/ancestor::bookstore'                         || ["/bookstore"]
 212             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 213             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 214             'ancestor with parent'                      | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 215             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 216             'ancestor with parent that does not exist'  | '//books/ancestor::parentDoesNoExist/categories'      || []
 217             'ancestor does not exist'                   | '//books/ancestor::ancestorDoesNotExist'              || []
 218             'ancestor combined with contains condition' | '//books[contains(@title,"Mat")]/ancestor::bookstore' || ["/bookstore"]
 219     }
 220
 221     def 'Query for attribute by cps path of type ancestor with #scenario descendants.'() {
 222         when: 'the given cps path is parsed'
 223             def result = objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 224         then: 'the xpaths of the retrieved data nodes are as expected'
 225             assert countDataNodesInTree(result) == expectedNumberOfNodes
 226         where: 'the following data is used'
 227             scenario | fetchDescendantsOption  || expectedNumberOfNodes
 228             'no'     | OMIT_DESCENDANTS        || 1
 229             'direct' | DIRECT_CHILDREN_ONLY    || 6
 230             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 231     }
 232
 233     def 'Cps Path query with syntax error throws a CPS Path Exception.'() {
 234         when: 'trying to execute a query with a syntax (parsing) error'
 235             objectUnderTest.queryDataNodes(FUNCTIONAL_TEST_DATASPACE_1, BOOKSTORE_ANCHOR_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 236         then: 'a cps path exception is thrown'
 237             thrown(CpsPathException)
 238     }
 239
 240     @Ignore
 241     def 'Cps Path query across anchors with #scenario.'() {
 242         when: 'a query is executed to get a data nodes across anchors by the given CpsPath'
 243             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, cpsPath, OMIT_DESCENDANTS)
 244         then: 'the correct dataspace is queried'
 245             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 246         and: 'correct anchors are queried'
 247             assert result.anchorName.toSet() == [BOOKSTORE_ANCHOR_1, BOOKSTORE_ANCHOR_2].toSet()
 248         and: 'the correct number of nodes is returned'
 249             assert result.size() == expectedXpathsPerAnchor.size() * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 250         and: 'the queried nodes have expected xpaths'
 251             assert result.xpath.toSet() == expectedXpathsPerAnchor.toSet()
 252         where: 'the following data is used'
 253             scenario                                    | cpsPath                                               || expectedXpathsPerAnchor
 254             'container node'                            | '/bookstore'                                          || ["/bookstore"]
 255             'list node'                                 | '/bookstore/categories'                               || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 256             'string leaf-condition'                     | '/bookstore[@bookstore-name="Easons"]'                || ["/bookstore"]
 257             'integer leaf-condition'                    | '/bookstore/categories[@code="1"]/books[@price=15]'   || ["/bookstore/categories[@code='1']/books[@title='The Gruffalo']"]
 258             'multiple list-ancestors'                   | '//books/ancestor::categories'                        || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 259             'one ancestor with list value'              | '//books/ancestor::categories[@code="1"]'             || ["/bookstore/categories[@code='1']"]
 260             'list with index value in the xpath prefix' | '//categories[@code="1"]/books/ancestor::bookstore'   || ["/bookstore"]
 261             'ancestor with parent list'                 | '//books/ancestor::bookstore/categories'              || ["/bookstore/categories[@code='1']", "/bookstore/categories[@code='2']", "/bookstore/categories[@code='3']", "/bookstore/categories[@code='4']"]
 262             'ancestor with parent list element'         | '//books/ancestor::bookstore/categories[@code="2"]'   || ["/bookstore/categories[@code='2']"]
 263             'ancestor combined with text condition'     | '//books/title[text()="Matilda"]/ancestor::bookstore' || ["/bookstore"]
 264     }
 265
 266     @Ignore
 267     def 'Cps Path query across anchors with #scenario descendants.'() {
 268         when: 'a query is executed to get a data node by the given cps path'
 269             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '/bookstore', fetchDescendantsOption)
 270         then: 'the correct dataspace was queried'
 271             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 272         and: 'correct number of datanodes are returned'
 273             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 274         where: 'the following data is used'
 275             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 276             'no'     | OMIT_DESCENDANTS        || 1
 277             'direct' | DIRECT_CHILDREN_ONLY    || 6
 278             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 279     }
 280
 281     @Ignore
 282     def 'Cps Path query across anchors with ancestors and #scenario descendants.'() {
 283         when: 'a query is executed to get a data node by the given cps path'
 284             def result = objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, '//books/ancestor::bookstore', fetchDescendantsOption)
 285         then: 'the correct dataspace was queried'
 286             assert result.dataspace.toSet() == [FUNCTIONAL_TEST_DATASPACE_1].toSet()
 287         and: 'correct number of datanodes are returned'
 288             assert countDataNodesInTree(result) == expectedNumberOfNodesPerAnchor * NUMBER_OF_ANCHORS_PER_DATASPACE_WITH_BOOKSTORE_DATA
 289         where: 'the following data is used'
 290             scenario | fetchDescendantsOption  || expectedNumberOfNodesPerAnchor
 291             'no'     | OMIT_DESCENDANTS        || 1
 292             'direct' | DIRECT_CHILDREN_ONLY    || 6
 293             'all'    | INCLUDE_ALL_DESCENDANTS || 17
 294     }
 295
 296     def 'Cps Path query across anchors with syntax error throws a CPS Path Exception.'() {
 297         when: 'trying to execute a query with a syntax (parsing) error'
 298             objectUnderTest.queryDataNodesAcrossAnchors(FUNCTIONAL_TEST_DATASPACE_1, 'cpsPath that cannot be parsed' , OMIT_DESCENDANTS)
 299         then: 'a cps path exception is thrown'
 300             thrown(CpsPathException)
 301     }
 302
 303 }