cps-rest/src/test/groovy/org/onap/cps/rest/controller/QueryRestControllerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021-2022 Nordix Foundation
   4  *  Modifications Copyright (C) 2021-2022 Bell Canada.
   5  *  Modifications Copyright (C) 2021 Pantheon.tech
   6  *  ================================================================================
   7  *  Licensed under the Apache License, Version 2.0 (the "License");
   8  *  you may not use this file except in compliance with the License.
   9  *  You may obtain a copy of the License at
  10  *
  11  *        http://www.apache.org/licenses/LICENSE-2.0
  12  *
  13  *  Unless required by applicable law or agreed to in writing, software
  14  *  distributed under the License is distributed on an "AS IS" BASIS,
  15  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16  *  See the License for the specific language governing permissions and
  17  *  limitations under the License.
  18  *
  19  *  SPDX-License-Identifier: Apache-2.0
  20  *  ============LICENSE_END=========================================================
  21  */
  22
  23 package org.onap.cps.rest.controller
  24
  25 import org.onap.cps.utils.PrefixResolver
  26
  27 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  28 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  29 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  30
  31 import com.fasterxml.jackson.databind.ObjectMapper
  32 import org.onap.cps.utils.JsonObjectMapper
  33 import org.onap.cps.api.CpsQueryService
  34 import org.onap.cps.spi.model.DataNodeBuilder
  35 import org.spockframework.spring.SpringBean
  36 import org.springframework.beans.factory.annotation.Autowired
  37 import org.springframework.beans.factory.annotation.Value
  38 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  39 import org.springframework.http.HttpStatus
  40 import org.springframework.test.web.servlet.MockMvc
  41 import spock.lang.Specification
  42
  43 @WebMvcTest(QueryRestController)
  44 class QueryRestControllerSpec extends Specification {
  45
  46     @SpringBean
  47     CpsQueryService mockCpsQueryService = Mock()
  48
  49     @SpringBean
  50     JsonObjectMapper jsonObjectMapper = new JsonObjectMapper(new ObjectMapper())
  51
  52     @SpringBean
  53     PrefixResolver prefixResolver = Mock()
  54
  55     @Autowired
  56     MockMvc mvc
  57
  58     @Value('${rest.api.cps-base-path}')
  59     def basePath
  60
  61     def 'Query data node by cps path for the given dataspace and anchor with #scenario.'() {
  62         given: 'service method returns a list containing a data node'
  63              def dataNode1 = new DataNodeBuilder().withXpath('/xpath')
  64                     .withLeaves([leaf: 'value', leafList: ['leaveListElement1', 'leaveListElement2']]).build()
  65             def dataspaceName = 'my_dataspace'
  66             def anchorName = 'my_anchor'
  67             def cpsPath = 'some cps-path'
  68             mockCpsQueryService.queryDataNodes(dataspaceName, anchorName, cpsPath, expectedCpsDataServiceOption) >> [dataNode1, dataNode1]
  69         and: 'the query endpoint'
  70             def dataNodeEndpoint = "$basePath/v1/dataspaces/$dataspaceName/anchors/$anchorName/nodes/query"
  71         when: 'query data nodes API is invoked'
  72             def response =
  73                     mvc.perform(
  74                             get(dataNodeEndpoint)
  75                                     .param('cps-path', cpsPath)
  76                                     .param('include-descendants', includeDescendantsOption))
  77                             .andReturn().response
  78         then: 'the response contains the the datanode in json format'
  79             response.status == HttpStatus.OK.value()
  80             response.getContentAsString().contains('{"xpath":{"leaf":"value","leafList":["leaveListElement1","leaveListElement2"]}}')
  81         where: 'the following options for include descendants are provided in the request'
  82             scenario                    | includeDescendantsOption || expectedCpsDataServiceOption
  83             'no descendants by default' | ''                       || OMIT_DESCENDANTS
  84             'no descendant explicitly'  | 'false'                  || OMIT_DESCENDANTS
  85             'descendants'               | 'true'                   || INCLUDE_ALL_DESCENDANTS
  86     }
  87 }