cps-rest/src/test/groovy/org/onap/cps/rest/controller/DataRestControllerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 Nordix Foundation
   4  *  Modifications Copyright (C) 2021 Pantheon.tech
   5  *  Modifications Copyright (C) 2021 Bell Canada.
   6  *  ================================================================================
   7  *  Licensed under the Apache License, Version 2.0 (the "License");
   8  *  you may not use this file except in compliance with the License.
   9  *  You may obtain a copy of the License at
  10  *
  11  *        http://www.apache.org/licenses/LICENSE-2.0
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.rest.controller
  23
  24 import static org.onap.cps.spi.FetchDescendantsOption.INCLUDE_ALL_DESCENDANTS
  25 import static org.onap.cps.spi.FetchDescendantsOption.OMIT_DESCENDANTS
  26 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  27 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.patch
  28 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  29 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.put
  30
  31 import org.modelmapper.ModelMapper
  32 import org.onap.cps.api.CpsAdminService
  33 import org.onap.cps.api.CpsDataService
  34 import org.onap.cps.api.CpsModuleService
  35 import org.onap.cps.api.CpsQueryService
  36 import org.onap.cps.spi.exceptions.AnchorNotFoundException
  37 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  38 import org.onap.cps.spi.exceptions.DataspaceNotFoundException
  39 import org.onap.cps.spi.model.DataNode
  40 import org.onap.cps.spi.model.DataNodeBuilder
  41 import org.spockframework.spring.SpringBean
  42 import org.springframework.beans.factory.annotation.Autowired
  43 import org.springframework.beans.factory.annotation.Value
  44 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  45 import org.springframework.http.HttpStatus
  46 import org.springframework.http.MediaType
  47 import org.springframework.test.web.servlet.MockMvc
  48 import spock.lang.Shared
  49 import spock.lang.Unroll
  50
  51 @WebMvcTest
  52 class DataRestControllerSpec extends RestControllerSpecification {
  53
  54     @SpringBean
  55     CpsDataService mockCpsDataService = Mock()
  56
  57     @SpringBean
  58     CpsModuleService mockCpsModuleService = Mock()
  59
  60     @SpringBean
  61     CpsAdminService mockCpsAdminService = Mock()
  62
  63     @SpringBean
  64     CpsQueryService mockCpsQueryService = Mock()
  65
  66     @SpringBean
  67     ModelMapper modelMapper = Mock()
  68
  69     @Autowired
  70     MockMvc mvc
  71
  72     @Value('${rest.api.cps-base-path}')
  73     def basePath
  74
  75     def dataNodeBaseEndpoint
  76     def dataspaceName = 'my_dataspace'
  77     def anchorName = 'my_anchor'
  78
  79     @Shared
  80     static DataNode dataNodeWithLeavesNoChildren = new DataNodeBuilder().withXpath('/xpath')
  81             .withLeaves([leaf: 'value', leafList: ['leaveListElement1', 'leaveListElement2']]).build()
  82
  83     @Shared
  84     static DataNode dataNodeWithChild = new DataNodeBuilder().withXpath('/parent')
  85             .withChildDataNodes([new DataNodeBuilder().withXpath("/parent/child").build()]).build()
  86
  87     def setup() {
  88         dataNodeBaseEndpoint = "$basePath/v1/dataspaces/$dataspaceName"
  89     }
  90
  91     def 'Create a node.'() {
  92         given: 'some json to create a data node'
  93             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/nodes"
  94             def json = 'some json (this is not validated)'
  95         when: 'post is invoked with datanode endpoint and json'
  96             def response =
  97                     mvc.perform(
  98                             post(endpoint)
  99                                     .header("Authorization", getAuthorizationHeader())
 100                                     .contentType(MediaType.APPLICATION_JSON).content(json))
 101                             .andReturn().response
 102         then: 'a created response is returned'
 103             response.status == HttpStatus.CREATED.value()
 104         then: 'the java API was called with the correct parameters'
 105             1 * mockCpsDataService.saveData(dataspaceName, anchorName, json)
 106     }
 107
 108     @Unroll
 109     def 'Get data node with leaves'() {
 110         given: 'the service returns data node leaves'
 111             def xpath = 'some xPath'
 112             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/node"
 113             mockCpsDataService.getDataNode(dataspaceName, anchorName, xpath, OMIT_DESCENDANTS) >> dataNodeWithLeavesNoChildren
 114         when: 'get request is performed through REST API'
 115             def response =
 116                     mvc.perform(get(endpoint).header("Authorization", getAuthorizationHeader()).param('xpath', xpath))
 117                             .andReturn().response
 118         then: 'a success response is returned'
 119             response.status == HttpStatus.OK.value()
 120         and: 'response contains expected leaf and value'
 121             response.contentAsString.contains('"leaf":"value"')
 122         and: 'response contains expected leaf-list and values'
 123             response.contentAsString.contains('"leafList":["leaveListElement1","leaveListElement2"]')
 124     }
 125
 126     @Unroll
 127     def 'Get data node with #scenario.'() {
 128         given: 'the service returns data node with #scenario'
 129             def xpath = 'some xPath'
 130             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/node"
 131             mockCpsDataService.getDataNode(dataspaceName, anchorName, xpath, expectedCpsDataServiceOption) >> dataNode
 132         when: 'get request is performed through REST API'
 133             def response =
 134                     mvc.perform(
 135                             get(endpoint)
 136                                     .header("Authorization", getAuthorizationHeader())
 137                                     .param('xpath', xpath)
 138                                     .param('include-descendants', includeDescendantsOption))
 139                             .andReturn().response
 140         then: 'a success response is returned'
 141             response.status == HttpStatus.OK.value()
 142         and: 'the response contains child is #expectChildInResponse'
 143             response.contentAsString.contains('"child"') == expectChildInResponse
 144         where:
 145             scenario                    | dataNode                     | includeDescendantsOption || expectedCpsDataServiceOption | expectChildInResponse
 146             'no descendants by default' | dataNodeWithLeavesNoChildren | ''                       || OMIT_DESCENDANTS             | false
 147             'no descendant explicitly'  | dataNodeWithLeavesNoChildren | 'false'                  || OMIT_DESCENDANTS             | false
 148             'with descendants'          | dataNodeWithChild            | 'true'                   || INCLUDE_ALL_DESCENDANTS      | true
 149     }
 150
 151     @Unroll
 152     def 'Get data node error scenario: #scenario.'() {
 153         given: 'the service throws an exception'
 154             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/node"
 155             mockCpsDataService.getDataNode(dataspaceName, anchorName, xpath, _) >> { throw exception }
 156         when: 'get request is performed through REST API'
 157             def response =
 158                     mvc.perform(get(endpoint).header("Authorization", getAuthorizationHeader()).param("xpath", xpath))
 159                             .andReturn().response
 160         then: 'a success response is returned'
 161             response.status == httpStatus.value()
 162         where:
 163             scenario       | xpath     | exception                                 || httpStatus
 164             'no dataspace' | '/x-path' | new DataspaceNotFoundException('')        || HttpStatus.BAD_REQUEST
 165             'no anchor'    | '/x-path' | new AnchorNotFoundException('', '')       || HttpStatus.BAD_REQUEST
 166             'no data'      | '/x-path' | new DataNodeNotFoundException('', '', '') || HttpStatus.NOT_FOUND
 167             'empty path'   | ''        | new IllegalStateException()               || HttpStatus.NOT_IMPLEMENTED
 168     }
 169
 170     @Unroll
 171     def 'Update data node leaves: #scenario.'() {
 172         given: 'json data'
 173             def jsonData = 'json data'
 174             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/nodes"
 175         when: 'patch request is performed'
 176             def response =
 177                     mvc.perform(
 178                             patch(endpoint)
 179                                     .contentType(MediaType.APPLICATION_JSON)
 180                                     .content(jsonData)
 181                                     .header("Authorization", getAuthorizationHeader())
 182                                     .param('xpath', xpath)
 183                     ).andReturn().response
 184         then: 'the service method is invoked with expected parameters'
 185             1 * mockCpsDataService.updateNodeLeaves(dataspaceName, anchorName, xpathServiceParameter, jsonData)
 186         and: 'response status indicates success'
 187             response.status == HttpStatus.OK.value()
 188         where:
 189             scenario               | xpath    | xpathServiceParameter
 190             'root node by default' | ''       | '/'
 191             'node by parent xpath' | '/xpath' | '/xpath'
 192     }
 193
 194     @Unroll
 195     def 'Replace data node tree: #scenario.'() {
 196         given: 'json data'
 197             def jsonData = 'json data'
 198             def endpoint = "$dataNodeBaseEndpoint/anchors/$anchorName/nodes"
 199         when: 'put request is performed'
 200             def response =
 201                     mvc.perform(
 202                             put(endpoint)
 203                                     .contentType(MediaType.APPLICATION_JSON)
 204                                     .content(jsonData)
 205                                     .header("Authorization", getAuthorizationHeader())
 206                                     .param('xpath', xpath))
 207                             .andReturn().response
 208         then: 'the service method is invoked with expected parameters'
 209             1 * mockCpsDataService.replaceNodeTree(dataspaceName, anchorName, xpathServiceParameter, jsonData)
 210         and: 'response status indicates success'
 211             response.status == HttpStatus.OK.value()
 212         where:
 213             scenario               | xpath    | xpathServiceParameter
 214             'root node by default' | ''       | '/'
 215             'node by parent xpath' | '/xpath' | '/xpath'
 216     }
 217 }