cps-rest/src/test/groovy/org/onap/cps/rest/controller/AdminRestControllerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2020 Pantheon.tech
   4  *  Modifications Copyright (C) 2020 Bell Canada. All rights reserved.
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.rest.controller
  22
  23 import org.modelmapper.ModelMapper
  24 import org.onap.cps.api.CpsAdminService
  25 import org.onap.cps.api.CpsModuleService
  26 import org.onap.cps.spi.model.Anchor
  27 import org.onap.cps.spi.exceptions.DataspaceAlreadyDefinedException
  28 import org.spockframework.spring.SpringBean
  29 import org.springframework.beans.factory.annotation.Autowired
  30 import org.springframework.boot.test.autoconfigure.web.servlet.AutoConfigureMockMvc
  31 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  32 import org.springframework.http.HttpStatus
  33 import org.springframework.http.MediaType
  34 import org.springframework.mock.web.MockMultipartFile
  35 import org.springframework.test.web.servlet.MockMvc
  36 import org.springframework.test.web.servlet.request.MockMvcRequestBuilders
  37 import org.springframework.util.LinkedMultiValueMap
  38 import org.springframework.util.MultiValueMap
  39 import spock.lang.Specification
  40
  41 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  42 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  43
  44 @WebMvcTest
  45 class AdminRestControllerSpec extends Specification {
  46
  47     @SpringBean
  48     CpsModuleService mockCpsModuleService = Mock()
  49
  50     @SpringBean
  51     CpsAdminService mockCpsAdminService = Mock()
  52
  53     @SpringBean
  54     ModelMapper modelMapper = Mock()
  55
  56     @Autowired
  57     MockMvc mvc
  58
  59     def anchorsEndpoint = '/v1/dataspaces/my_dataspace/anchors'
  60
  61     def anchor = new Anchor(name: 'my_anchor')
  62     def anchorList = [anchor]
  63
  64     def 'Create new dataspace'() {
  65         when:
  66             def response = performCreateDataspaceRequest("new-dataspace")
  67         then: 'Service method is invoked with expected parameters'
  68             1 * mockCpsAdminService.createDataspace("new-dataspace")
  69         and:
  70             response.status == HttpStatus.CREATED.value()
  71     }
  72
  73     def 'Create dataspace over existing with same name'() {
  74         given:
  75             def thrownException = new DataspaceAlreadyDefinedException("", new RuntimeException())
  76             mockCpsAdminService.createDataspace("existing-dataspace") >> { throw thrownException }
  77         when:
  78             def response = performCreateDataspaceRequest("existing-dataspace")
  79         then:
  80             response.status == HttpStatus.BAD_REQUEST.value()
  81     }
  82
  83     def 'Create schema set from yang file'() {
  84         def yangResourceMapCapture
  85         given:
  86             def multipartFile = createMultipartFile("filename.yang", "content")
  87         when:
  88             def response = performCreateSchemaSetRequest(multipartFile)
  89         then: 'Service method is invoked with expected parameters'
  90             1 * mockCpsModuleService.createSchemaSet('test-dataspace', 'test-schema-set', _) >>
  91                     { args -> yangResourceMapCapture = args[2] }
  92             yangResourceMapCapture['filename.yang'] == 'content'
  93         and: 'Response code indicates success'
  94             response.status == HttpStatus.CREATED.value()
  95     }
  96
  97     def 'Create schema set from file with invalid filename extension'() {
  98         given:
  99             def multipartFile = createMultipartFile("filename.doc", "content")
 100         when:
 101             def response = performCreateSchemaSetRequest(multipartFile)
 102         then:
 103             response.status == HttpStatus.BAD_REQUEST.value()
 104     }
 105
 106     def performCreateDataspaceRequest(String dataspaceName) {
 107         return mvc.perform(
 108                 MockMvcRequestBuilders
 109                         .post('/v1/dataspaces')
 110                         .param('dataspace-name', dataspaceName)
 111         ).andReturn().response
 112     }
 113
 114     def createMultipartFile(filename, content) {
 115         return new MockMultipartFile("file", filename, "text/plain", content.getBytes())
 116     }
 117
 118     def performCreateSchemaSetRequest(multipartFile) {
 119         return mvc.perform(
 120                 MockMvcRequestBuilders
 121                         .multipart('/v1/dataspaces/test-dataspace/schema-sets')
 122                         .file(multipartFile)
 123                         .param('schemaSetName', 'test-schema-set')
 124         ).andReturn().response
 125     }
 126
 127     def 'when createAnchor API is called, the response status is 201. '() {
 128         given:
 129             def requestParams = new LinkedMultiValueMap<>()
 130             requestParams.add('schema-set-name', 'my_schema-set')
 131             requestParams.add('anchor-name', 'my_anchor')
 132         when: 'post is invoked'
 133             def response = mvc.perform(post(anchorsEndpoint).contentType(MediaType.APPLICATION_JSON)
 134                     .params(requestParams as MultiValueMap)).andReturn().response
 135         then: 'Status is 201 and the response is the name of the created anchor -> my_anchor'
 136             1 * mockCpsAdminService.createAnchor('my_dataspace', 'my_schema-set', 'my_anchor')
 137             assert response.status == HttpStatus.CREATED.value()
 138             assert response.getContentAsString().contains('my_anchor')
 139     }
 140
 141     def 'when get all anchors for a dataspace API is called, the response status is 200 '() {
 142         given:
 143             mockCpsAdminService.getAnchors('my_dataspace') >> anchorList
 144         when: 'get all anchors API is invoked'
 145             def response = mvc.perform(get(anchorsEndpoint)).andReturn().response
 146         then: 'Status is 200 and the response is Collection of Anchors containing anchor name -> my_anchor'
 147             assert response.status == HttpStatus.OK.value()
 148             assert response.getContentAsString().contains('my_anchor')
 149     }
 150 }