cps-path-parser/src/test/groovy/org/onap/cps/cpspath/parser/CpsPathQuerySpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021-2023 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.cpspath.parser
  23
  24 import spock.lang.Specification
  25
  26 import static org.onap.cps.cpspath.parser.CpsPathPrefixType.ABSOLUTE
  27 import static org.onap.cps.cpspath.parser.CpsPathPrefixType.DESCENDANT
  28
  29 class CpsPathQuerySpec extends Specification {
  30
  31     def 'Parse cps path with valid cps path and a filter with #scenario.'() {
  32         when: 'the given cps path is parsed'
  33             def result = CpsPathQuery.createFrom(cpsPath)
  34         then: 'the query has the right xpath type'
  35             assert result.cpsPathPrefixType == ABSOLUTE
  36         and: 'the right query parameters are set'
  37             assert result.xpathPrefix == expectedXpathPrefix
  38             assert result.hasLeafConditions()
  39             assert result.leavesData[0].name == expectedLeafName
  40             assert result.leavesData[0].value == expectedLeafValue
  41         where: 'the following data is used'
  42             scenario               | cpsPath                                                    || expectedXpathPrefix                             | expectedLeafName       | expectedLeafValue
  43             'leaf of type String'  | '/parent/child[@common-leaf-name="common-leaf-value"]'     || '/parent/child'                                 | 'common-leaf-name'     | 'common-leaf-value'
  44             'leaf of type String'  | '/parent/child[@common-leaf-name=\'common-leaf-value\']'   || '/parent/child'                                 | 'common-leaf-name'     | 'common-leaf-value'
  45             'leaf of type Integer' | '/parent/child[@common-leaf-name-int=5]'                   || '/parent/child'                                 | 'common-leaf-name-int' | 5
  46             'spaces around ='      | '/parent/child[@common-leaf-name-int = 5]'                 || '/parent/child'                                 | 'common-leaf-name-int' | 5
  47             'key in top container' | '/parent[@common-leaf-name-int=5]'                         || '/parent'                                       | 'common-leaf-name-int' | 5
  48             'parent list'          | '/shops/shop[@id=1]/categories[@id=1]/book[@title="Dune"]' || "/shops/shop[@id='1']/categories[@id='1']/book" | 'title'                | 'Dune'
  49     }
  50
  51     def 'Parse cps path of type ends with a #scenario.'() {
  52         when: 'the given cps path is parsed'
  53             def result = CpsPathQuery.createFrom(cpsPath)
  54         then: 'the query has the right xpath type'
  55             result.cpsPathPrefixType == DESCENDANT
  56         and: 'the right ends with parameters are set'
  57             result.descendantName == expectedDescendantName
  58         where: 'the following data is used'
  59             scenario         | cpsPath          || expectedDescendantName
  60             'yang container' | '//cps-path'     || 'cps-path'
  61             'parent & child' | '//parent/child' || 'parent/child'
  62     }
  63
  64     def 'Parse cps path to form the Normalized cps path containing #scenario.'() {
  65         when: 'the given cps path is parsed'
  66             def result = CpsPathUtil.getCpsPathQuery(cpsPath)
  67         then: 'the query has the right normalized xpath type'
  68             assert result.normalizedXpath == expectedNormalizedXPath
  69         where: 'the following data is used'
  70             scenario                                                      | cpsPath                                                        || expectedNormalizedXPath
  71             'yang container'                                              | '/cps-path'                                                    || '/cps-path'
  72             'descendant anywhere'                                         | '//cps-path'                                                   || '//cps-path'
  73             'descendant with leaf condition'                              | '//cps-path[@key=1]'                                           || "//cps-path[@key='1']"
  74             'descendant with leaf condition has ">" operator'             | '//cps-path[@key>9]'                                           || "//cps-path[@key>'9']"
  75             'descendant with leaf condition has "<" operator'             | '//cps-path[@key<10]'                                          || "//cps-path[@key<'10']"
  76             'descendant with leaf condition has ">=" operator'            | '//cps-path[@key>=8]'                                          || "//cps-path[@key>='8']"
  77             'descendant with leaf condition has "<=" operator'            | '//cps-path[@key<=12]'                                         || "//cps-path[@key<='12']"
  78             'descendant with leaf value and ancestor'                     | '//cps-path[@key=1]/ancestor:parent[@key=1]'                   || "//cps-path[@key='1']/ancestor:parent[@key='1']"
  79             'parent & child'                                              | '/parent/child'                                                || '/parent/child'
  80             'parent leaf of type Integer & child'                         | '/parent/child[@code=1]/child2'                                || "/parent/child[@code='1']/child2"
  81             'parent leaf with double quotes'                              | '/parent/child[@code="1"]/child2'                              || "/parent/child[@code='1']/child2"
  82             'parent leaf with double quotes inside single quotes'         | '/parent/child[@code=\'"1"\']/child2'                          || "/parent/child[@code='\"1\"']/child2"
  83             'parent leaf with single quotes inside double quotes'         | '/parent/child[@code="\'1\'"]/child2'                          || "/parent/child[@code='\\\'1\\\'']/child2"
  84             'leaf with single quotes inside double quotes'                | '/parent/child[@code="\'1\'"]'                                 || "/parent/child[@code='\\\'1\\\'']"
  85             'leaf with more than one attribute'                           | '/parent/child[@key1=1 and @key2="abc"]'                       || "/parent/child[@key1='1' and @key2='abc']"
  86             'parent & child with more than one attribute'                 | '/parent/child[@key1=1 and @key2="abc"]/child2'                || "/parent/child[@key1='1' and @key2='abc']/child2"
  87             'leaf with more than one attribute has OR operator'           | '/parent/child[@key1=1 or @key2="abc"]'                        || "/parent/child[@key1='1' or @key2='abc']"
  88             'parent & child with more than one attribute has OR operator' | '/parent/child[@key1=1 or @key2="abc"]/child2'                 || "/parent/child[@key1='1' or @key2='abc']/child2"
  89             'parent & child with multiple AND  operators'                 | '/parent/child[@key1=1 and @key2="abc" and @key="xyz"]/child2' || "/parent/child[@key1='1' and @key2='abc' and @key='xyz']/child2"
  90             'parent & child with multiple OR  operators'                  | '/parent/child[@key1=1 or @key2="abc" or @key="xyz"]/child2'   || "/parent/child[@key1='1' or @key2='abc' or @key='xyz']/child2"
  91             'parent & child with multiple AND/OR combination'             | '/parent/child[@key1=1 and @key2="abc" or @key="xyz"]/child2'  || "/parent/child[@key1='1' and @key2='abc' or @key='xyz']/child2"
  92             'parent & child with multiple OR/AND combination'             | '/parent/child[@key1=1 or @key2="abc" and @key="xyz"]/child2'  || "/parent/child[@key1='1' or @key2='abc' and @key='xyz']/child2"
  93     }
  94
  95     def 'Parse xpath to form the Normalized xpath containing #scenario.'() {
  96         when: 'the given xpath is parsed'
  97             def result = CpsPathUtil.getNormalizedXpath(xPath)
  98         then: 'the query has the right normalized xpath type'
  99             assert result == expectedNormalizedXPath
 100         where: 'the following data is used'
 101             scenario               | xPath      || expectedNormalizedXPath
 102             'yang container'       | '/xpath'   || '/xpath'
 103             'descendant anywhere'  | '//xpath'  || '//xpath'
 104     }
 105
 106     def 'Parse cps path that ends with a yang list containing multiple leaf conditions.'() {
 107         when: 'the given cps path is parsed'
 108             def result = CpsPathQuery.createFrom(cpsPath)
 109         then: 'the expected number of leaves are returned'
 110             result.leavesData.size() == expectedNumberOfLeaves
 111         and: 'the given operator(s) returns in the correct order'
 112             result.booleanOperators == expectedOperators
 113         and: 'the given comparativeOperator(s) returns in the correct order'
 114             result.comparativeOperators == expectedComparativeOperator
 115         where: 'the following data is used'
 116             cpsPath                                                                                   || expectedNumberOfLeaves || expectedOperators || expectedComparativeOperator
 117             '/parent[@code=1]/child[@common-leaf-name-int=5]'                                         || 1                      || []                || ['=']
 118             '//child[@int-leaf>15 and @leaf-name="leaf value"]'                                       || 2                      || ['and']           || ['>', '=']
 119             '//child[@int-leaf<5 or @leaf-name="leaf value"]'                                         || 2                      || ['or']            || ['<', '=']
 120             '//child[@int-leaf=5 and @common-leaf-name="leaf value" or @leaf-name="leaf value1" ]'    || 3                      || ['and', 'or']     || ['=', '=', '=']
 121             '//child[@int-leaf=5 or @common-leaf-name="leaf value" and @leaf-name="leaf value1" ]'    || 3                      || ['or', 'and']     || ['=', '=', '=']
 122             '//child[@int-leaf>=18 and @common-leaf-name="leaf value" and @leaf-name="leaf value1" ]' || 3                      || ['and', 'and']    || ['>=', '=', '=']
 123             '//child[@int-leaf<=25 or @common-leaf-name="leaf value" or @leaf-name="leaf value1" ]'   || 3                      || ['or', 'or']      || ['<=', '=', '=']
 124     }
 125
 126     def 'Parse #scenario cps path with text function condition'() {
 127         when: 'the given cps path is parsed'
 128             def result = CpsPathQuery.createFrom(cpsPath)
 129         then: 'the query has the right xpath type'
 130             result.cpsPathPrefixType == DESCENDANT
 131         and: 'leaf conditions are only present when expected'
 132             result.hasLeafConditions() == expectLeafConditions
 133         and: 'the right text function condition is set'
 134             result.hasTextFunctionCondition()
 135             result.textFunctionConditionLeafName == 'leaf-name'
 136             result.textFunctionConditionValue == 'search'
 137         and: 'the ancestor is only present when expected'
 138             assert result.hasAncestorAxis() == expectHasAncestorAxis
 139         where: 'the following data is used'
 140             scenario                                  | cpsPath                                                              || expectLeafConditions | expectHasAncestorAxis
 141             'descendant anywhere'                     | '//someContainer/leaf-name[text()="search"]'                         || false                | false
 142             'descendant with leaf value'              | '//child[@other-leaf=1]/leaf-name[text()="search"]'                  || true                 | false
 143             'descendant anywhere and ancestor'        | '//someContainer/leaf-name[text()="search"]/ancestor::parent'        || false                | true
 144             'descendant with leaf value and ancestor' | '//child[@other-leaf=1]/leaf-name[text()="search"]/ancestor::parent' || true                 | true
 145     }
 146
 147     def 'Parse cps path with contains function condition'() {
 148         when: 'the given cps path is parsed'
 149             def result = CpsPathQuery.createFrom('//someContainer[contains(@lang,"en")]')
 150         then: 'the query has the right xpath type'
 151             result.cpsPathPrefixType == DESCENDANT
 152         and: 'the right contains function condition is set'
 153             result.hasContainsFunctionCondition()
 154             result.containsFunctionConditionLeafName == 'lang'
 155             result.containsFunctionConditionValue == 'en'
 156     }
 157
 158     def 'Parse cps path with error: #scenario.'() {
 159         when: 'the given cps path is parsed'
 160             CpsPathQuery.createFrom(cpsPath)
 161         then: 'a CpsPathException is thrown'
 162             thrown(PathParsingException)
 163         where: 'the following data is used'
 164             scenario                                 | cpsPath
 165             'no / at the start'                      | 'invalid-cps-path/child'
 166             'additional / after descendant option'   | '///cps-path'
 167             'float value'                            | '/parent/child[@someFloat=5.0]'
 168             'unmatched quotes, double quote first '  | '/parent/child[@someString="value with unmatched quotes\']'
 169             'unmatched quotes, single quote first'   | '/parent/child[@someString=\'value with unmatched quotes"]'
 170             'missing attribute value'                | '//child[@int-leaf=5 and @name]'
 171             'incomplete ancestor value'              | '//books/ancestor::'
 172             'invalid list element with missing ['    | '/parent-206/child-206/grand-child-206@key="A"]'
 173             'invalid list element with incorrect ]'  | '/parent-206/child-206/grand-child-206]@key="A"]'
 174             'invalid list element with incorrect ::' | '/parent-206/child-206/grand-child-206::@key"A"]'
 175     }
 176
 177     def 'Parse cps path using ancestor by schema node identifier with a #scenario.'() {
 178         when: 'the given cps path is parsed'
 179             def result = CpsPathQuery.createFrom('//descendant/ancestor::' + ancestorPath)
 180         then: 'the query has the right type'
 181             result.cpsPathPrefixType == DESCENDANT
 182         and: 'the result has ancestor axis'
 183             result.hasAncestorAxis()
 184         and: 'the correct ancestor schema node identifier is set'
 185             result.ancestorSchemaNodeIdentifier == ancestorPath
 186         and: 'there are no leaves conditions'
 187             result.hasLeafConditions() == false
 188         where:
 189             scenario                                    | ancestorPath
 190             'basic container'                           | 'someContainer'
 191             'container with parent'                     | 'parent/child'
 192             'ancestor that is a list'                   | "categories[@code='1']"
 193             'ancestor that is a list with compound key' | "categories[@key1='1' and @key2='2']"
 194             'parent that is a list'                     | "parent[@id='1']/child"
 195     }
 196
 197     def 'Combinations #scenario.'() {
 198         when: 'the given cps path is parsed'
 199             def result = CpsPathQuery.createFrom(cpsPath + '/ancestor::someAncestor')
 200         then: 'the query has the right type'
 201             result.cpsPathPrefixType == DESCENDANT
 202         and: 'leaf conditions are only present when expected'
 203             result.hasLeafConditions() == expectLeafConditions
 204         and: 'the result has ancestor axis'
 205             result.hasAncestorAxis()
 206         and: 'the correct ancestor schema node identifier is set'
 207             result.ancestorSchemaNodeIdentifier == 'someAncestor'
 208             result.descendantName == expectedDescendantName
 209         where:
 210             scenario                     | cpsPath                               || expectedDescendantName   | expectLeafConditions
 211             'basic container'            | '//someContainer'                     || 'someContainer'          | false
 212             'container with parent'      | '//parent/child'                      || 'parent/child'           | false
 213             'container with list-parent' | '//parent[@id=1]/child'               || "parent[@id='1']/child"  | false
 214             'container with list-parent' | '//parent[@id=1]/child[@name="test"]' || "parent[@id='1']/child"  | true
 215     }
 216
 217     def 'Parse cps path with multiple conditions on same leaf.'() {
 218         when: 'the given cps path is parsed using multiple conditions on same leaf'
 219             def result = CpsPathQuery.createFrom('/test[@same-name="value1" or @same-name="value2"]')
 220         then: 'two leaves are present with correct values'
 221             assert result.leavesData.size() == 2
 222             assert result.leavesData[0].name == "same-name"
 223             assert result.leavesData[0].value == "value1"
 224             assert result.leavesData[1].name == "same-name"
 225             assert result.leavesData[1].value == "value2"
 226     }
 227
 228     def 'Ordering of data leaves is preserved.'() {
 229         when: 'the given cps path is parsed'
 230             def result = CpsPathQuery.createFrom(cpsPath)
 231         then: 'the order of the data leaves is preserved'
 232             assert result.leavesData[0].name == expectedFirstLeafName
 233             assert result.leavesData[1].name == expectedSecondLeafName
 234         where: 'the following data is used'
 235             cpsPath                                      || expectedFirstLeafName | expectedSecondLeafName
 236             '/test[@name1="value1" and @name2="value2"]' || 'name1'               | 'name2'
 237             '/test[@name2="value2" and @name1="value1"]' || 'name2'               | 'name1'
 238     }
 239
 240 }