cps-path-parser/src/test/groovy/org/onap/cps/cpspath/parser/CpsPathQuerySpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021-2022 Nordix Foundation
   4  *  Modifications Copyright (C) 2023 TechMahindra Ltd
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.cpspath.parser
  23
  24 import spock.lang.Specification
  25
  26 import static org.onap.cps.cpspath.parser.CpsPathPrefixType.ABSOLUTE
  27 import static org.onap.cps.cpspath.parser.CpsPathPrefixType.DESCENDANT
  28
  29 class CpsPathQuerySpec extends Specification {
  30
  31     def 'Parse cps path with valid cps path and a filter with #scenario.'() {
  32         when: 'the given cps path is parsed'
  33             def result = CpsPathQuery.createFrom(cpsPath)
  34         then: 'the query has the right xpath type'
  35             result.cpsPathPrefixType == ABSOLUTE
  36         and: 'the right query parameters are set'
  37             result.xpathPrefix == expectedXpathPrefix
  38             result.hasLeafConditions()
  39             result.leavesData.containsKey(expectedLeafName)
  40             result.leavesData.get(expectedLeafName) == expectedLeafValue
  41         where: 'the following data is used'
  42             scenario               | cpsPath                                                    || expectedXpathPrefix                             | expectedLeafName       | expectedLeafValue
  43             'leaf of type String'  | '/parent/child[@common-leaf-name="common-leaf-value"]'     || '/parent/child'                                 | 'common-leaf-name'     | 'common-leaf-value'
  44             'leaf of type String'  | '/parent/child[@common-leaf-name=\'common-leaf-value\']'   || '/parent/child'                                 | 'common-leaf-name'     | 'common-leaf-value'
  45             'leaf of type Integer' | '/parent/child[@common-leaf-name-int=5]'                   || '/parent/child'                                 | 'common-leaf-name-int' | 5
  46             'spaces around ='      | '/parent/child[@common-leaf-name-int = 5]'                 || '/parent/child'                                 | 'common-leaf-name-int' | 5
  47             'key in top container' | '/parent[@common-leaf-name-int=5]'                         || '/parent'                                       | 'common-leaf-name-int' | 5
  48             'parent list'          | '/shops/shop[@id=1]/categories[@id=1]/book[@title="Dune"]' || "/shops/shop[@id='1']/categories[@id='1']/book" | 'title'                | 'Dune'
  49     }
  50
  51     def 'Parse cps path of type ends with a #scenario.'() {
  52         when: 'the given cps path is parsed'
  53             def result = CpsPathQuery.createFrom(cpsPath)
  54         then: 'the query has the right xpath type'
  55             result.cpsPathPrefixType == DESCENDANT
  56         and: 'the right ends with parameters are set'
  57             result.descendantName == expectedDescendantName
  58         where: 'the following data is used'
  59             scenario         | cpsPath          || expectedDescendantName
  60             'yang container' | '//cps-path'     || 'cps-path'
  61             'parent & child' | '//parent/child' || 'parent/child'
  62     }
  63
  64     def 'Parse cps path to form the Normalized cps path containing #scenario.'() {
  65         when: 'the given cps path is parsed'
  66             def result = CpsPathUtil.getCpsPathQuery(cpsPath)
  67         then: 'the query has the right normalized xpath type'
  68             assert result.normalizedXpath == expectedNormalizedXPath
  69         where: 'the following data is used'
  70             scenario                                                      | cpsPath                                                        || expectedNormalizedXPath
  71             'yang container'                                              | '/cps-path'                                                    || '/cps-path'
  72             'descendant anywhere'                                         | '//cps-path'                                                   || '//cps-path'
  73             'descendant with leaf condition'                              | '//cps-path[@key=1]'                                           || "//cps-path[@key='1']"
  74             'descendant with leaf value and ancestor'                     | '//cps-path[@key=1]/ancestor:parent[@key=1]'                   || "//cps-path[@key='1']/ancestor:parent[@key='1']"
  75             'parent & child'                                              | '/parent/child'                                                || '/parent/child'
  76             'parent leaf of type Integer & child'                         | '/parent/child[@code=1]/child2'                                || "/parent/child[@code='1']/child2"
  77             'parent leaf with double quotes'                              | '/parent/child[@code="1"]/child2'                              || "/parent/child[@code='1']/child2"
  78             'parent leaf with double quotes inside single quotes'         | '/parent/child[@code=\'"1"\']/child2'                          || "/parent/child[@code='\"1\"']/child2"
  79             'parent leaf with single quotes inside double quotes'         | '/parent/child[@code="\'1\'"]/child2'                          || "/parent/child[@code='\\\'1\\\'']/child2"
  80             'leaf with single quotes inside double quotes'                | '/parent/child[@code="\'1\'"]'                                 || "/parent/child[@code='\\\'1\\\'']"
  81             'leaf with more than one attribute'                           | '/parent/child[@key1=1 and @key2="abc"]'                       || "/parent/child[@key1='1' and @key2='abc']"
  82             'parent & child with more than one attribute'                 | '/parent/child[@key1=1 and @key2="abc"]/child2'                || "/parent/child[@key1='1' and @key2='abc']/child2"
  83             'leaf with more than one attribute has OR operator'           | '/parent/child[@key1=1 or @key2="abc"]'                        || "/parent/child[@key1='1' or @key2='abc']"
  84             'parent & child with more than one attribute has OR operator' | '/parent/child[@key1=1 or @key2="abc"]/child2'                 || "/parent/child[@key1='1' or @key2='abc']/child2"
  85             'parent & child with multiple AND  operators'                 | '/parent/child[@key1=1 and @key2="abc" and @key="xyz"]/child2' || "/parent/child[@key1='1' and @key2='abc' and @key='xyz']/child2"
  86             'parent & child with multiple OR  operators'                  | '/parent/child[@key1=1 or @key2="abc" or @key="xyz"]/child2'   || "/parent/child[@key1='1' or @key2='abc' or @key='xyz']/child2"
  87     }
  88
  89     def 'Parse xpath to form the Normalized xpath containing #scenario.'() {
  90         when: 'the given xpath is parsed'
  91             def result = CpsPathUtil.getNormalizedXpath(xPath)
  92         then: 'the query has the right normalized xpath type'
  93             assert result == expectedNormalizedXPath
  94         where: 'the following data is used'
  95             scenario               | xPath      || expectedNormalizedXPath
  96             'yang container'       | '/xpath'   || '/xpath'
  97             'descendant anywhere'  | '//xpath'  || '//xpath'
  98     }
  99
 100     def 'Parse cps path that ends with a yang list containing #scenario.'() {
 101         when: 'the given cps path is parsed'
 102             def result = CpsPathQuery.createFrom(cpsPath)
 103         then: 'the query has the right xpath type'
 104             result.cpsPathPrefixType == DESCENDANT
 105         and: 'the right parameters are set'
 106             result.descendantName == "child"
 107             result.leavesData.size() == expectedNumberOfLeaves
 108             result.booleanOperatorsType == expectedOperators
 109         where: 'the following data is used'
 110             scenario                                                   | cpsPath                                                                          || expectedNumberOfLeaves || expectedOperators
 111             'one attribute'                                            | '//child[@common-leaf-name-int=5]'                                               || 1                      || null
 112             'more than one attribute has AND operator'                 | '//child[@int-leaf=5 and @leaf-name="leaf value"]'                               || 2                      || ['and']
 113             'more than one attribute has OR operator'                  | '//child[@int-leaf=5 or @leaf-name="leaf value"]'                                || 2                      || ['or']
 114             'more than one attribute has combinations and/or operator' | '//child[@int-leaf=5 and @leaf-name="leaf value" and @leaf-name="leaf value1" ]' || 2                      || ['and', 'and']
 115             'more than one attribute has combinations or/and operator' | '//child[@int-leaf=5 or @leaf-name="leaf value" or @leaf-name="leaf value1" ]'   || 2                      || ['or', 'or']
 116     }
 117
 118     def 'Parse #scenario cps path with text function condition'() {
 119         when: 'the given cps path is parsed'
 120             def result = CpsPathQuery.createFrom(cpsPath)
 121         then: 'the query has the right xpath type'
 122             result.cpsPathPrefixType == DESCENDANT
 123         and: 'leaf conditions are only present when expected'
 124             result.hasLeafConditions() == expectLeafConditions
 125         and: 'the right text function condition is set'
 126             result.hasTextFunctionCondition()
 127             result.textFunctionConditionLeafName == 'leaf-name'
 128             result.textFunctionConditionValue == 'search'
 129         and: 'the ancestor is only present when expected'
 130             assert result.hasAncestorAxis() == expectHasAncestorAxis
 131         where: 'the following data is used'
 132             scenario                                  | cpsPath                                                              || expectLeafConditions | expectHasAncestorAxis
 133             'descendant anywhere'                     | '//someContainer/leaf-name[text()="search"]'                         || false                | false
 134             'descendant with leaf value'              | '//child[@other-leaf=1]/leaf-name[text()="search"]'                  || true                 | false
 135             'descendant anywhere and ancestor'        | '//someContainer/leaf-name[text()="search"]/ancestor::parent'        || false                | true
 136             'descendant with leaf value and ancestor' | '//child[@other-leaf=1]/leaf-name[text()="search"]/ancestor::parent' || true                 | true
 137     }
 138
 139     def 'Parse cps path with error: #scenario.'() {
 140         when: 'the given cps path is parsed'
 141             CpsPathQuery.createFrom(cpsPath)
 142         then: 'a CpsPathException is thrown'
 143             thrown(PathParsingException)
 144         where: 'the following data is used'
 145             scenario                                 | cpsPath
 146             'no / at the start'                      | 'invalid-cps-path/child'
 147             'additional / after descendant option'   | '///cps-path'
 148             'float value'                            | '/parent/child[@someFloat=5.0]'
 149             'unmatched quotes, double quote first '  | '/parent/child[@someString="value with unmatched quotes\']'
 150             'unmatched quotes, single quote first'   | '/parent/child[@someString=\'value with unmatched quotes"]'
 151             'missing attribute value'                | '//child[@int-leaf=5 and @name]'
 152             'incomplete ancestor value'              | '//books/ancestor::'
 153             'invalid list element with missing ['    | '/parent-206/child-206/grand-child-206@key="A"]'
 154             'invalid list element with incorrect ]'  | '/parent-206/child-206/grand-child-206]@key="A"]'
 155             'invalid list element with incorrect ::' | '/parent-206/child-206/grand-child-206::@key"A"]'
 156     }
 157
 158     def 'Parse cps path using ancestor by schema node identifier with a #scenario.'() {
 159         when: 'the given cps path is parsed'
 160             def result = CpsPathQuery.createFrom('//descendant/ancestor::' + ancestorPath)
 161         then: 'the query has the right type'
 162             result.cpsPathPrefixType == DESCENDANT
 163         and: 'the result has ancestor axis'
 164             result.hasAncestorAxis()
 165         and: 'the correct ancestor schema node identifier is set'
 166             result.ancestorSchemaNodeIdentifier == ancestorPath
 167         and: 'there are no leaves conditions'
 168             result.hasLeafConditions() == false
 169         where:
 170             scenario                                    | ancestorPath
 171             'basic container'                           | 'someContainer'
 172             'container with parent'                     | 'parent/child'
 173             'ancestor that is a list'                   | "categories[@code='1']"
 174             'ancestor that is a list with compound key' | "categories[@key1='1' and @key2='2']"
 175             'parent that is a list'                     | "parent[@id='1']/child"
 176     }
 177
 178     def 'Combinations #scenario.'() {
 179         when: 'the given cps path is parsed'
 180             def result = CpsPathQuery.createFrom(cpsPath + '/ancestor::someAncestor')
 181         then: 'the query has the right type'
 182             result.cpsPathPrefixType == DESCENDANT
 183         and: 'leaf conditions are only present when expected'
 184             result.hasLeafConditions() == expectLeafConditions
 185         and: 'the result has ancestor axis'
 186             result.hasAncestorAxis()
 187         and: 'the correct ancestor schema node identifier is set'
 188             result.ancestorSchemaNodeIdentifier == 'someAncestor'
 189             result.descendantName == expectedDescendantName
 190         where:
 191             scenario                     | cpsPath                               || expectedDescendantName   | expectLeafConditions
 192             'basic container'            | '//someContainer'                     || 'someContainer'          | false
 193             'container with parent'      | '//parent/child'                      || 'parent/child'           | false
 194             'container with list-parent' | '//parent[@id=1]/child'               || "parent[@id='1']/child"  | false
 195             'container with list-parent' | '//parent[@id=1]/child[@name="test"]' || "parent[@id='1']/child"  | true
 196     }
 197 }