cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/utils/DmiServiceUrlBuilderSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.utils
  22
  23
  24 import static org.onap.cps.ncmp.api.impl.operations.DmiOperations.DataStoreEnum.PASSTHROUGH_RUNNING
  25
  26 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  27 import org.onap.cps.ncmp.api.impl.config.NcmpConfiguration
  28 import org.onap.cps.ncmp.api.impl.utils.DmiServiceUrlBuilder
  29 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  30 import spock.lang.Shared
  31 import spock.lang.Specification
  32
  33 class DmiServiceUrlBuilderSpec extends Specification {
  34
  35     @Shared
  36     YangModelCmHandle yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('dmiServiceName',
  37         'dmiDataServiceName', 'dmiModuleServiceName', new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id'))
  38
  39     NcmpConfiguration.DmiProperties dmiProperties = new NcmpConfiguration.DmiProperties()
  40
  41     def objectUnderTest = new DmiServiceUrlBuilder(dmiProperties)
  42
  43     def 'Create the dmi service url with #scenario.'() {
  44         given: 'uri variables'
  45             dmiProperties.dmiBasePath = 'dmi'
  46             def uriVars = objectUnderTest.populateUriVariables(yangModelCmHandle,
  47                     "cmHandle", PASSTHROUGH_RUNNING)
  48         and: 'query params'
  49                             def uriQueries = objectUnderTest.populateQueryParams(resourceId,
  50                     'optionsParamInQuery', topic)
  51         when: 'a dmi datastore service url is generated'
  52             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  53         then: 'service url is generated as expected'
  54             assert dmiServiceUrl == expectedDmiServiceUrl
  55         where: 'the following parameters are used'
  56             scenario                       | topic               | resourceId   || expectedDmiServiceUrl
  57             'With valid resourceId'        | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  58             'With Empty resourceId'        | 'topicParamInQuery' | ''           || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?options=optionsParamInQuery&topic=topicParamInQuery'
  59             'With Empty dmi base path'     | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  60             'With Empty topicParamInQuery' | ''                  | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery'
  61     }
  62
  63     def 'Populate dmi data store url #scenario.'() {
  64         given: 'uri variables are created'
  65             dmiProperties.dmiBasePath = dmiBasePath
  66             def uriVars = objectUnderTest.populateUriVariables(yangModelCmHandle,
  67                     "cmHandle", PASSTHROUGH_RUNNING)
  68         and: 'null query params'
  69             def uriQueries = objectUnderTest.populateQueryParams(null,
  70                     null, null)
  71         when: 'a dmi datastore service url is generated'
  72             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  73         then: 'the created dmi service url matches the expected'
  74             assert dmiServiceUrl == expectedDmiServiceUrl
  75         where: 'the following parameters are used'
  76             scenario               | decription                                | dmiBasePath || expectedDmiServiceUrl
  77             'with base path  / '   | 'Invalid base path as it starts with /'   | '/dmi'      || 'dmiServiceName//dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  78             'without base path / ' | 'Valid path as it does not starts with /' | 'dmi'       || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  79     }
  80 }