cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/utils/DmiServiceUrlBuilderSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022-2023 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.utils
  22
  23 import static org.onap.cps.ncmp.api.impl.operations.DatastoreType.PASSTHROUGH_RUNNING
  24
  25 import org.onap.cps.ncmp.api.impl.operations.RequiredDmiService
  26 import org.onap.cps.spi.utils.CpsValidator
  27 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  28 import org.onap.cps.ncmp.api.impl.config.NcmpConfiguration
  29 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  30 import spock.lang.Shared
  31 import spock.lang.Specification
  32
  33 class DmiServiceUrlBuilderSpec extends Specification {
  34
  35     @Shared
  36     YangModelCmHandle yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('dmiServiceName',
  37         'dmiDataServiceName', 'dmiModuleServiceName', new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id'))
  38
  39     NcmpConfiguration.DmiProperties dmiProperties = new NcmpConfiguration.DmiProperties()
  40
  41     def mockCpsValidator = Mock(CpsValidator)
  42
  43     def objectUnderTest = new DmiServiceUrlBuilder(dmiProperties, mockCpsValidator)
  44
  45     def 'Create the dmi service url with #scenario.'() {
  46         given: 'uri variables'
  47             dmiProperties.dmiBasePath = 'dmi'
  48             def uriVars = objectUnderTest.populateUriVariables(PASSTHROUGH_RUNNING.datastoreName, yangModelCmHandle.resolveDmiServiceName(RequiredDmiService.DATA),
  49                     "cmHandle")
  50         and: 'query params'
  51                             def uriQueries = objectUnderTest.populateQueryParams(resourceId,
  52                     'optionsParamInQuery', topic)
  53         when: 'a dmi datastore service url is generated'
  54             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  55         then: 'service url is generated as expected'
  56             assert dmiServiceUrl == expectedDmiServiceUrl
  57         where: 'the following parameters are used'
  58             scenario                       | topic               | resourceId   || expectedDmiServiceUrl
  59             'With valid resourceId'        | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  60             'With Empty resourceId'        | 'topicParamInQuery' | ''           || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?options=optionsParamInQuery&topic=topicParamInQuery'
  61             'With Empty dmi base path'     | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  62             'With Empty topicParamInQuery' | ''                  | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery'
  63     }
  64
  65     def 'Populate dmi data store url #scenario.'() {
  66         given: 'uri variables are created'
  67             dmiProperties.dmiBasePath = dmiBasePath
  68             def uriVars = objectUnderTest.populateUriVariables(PASSTHROUGH_RUNNING.datastoreName, yangModelCmHandle.resolveDmiServiceName(RequiredDmiService.DATA),
  69                     "cmHandle")
  70         and: 'null query params'
  71             def uriQueries = objectUnderTest.populateQueryParams(null,
  72                     null, null)
  73         when: 'a dmi datastore service url is generated'
  74             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  75         then: 'the created dmi service url matches the expected'
  76             assert dmiServiceUrl == expectedDmiServiceUrl
  77         where: 'the following parameters are used'
  78             scenario               | decription                                | dmiBasePath || expectedDmiServiceUrl
  79             'with base path  / '   | 'Invalid base path as it starts with /'   | '/dmi'      || 'dmiServiceName//dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  80             'without base path / ' | 'Valid path as it does not starts with /' | 'dmi'       || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  81     }
  82 }