cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/utils/DmiServiceUrlBuilderSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022-2024 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.utils
  22
  23 import org.onap.cps.ncmp.api.impl.config.DmiWebClientConfiguration
  24
  25 import static org.onap.cps.ncmp.api.impl.operations.DatastoreType.PASSTHROUGH_RUNNING
  26
  27 import org.onap.cps.ncmp.api.impl.operations.RequiredDmiService
  28 import org.onap.cps.spi.utils.CpsValidator
  29 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  30 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  31 import spock.lang.Specification
  32
  33 class DmiServiceUrlBuilderSpec extends Specification {
  34
  35     static YangModelCmHandle yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('dmiServiceName',
  36         'dmiDataServiceName', 'dmiModuleServiceName', new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id'),'my-module-set-tag', 'my-alternate-id', 'my-data-producer-identifier')
  37
  38     DmiWebClientConfiguration.DmiProperties dmiProperties = new DmiWebClientConfiguration.DmiProperties()
  39
  40     def mockCpsValidator = Mock(CpsValidator)
  41
  42     def objectUnderTest = new DmiServiceUrlBuilder(dmiProperties, mockCpsValidator)
  43
  44     def setup() {
  45         dmiProperties.dmiBasePath = 'dmi'
  46     }
  47
  48     def 'Create the dmi service url with #scenario.'() {
  49         given: 'uri variables'
  50             def uriVars = objectUnderTest.populateUriVariables(PASSTHROUGH_RUNNING.datastoreName, yangModelCmHandle.resolveDmiServiceName(RequiredDmiService.DATA), 'cmHandle')
  51         and: 'query params'
  52             def uriQueries = objectUnderTest.populateQueryParams(resourceId, 'optionsParamInQuery', topic)
  53         when: 'a dmi datastore service url is generated'
  54             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  55         then: 'service url is generated as expected'
  56             assert dmiServiceUrl == expectedDmiServiceUrl
  57         where: 'the following parameters are used'
  58             scenario                       | topic               | resourceId   || expectedDmiServiceUrl
  59             'With valid resourceId'        | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  60             'With Empty resourceId'        | 'topicParamInQuery' | ''           || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?options=optionsParamInQuery&topic=topicParamInQuery'
  61             'With Empty dmi base path'     | 'topicParamInQuery' | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery&topic=topicParamInQuery'
  62             'With Empty topicParamInQuery' | ''                  | 'resourceId' || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running?resourceIdentifier=resourceId&options=optionsParamInQuery'
  63     }
  64
  65     def 'Populate dmi data store url #scenario.'() {
  66         given: 'uri variables are created'
  67             dmiProperties.dmiBasePath = dmiBasePath
  68             def uriVars = objectUnderTest.populateUriVariables(PASSTHROUGH_RUNNING.datastoreName, yangModelCmHandle.resolveDmiServiceName(RequiredDmiService.DATA), 'cmHandle')
  69         and: 'null query params'
  70             def uriQueries = objectUnderTest.populateQueryParams(null, null, null)
  71         when: 'a dmi datastore service url is generated'
  72             def dmiServiceUrl = objectUnderTest.getDmiDatastoreUrl(uriQueries, uriVars)
  73         then: 'the created dmi service url matches the expected'
  74             assert dmiServiceUrl == expectedDmiServiceUrl
  75         where: 'the following parameters are used'
  76             scenario               | decription                                | dmiBasePath || expectedDmiServiceUrl
  77             'with base path  / '   | 'Invalid base path as it starts with /'   | '/dmi'      || 'dmiServiceName//dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  78             'without base path / ' | 'Valid path as it does not starts with /' | 'dmi'       || 'dmiServiceName/dmi/v1/ch/cmHandle/data/ds/ncmp-datastore:passthrough-running'
  79     }
  80
  81     def 'Bath request Url creation.'() {
  82         given: 'the required path parameters'
  83             def batchRequestUriVariables = [dmiServiceName: 'some-service', dmiBasePath: 'testBase', cmHandleId: '123']
  84         and: 'the relevant query parameters'
  85             def batchRequestQueryParams = objectUnderTest.getDataOperationRequestQueryParams('some topic', 'some id')
  86         when: 'a URL is created'
  87             def result = objectUnderTest.getDataOperationRequestUrl(batchRequestQueryParams, batchRequestUriVariables)
  88         then: 'it is formed correctly'
  89             assert result.toString() == 'some-service/testBase/v1/data?topic=some+topic&requestId=some+id'
  90     }
  91
  92     def 'Populate batch uri variables.'() {
  93         expect: 'Populate batch uri variables returns a map with given service name and base path from setup'
  94             assert objectUnderTest.populateDataOperationRequestUriVariables('some service')  == [dmiServiceName: 'some service', dmiBasePath: 'dmi' ]
  95     }
  96 }