cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/inventory/sync/ModuleSyncServiceSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2022-2023 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.inventory.sync
  22
  23 import org.onap.cps.api.CpsAnchorService
  24
  25 import static org.onap.cps.ncmp.api.impl.ncmppersistence.NcmpPersistence.NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME
  26 import static org.onap.cps.ncmp.api.impl.inventory.LockReasonCategory.MODULE_UPGRADE
  27
  28 import org.onap.cps.ncmp.api.impl.inventory.CmHandleState
  29 import org.onap.cps.spi.FetchDescendantsOption
  30 import org.onap.cps.spi.model.DataNode
  31 import org.onap.cps.api.CpsDataService
  32 import org.onap.cps.api.CpsModuleService
  33 import org.onap.cps.spi.model.DataNodeBuilder
  34 import org.onap.cps.ncmp.api.impl.operations.DmiModelOperations
  35 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  36 import org.onap.cps.ncmp.api.impl.inventory.CmHandleQueries
  37 import org.onap.cps.ncmp.api.impl.inventory.CompositeStateBuilder
  38 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  39 import org.onap.cps.spi.CascadeDeleteAllowed
  40 import org.onap.cps.spi.exceptions.SchemaSetNotFoundException
  41 import org.onap.cps.spi.model.ModuleReference
  42 import org.onap.cps.utils.JsonObjectMapper
  43 import spock.lang.Specification
  44
  45 class ModuleSyncServiceSpec extends Specification {
  46
  47     def mockCpsModuleService = Mock(CpsModuleService)
  48     def mockDmiModelOperations = Mock(DmiModelOperations)
  49     def mockCpsAnchorService = Mock(CpsAnchorService)
  50     def mockCmHandleQueries = Mock(CmHandleQueries)
  51     def mockCpsDataService = Mock(CpsDataService)
  52     def mockJsonObjectMapper = Mock(JsonObjectMapper)
  53
  54     def objectUnderTest = new ModuleSyncService(mockDmiModelOperations, mockCpsModuleService,
  55             mockCmHandleQueries, mockCpsDataService, mockCpsAnchorService, mockJsonObjectMapper)
  56
  57     def expectedDataspaceName = NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME
  58     def static cmHandleWithModuleSetTag = new DataNodeBuilder().withXpath("//cm-handles[@module-set-tag='tag-1'][@id='otherId']").withAnchor('otherId').build()
  59
  60     def 'Sync model for a NEW cm handle without cache with #scenario'() {
  61         given: 'a cm handle having some state'
  62             def ncmpServiceCmHandle = new NcmpServiceCmHandle()
  63             ncmpServiceCmHandle.setCompositeState(new CompositeStateBuilder().withCmHandleState(CmHandleState.ADVISED).build())
  64             ncmpServiceCmHandle.cmHandleId = 'ch-1'
  65             def yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('some service name', '', '', ncmpServiceCmHandle, moduleSetTag, '')
  66         and: 'DMI operations returns some module references'
  67             def moduleReferences =  [ new ModuleReference('module1','1'), new ModuleReference('module2','2') ]
  68             mockDmiModelOperations.getModuleReferences(yangModelCmHandle) >> moduleReferences
  69         and: 'DMI-Plugin returns resource(s) for "new" module(s)'
  70             mockDmiModelOperations.getNewYangResourcesFromDmi(yangModelCmHandle, [new ModuleReference('module1', '1')]) >> newModuleNameContentToMap
  71         and: 'the module service identifies #identifiedNewModuleReferences.size() new modules'
  72             mockCpsModuleService.identifyNewModuleReferences(moduleReferences) >> toModuleReferences(identifiedNewModuleReferences)
  73         and: 'system contains #existingCmHandlesWithSameTag.size() cm handles with same tag'
  74             mockCmHandleQueries.queryNcmpRegistryByCpsPath("//cm-handles[@module-set-tag='new-tag-1']",
  75                     FetchDescendantsOption.OMIT_DESCENDANTS) >> []
  76         when: 'module sync is triggered'
  77             objectUnderTest.syncAndCreateOrUpgradeSchemaSetAndAnchor(yangModelCmHandle)
  78         then: 'create schema set from module is invoked with correct parameters'
  79             1 * mockCpsModuleService.createSchemaSetFromModules(NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME, 'ch-1', newModuleNameContentToMap, moduleReferences)
  80         and: 'anchor is created with the correct parameters'
  81             1 * mockCpsAnchorService.createAnchor(NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME, 'ch-1', 'ch-1')
  82         where: 'the following parameters are used'
  83             scenario         | existingModuleResourcesInCps         | identifiedNewModuleReferences | newModuleNameContentToMap     | moduleSetTag
  84             'one new module' | [['module2': '2'], ['module3': '3']] | [['module1': '1']]            | [module1: 'some yang source'] | ''
  85             'no new module'  | [['module1': '1'], ['module2': '2']] | []                            | [:]                           | 'new-tag-1'
  86     }
  87
  88     def 'Upgrade model for an existing cm handle with Module Set Tag where the modules are #scenario'() {
  89         given: 'a cm handle being upgraded to module set tag: tag-1'
  90             def ncmpServiceCmHandle = new NcmpServiceCmHandle()
  91             ncmpServiceCmHandle.setCompositeState(new CompositeStateBuilder().withLockReason(MODULE_UPGRADE, 'Upgrade to ModuleSetTag: tag-1').build())
  92             def dmiServiceName = 'some service name'
  93             ncmpServiceCmHandle.cmHandleId = 'upgraded-ch'
  94             def yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle(dmiServiceName, '', '', ncmpServiceCmHandle,'tag-1', '')
  95         and: 'some module references'
  96             def moduleReferences =  [ new ModuleReference('module1','1') ]
  97         and: 'cache or DMI operations returns some module references for upgraded cm handle'
  98             mockDmiModelOperations.getModuleReferences(yangModelCmHandle) >> moduleReferences
  99         and: 'none of these module references are new (unknown to the system)'
 100             mockCpsModuleService.identifyNewModuleReferences(moduleReferences) >> []
 101         and: 'CPS-Core returns list of existing module resources for TBD'
 102             mockCpsModuleService.getYangResourcesModuleReferences(*_) >> [ new ModuleReference('module1','1') ]
 103         and: 'system contains #existingCmHandlesWithSameTag.size() cm handles with same tag'
 104             mockCmHandleQueries.queryNcmpRegistryByCpsPath("//cm-handles[@module-set-tag='tag-1']", FetchDescendantsOption.OMIT_DESCENDANTS) >> existingCmHandlesWithSameTag
 105         and: 'the other cm handle is a state ready'
 106             mockCmHandleQueries.cmHandleHasState('otherId', CmHandleState.READY) >> true
 107         when: 'module sync is triggered'
 108             objectUnderTest.syncAndCreateOrUpgradeSchemaSetAndAnchor(yangModelCmHandle)
 109         then: 'update schema set from module is invoked for the upgraded cm handle'
 110             expectedCallsToUpgradeSchemaSet * mockCpsModuleService.upgradeSchemaSetFromModules(NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME, 'upgraded-ch', [:], moduleReferences)
 111         and: 'create schema set from module is invoked for the upgraded cm handle'
 112             expectedCallsToCeateSchemaSet * mockCpsModuleService.createSchemaSetFromModules(NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME, 'upgraded-ch', [:], moduleReferences)
 113         and: 'No anchor is created for the upgraded cm handle'
 114             0 * mockCpsAnchorService.createAnchor(*_)
 115         where: 'the following parameters are used'
 116             scenario      | existingCmHandlesWithSameTag || expectedCallsToUpgradeSchemaSet | expectedCallsToCeateSchemaSet
 117             'new'         | []                           || 1                               | 0
 118             'in database' | [cmHandleWithModuleSetTag]   || 1                               | 0
 119     }
 120
 121     def 'upgrade model for a existing cm handle'() {
 122         given: 'a cm handle that is ready but locked for upgrade'
 123             def ncmpServiceCmHandle = new NcmpServiceCmHandle()
 124             ncmpServiceCmHandle.setCompositeState(new CompositeStateBuilder()
 125                 .withLockReason(MODULE_UPGRADE, 'Upgrade to ModuleSetTag: targetModuleSetTag').build())
 126             ncmpServiceCmHandle.setCmHandleId('cmHandleId-1')
 127             def yangModelCmHandle = YangModelCmHandle.toYangModelCmHandle('some service name', '', '', ncmpServiceCmHandle, 'targetModuleSetTag', '')
 128             mockCmHandleQueries.cmHandleHasState('cmHandleId-1', CmHandleState.READY) >> true
 129         and: 'the module service returns some module references'
 130             def moduleReferences = [new ModuleReference('module1', '1'), new ModuleReference('module2', '2')]
 131             mockCpsModuleService.getYangResourcesModuleReferences(*_)>> moduleReferences
 132         and: 'a cm handle with the same moduleSetTag can be found in the registry'
 133             mockCmHandleQueries.queryNcmpRegistryByCpsPath("//cm-handles[@module-set-tag='targetModuleSetTag']",
 134                 FetchDescendantsOption.OMIT_DESCENDANTS) >> [new DataNode(xpath: '/dmi-registry/cm-handles[@id=\'cmHandleId-1\']', leaves: ['id': 'cmHandleId-1', 'cm-handle-state': 'READY'])]
 135         when: 'module upgrade is triggered'
 136             objectUnderTest.syncAndCreateOrUpgradeSchemaSetAndAnchor(yangModelCmHandle)
 137         then: 'the upgrade is delegated to the module service (with the correct parameters)'
 138             1 * mockCpsModuleService.upgradeSchemaSetFromModules(NFP_OPERATIONAL_DATASTORE_DATASPACE_NAME, 'cmHandleId-1', Collections.emptyMap(), moduleReferences)
 139     }
 140
 141     def 'Delete Schema Set for CmHandle'() {
 142         when: 'delete schema set if exists is called'
 143             objectUnderTest.deleteSchemaSetIfExists('some-cmhandle-id')
 144         then: 'the module service is invoked to delete the correct schema set'
 145             1 * mockCpsModuleService.deleteSchemaSet(expectedDataspaceName, 'some-cmhandle-id', CascadeDeleteAllowed.CASCADE_DELETE_ALLOWED)
 146     }
 147
 148     def 'Delete a non-existing Schema Set for CmHandle' () {
 149         given: 'the DB throws an exception because its Schema Set does not exist'
 150            mockCpsModuleService.deleteSchemaSet(*_) >> { throw new SchemaSetNotFoundException('some-dataspace-name', 'some-cmhandle-id') }
 151         when: 'delete schema set if exists is called'
 152             objectUnderTest.deleteSchemaSetIfExists('some-cmhandle-id')
 153         then: 'the exception from the DB is ignored; there are no exceptions'
 154             noExceptionThrown()
 155     }
 156
 157     def 'Delete Schema Set for CmHandle with other exception' () {
 158         given: 'an exception other than SchemaSetNotFoundException is thrown'
 159             UnsupportedOperationException unsupportedOperationException = new UnsupportedOperationException();
 160             1 * mockCpsModuleService.deleteSchemaSet(*_) >> { throw unsupportedOperationException }
 161         when: 'delete schema set if exists is called'
 162             objectUnderTest.deleteSchemaSetIfExists('some-cmhandle-id')
 163         then: 'an exception is thrown'
 164             def result = thrown(UnsupportedOperationException)
 165             result == unsupportedOperationException
 166     }
 167
 168     def toModuleReferences(moduleReferenceAsMap) {
 169         def moduleReferences = [].withDefault { [:] }
 170         moduleReferenceAsMap.forEach(property ->
 171             property.forEach((moduleName, revision) -> {
 172                 moduleReferences.add(new ModuleReference('moduleName' : moduleName, 'revision' : revision))
 173             }))
 174         return moduleReferences
 175     }
 176
 177 }