cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/events/lcm/LcmEventsCmHandleStateHandlerImplSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  * Copyright (C) 2022-2023 Nordix Foundation
   4  * ================================================================================
   5  * Licensed under the Apache License, Version 2.0 (the "License");
   6  * you may not use this file except in compliance with the License.
   7  * You may obtain a copy of the License at
   8  *
   9  *       http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  * Unless required by applicable law or agreed to in writing, software
  12  * distributed under the License is distributed on an "AS IS" BASIS,
  13  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  * See the License for the specific language governing permissions and
  15  * limitations under the License.
  16  *
  17  * SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.events.lcm
  22
  23 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  24 import org.onap.cps.ncmp.api.inventory.CompositeState
  25 import org.onap.cps.ncmp.api.inventory.DataStoreSyncState
  26 import org.onap.cps.ncmp.api.inventory.InventoryPersistence
  27 import spock.lang.Specification
  28
  29 import static org.onap.cps.ncmp.api.inventory.CmHandleState.ADVISED
  30 import static org.onap.cps.ncmp.api.inventory.CmHandleState.DELETED
  31 import static org.onap.cps.ncmp.api.inventory.CmHandleState.DELETING
  32 import static org.onap.cps.ncmp.api.inventory.CmHandleState.LOCKED
  33 import static org.onap.cps.ncmp.api.inventory.CmHandleState.READY
  34 import static org.onap.cps.ncmp.api.inventory.LockReasonCategory.LOCKED_MODULE_SYNC_FAILED
  35
  36 class LcmEventsCmHandleStateHandlerImplSpec extends Specification {
  37
  38     def mockInventoryPersistence = Mock(InventoryPersistence)
  39     def mockLcmEventsCreator = Mock(LcmEventsCreator)
  40     def mockLcmEventsService = Mock(LcmEventsService)
  41
  42     def lcmEventsCmHandleStateHandlerAsyncHelper = new LcmEventsCmHandleStateHandlerAsyncHelper(mockLcmEventsCreator, mockLcmEventsService)
  43     def objectUnderTest = new LcmEventsCmHandleStateHandlerImpl(mockInventoryPersistence, lcmEventsCmHandleStateHandlerAsyncHelper)
  44
  45     def cmHandleId = 'cmhandle-id-1'
  46     def compositeState
  47     def yangModelCmHandle
  48
  49     def 'Update and Publish Events on State Change #stateChange'() {
  50         given: 'Cm Handle represented as YangModelCmHandle'
  51             compositeState = new CompositeState(cmHandleState: fromCmHandleState)
  52             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [], compositeState: compositeState)
  53         when: 'update state is invoked'
  54             objectUnderTest.updateCmHandleState(yangModelCmHandle, toCmHandleState)
  55         then: 'state is saved using inventory persistence'
  56             expectedCallsToInventoryPersistence * mockInventoryPersistence.saveCmHandleState(cmHandleId, _)
  57         and: 'event service is called to publish event'
  58             expectedCallsToEventService * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
  59         where: 'state change parameters are provided'
  60             stateChange          | fromCmHandleState | toCmHandleState || expectedCallsToInventoryPersistence | expectedCallsToEventService
  61             'ADVISED to READY'   | ADVISED           | READY           || 1                                   | 1
  62             'READY to LOCKED'    | READY             | LOCKED          || 1                                   | 1
  63             'ADVISED to ADVISED' | ADVISED           | ADVISED         || 0                                   | 0
  64             'READY to READY'     | READY             | READY           || 0                                   | 0
  65             'LOCKED to LOCKED'   | LOCKED            | LOCKED          || 0                                   | 0
  66
  67     }
  68
  69     def 'Update and Publish Events on State Change from NO_EXISTING state to ADVISED'() {
  70         given: 'Cm Handle represented as YangModelCmHandle'
  71             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [])
  72         when: 'update state is invoked'
  73             objectUnderTest.updateCmHandleState(yangModelCmHandle, ADVISED)
  74         then: 'state is saved using inventory persistence'
  75             1 * mockInventoryPersistence.saveCmHandle(yangModelCmHandle)
  76         and: 'event service is called to publish event'
  77             1 * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
  78     }
  79
  80     def 'Update and Publish Events on State Change from LOCKED to ADVISED'() {
  81         given: 'Cm Handle represented as YangModelCmHandle in LOCKED state'
  82             compositeState = new CompositeState(cmHandleState: LOCKED,
  83                 lockReason: CompositeState.LockReason.builder().lockReasonCategory(LOCKED_MODULE_SYNC_FAILED).details('some lock details').build())
  84             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [], compositeState: compositeState)
  85         when: 'update state is invoked'
  86             objectUnderTest.updateCmHandleState(yangModelCmHandle, ADVISED)
  87         then: 'state is saved using inventory persistence and old lock reason details are retained'
  88             1 * mockInventoryPersistence.saveCmHandleState(cmHandleId, _) >> {
  89                 args -> {
  90                     assert (args[1] as CompositeState).lockReason.details == 'some lock details'
  91                 }
  92             }
  93         and: 'event service is called to publish event'
  94             1 * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
  95     }
  96
  97     def 'Update and Publish Events on State Change to READY'() {
  98         given: 'Cm Handle represented as YangModelCmHandle'
  99             compositeState = new CompositeState(cmHandleState: ADVISED)
 100             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [], compositeState: compositeState)
 101         and: 'global sync flag is set'
 102             compositeState.setDataSyncEnabled(false)
 103         when: 'update cmhandle state is invoked'
 104             objectUnderTest.updateCmHandleState(yangModelCmHandle, READY)
 105         then: 'state is saved using inventory persistence with expected dataSyncState'
 106             1 * mockInventoryPersistence.saveCmHandleState(cmHandleId, _) >> {
 107                 args-> {
 108                     def result = (args[1] as CompositeState)
 109                     assert result.dataSyncEnabled == false
 110                     assert result.dataStores.operationalDataStore.dataStoreSyncState == DataStoreSyncState.NONE_REQUESTED
 111
 112                 }
 113             }
 114         and: 'event service is called to publish event'
 115             1 * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
 116     }
 117
 118     def 'Update cmHandle state to "DELETING"' (){
 119         given: 'cm Handle as Yang model'
 120             compositeState = new CompositeState(cmHandleState: READY)
 121             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [], compositeState: compositeState)
 122         when: 'updating cm handle state to "DELETING"'
 123             objectUnderTest.updateCmHandleState(yangModelCmHandle, DELETING)
 124         then: 'the cm handle state is as expected'
 125             yangModelCmHandle.getCompositeState().getCmHandleState() == DELETING
 126         and: 'method to persist cm handle state is called once'
 127             1 * mockInventoryPersistence.saveCmHandleState(yangModelCmHandle.getId(), yangModelCmHandle.getCompositeState())
 128         and: 'the method to publish Lcm event is called once'
 129             1 * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
 130     }
 131
 132     def 'Update cmHandle state to "DELETED"' (){
 133         given: 'cm Handle with state "DELETING" as Yang model '
 134             compositeState = new CompositeState(cmHandleState: DELETING)
 135             yangModelCmHandle = new YangModelCmHandle(id: cmHandleId, dmiProperties: [], publicProperties: [], compositeState: compositeState)
 136         when: 'updating cm handle state to "DELETED"'
 137             objectUnderTest.updateCmHandleState(yangModelCmHandle, DELETED)
 138         then: 'the cm handle state is as expected'
 139             yangModelCmHandle.getCompositeState().getCmHandleState() == DELETED
 140         and: 'the method to publish Lcm event is called once'
 141             1 * mockLcmEventsService.publishLcmEvent(cmHandleId, _, _)
 142     }
 143
 144     def 'No state change and no event to be published'() {
 145         given: 'Cm Handle batch with same state transition as before'
 146             def cmHandleStateMap = setupBatch('NO_CHANGE')
 147         when: 'updating a batch of changes'
 148             objectUnderTest.updateCmHandleStateBatch(cmHandleStateMap)
 149         then: 'batch is empty and nothing to update'
 150             1 * mockInventoryPersistence.saveCmHandleBatch(_) >> {
 151                 args -> {
 152                     assert (args[0] as Collection<YangModelCmHandle>).size() == 0
 153                 }
 154             }
 155         and: 'no event will be published'
 156             0 * mockLcmEventsService.publishLcmEvent(*_)
 157     }
 158
 159     def 'Batch of new cm handles provided'() {
 160         given: 'A batch of new cm handles'
 161             def cmHandleStateMap = setupBatch('NEW')
 162         when: 'updating a batch of changes'
 163             objectUnderTest.updateCmHandleStateBatch(cmHandleStateMap)
 164         then: 'new cm handles are saved using inventory persistence'
 165             1 * mockInventoryPersistence.saveCmHandleBatch(_) >> {
 166                 args -> {
 167                     assert (args[0] as Collection<YangModelCmHandle>).id.containsAll('cmhandle1', 'cmhandle2')
 168                 }
 169             }
 170         and: 'event service is called to publish event'
 171             2 * mockLcmEventsService.publishLcmEvent(_, _, _)
 172
 173     }
 174
 175     def 'Batch of existing cm handles is updated'() {
 176         given: 'A batch of updated cm handles'
 177             def cmHandleStateMap = setupBatch('UPDATE')
 178         when: 'updating a batch of changes'
 179             objectUnderTest.updateCmHandleStateBatch(cmHandleStateMap)
 180         then : 'existing cm handles composite state is persisted'
 181             1 * mockInventoryPersistence.saveCmHandleStateBatch(_) >> {
 182                 args -> {
 183                     assert (args[0] as Map<String, CompositeState>).keySet().containsAll(['cmhandle1','cmhandle2'])
 184                 }
 185             }
 186         and: 'event service is called to publish event'
 187             2 * mockLcmEventsService.publishLcmEvent(_, _, _)
 188
 189     }
 190
 191     def setupBatch(type) {
 192
 193         def yangModelCmHandle1 = new YangModelCmHandle(id: 'cmhandle1', dmiProperties: [], publicProperties: [])
 194         def yangModelCmHandle2 = new YangModelCmHandle(id: 'cmhandle2', dmiProperties: [], publicProperties: [])
 195
 196         if ('NEW' == type) {
 197             return [(yangModelCmHandle1): ADVISED, (yangModelCmHandle2): ADVISED]
 198         }
 199
 200         if ('UPDATE' == type) {
 201             yangModelCmHandle1.compositeState = new CompositeState(cmHandleState: ADVISED)
 202             yangModelCmHandle2.compositeState = new CompositeState(cmHandleState: READY)
 203             return [(yangModelCmHandle1): READY, (yangModelCmHandle2): DELETING]
 204         }
 205
 206         if ('NO_CHANGE' == type) {
 207             yangModelCmHandle1.compositeState = new CompositeState(cmHandleState: ADVISED)
 208             yangModelCmHandle2.compositeState = new CompositeState(cmHandleState: READY)
 209             return [(yangModelCmHandle1): ADVISED, (yangModelCmHandle2): READY]
 210         }
 211     }
 212 }