cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/event/NcmpEventsPublisherSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  * Copyright (C) 2022 Nordix Foundation
   4  * ================================================================================
   5  * Licensed under the Apache License, Version 2.0 (the "License");
   6  * you may not use this file except in compliance with the License.
   7  * You may obtain a copy of the License at
   8  *
   9  *       http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  * Unless required by applicable law or agreed to in writing, software
  12  * distributed under the License is distributed on an "AS IS" BASIS,
  13  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  * See the License for the specific language governing permissions and
  15  * limitations under the License.
  16  *
  17  * SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.event
  22
  23 import com.fasterxml.jackson.databind.ObjectMapper
  24 import org.apache.kafka.clients.consumer.KafkaConsumer
  25 import org.onap.cps.ncmp.api.utils.MessagingSpec
  26 import org.onap.cps.ncmp.utils.TestUtils
  27 import org.onap.cps.utils.JsonObjectMapper
  28 import org.onap.ncmp.cmhandle.lcm.event.Event
  29 import org.onap.ncmp.cmhandle.lcm.event.NcmpEvent
  30 import org.spockframework.spring.SpringBean
  31 import org.springframework.beans.factory.annotation.Autowired
  32 import org.springframework.boot.test.context.SpringBootTest
  33 import org.springframework.test.annotation.DirtiesContext
  34 import org.testcontainers.spock.Testcontainers
  35
  36 import java.time.Duration
  37
  38 @SpringBootTest(classes = [NcmpEventsPublisher, ObjectMapper, JsonObjectMapper])
  39 @Testcontainers
  40 @DirtiesContext
  41 class NcmpEventsPublisherSpec extends MessagingSpec {
  42
  43     def kafkaConsumer = new KafkaConsumer<>(consumerConfigProperties('ncmp-group'))
  44
  45     def testTopic = 'ncmp-events-test'
  46
  47     @SpringBean
  48     NcmpEventsPublisher ncmpEventsPublisher = new NcmpEventsPublisher(kafkaTemplate)
  49
  50     @Autowired
  51     JsonObjectMapper jsonObjectMapper
  52
  53
  54     def 'Produce and Consume Ncmp Event'() {
  55         given: 'event key and event data'
  56             def eventKey = 'ncmp'
  57             def eventData = new NcmpEvent(eventId: 'test-uuid',
  58                 eventCorrelationId: 'cmhandle-as-correlationid',
  59                 eventSchema: URI.create('org.onap.ncmp.cmhandle.lcm.event:v1'),
  60                 eventSource: URI.create('org.onap.ncmp'),
  61                 eventTime: '2022-12-31T20:30:40.000+0000',
  62                 eventType: 'org.onap.ncmp.cmhandle.lcm.event',
  63                 event: new Event(cmHandleId: 'cmhandle-test', cmhandleState: 'READY', cmhandleProperties: [['publicProperty1': 'value1'], ['publicProperty2': 'value2']]))
  64         and: 'we have an expected NcmpEvent'
  65             def expectedJsonString = TestUtils.getResourceFileContent('expectedNcmpEvent.json')
  66             def expectedNcmpEvent = jsonObjectMapper.convertJsonString(expectedJsonString, NcmpEvent.class)
  67         and: 'consumer has a subscription'
  68             kafkaConsumer.subscribe([testTopic] as List<String>)
  69         when: 'an event is published'
  70             ncmpEventsPublisher.publishEvent(testTopic, eventKey, eventData)
  71         and: 'topic is polled'
  72             def records = kafkaConsumer.poll(Duration.ofMillis(1500))
  73         then: 'no exception is thrown'
  74             noExceptionThrown()
  75         and: 'poll returns one record'
  76             assert records.size() == 1
  77         and: 'record key matches the expected event key'
  78             def record = records.iterator().next()
  79             assert eventKey == record.key
  80         and: 'record matches the expected event'
  81             assert expectedNcmpEvent == jsonObjectMapper.convertJsonString(record.value, NcmpEvent.class)
  82
  83     }
  84 }