cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/config/embeddedcache/ForwardedSubscriptionEventCacheConfigSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2023 Nordix Foundation
   4  *  ================================================================================
   5  *  Licensed under the Apache License, Version 2.0 (the "License");
   6  *  you may not use this file except in compliance with the License.
   7  *  You may obtain a copy of the License at
   8  *
   9  *        http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  *  Unless required by applicable law or agreed to in writing, software
  12  *  distributed under the License is distributed on an "AS IS" BASIS,
  13  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  *  See the License for the specific language governing permissions and
  15  *  limitations under the License.
  16  *
  17  *  SPDX-License-Identifier: Apache-2.0
  18  *  ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.api.impl.config.embeddedcache
  22
  23 import com.hazelcast.config.Config
  24 import com.hazelcast.core.Hazelcast
  25 import com.hazelcast.map.IMap
  26 import org.springframework.beans.factory.annotation.Autowired
  27 import org.springframework.boot.test.context.SpringBootTest
  28 import spock.lang.Specification
  29
  30 @SpringBootTest(classes = [ForwardedSubscriptionEventCacheConfig])
  31 class ForwardedSubscriptionEventCacheConfigSpec extends Specification {
  32
  33     @Autowired
  34     private IMap<String, Set<String>> forwardedSubscriptionEventCache
  35
  36     def 'Embedded (hazelcast) cache for Forwarded Subscription Event Cache.'() {
  37         expect: 'system is able to create an instance of the Forwarded Subscription Event Cache'
  38             assert null != forwardedSubscriptionEventCache
  39         and: 'there is at least 1 instance'
  40             assert Hazelcast.allHazelcastInstances.size() > 0
  41         and: 'Forwarded Subscription Event Cache is present'
  42             assert Hazelcast.allHazelcastInstances.name.contains('hazelCastInstanceSubscriptionEvents')
  43     }
  44
  45     def 'Verify configs for Distributed Caches'(){
  46         given: 'the Forwarded Subscription Event Cache config'
  47             def forwardedSubscriptionEventCacheConfig =  Hazelcast.getHazelcastInstanceByName('hazelCastInstanceSubscriptionEvents').config
  48             def forwardedSubscriptionEventCacheMapConfig =  forwardedSubscriptionEventCacheConfig.mapConfigs.get('forwardedSubscriptionEventCacheMapConfig')
  49         expect: 'system created instance with correct config'
  50             assert forwardedSubscriptionEventCacheConfig.clusterName == 'cps-and-ncmp-test-caches'
  51             assert forwardedSubscriptionEventCacheMapConfig.backupCount == 3
  52             assert forwardedSubscriptionEventCacheMapConfig.asyncBackupCount == 3
  53     }
  54
  55     def 'Verify deployment network configs for Distributed Caches'() {
  56         given: 'the Forwarded Subscription Event Cache config'
  57             def forwardedSubscriptionEventCacheNetworkConfig = Hazelcast.getHazelcastInstanceByName('hazelCastInstanceSubscriptionEvents').config.networkConfig
  58         expect: 'system created instance with correct config'
  59             assert forwardedSubscriptionEventCacheNetworkConfig.join.autoDetectionConfig.enabled
  60             assert !forwardedSubscriptionEventCacheNetworkConfig.join.kubernetesConfig.enabled
  61     }
  62
  63     def 'Verify network config'() {
  64         given: 'Synchronization config object and test configuration'
  65             def objectUnderTest = new ForwardedSubscriptionEventCacheConfig()
  66             def testConfig = new Config()
  67         when: 'kubernetes properties are enabled'
  68             objectUnderTest.cacheKubernetesEnabled = true
  69             objectUnderTest.cacheKubernetesServiceName = 'test-service-name'
  70         and: 'method called to update the discovery mode'
  71             objectUnderTest.updateDiscoveryMode(testConfig)
  72         then: 'applied properties are reflected'
  73             assert testConfig.networkConfig.join.kubernetesConfig.enabled
  74             assert testConfig.networkConfig.join.kubernetesConfig.properties.get('service-name') == 'test-service-name'
  75
  76     }
  77 }