cps-ncmp-service/src/test/groovy/org/onap/cps/ncmp/api/impl/NetworkCmProxyDataServiceImplRegistrationSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021-2022 Nordix Foundation
   4  *  Modifications Copyright (C) 2022 Bell Canada
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.api.impl
  23
  24 import com.fasterxml.jackson.databind.ObjectMapper
  25 import org.onap.cps.api.CpsDataService
  26 import org.onap.cps.api.CpsModuleService
  27 import org.onap.cps.ncmp.api.NetworkCmProxyCmHandlerQueryService
  28 import org.onap.cps.ncmp.api.impl.event.lcm.LcmEventsCmHandleStateHandler
  29 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  30 import org.onap.cps.ncmp.api.impl.operations.DmiDataOperations
  31 import org.onap.cps.ncmp.api.impl.yangmodels.YangModelCmHandle
  32 import org.onap.cps.ncmp.api.inventory.CmHandleQueries
  33 import org.onap.cps.ncmp.api.inventory.CmHandleState
  34 import org.onap.cps.ncmp.api.inventory.InventoryPersistence
  35 import org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse
  36 import org.onap.cps.ncmp.api.models.DmiPluginRegistration
  37 import org.onap.cps.ncmp.api.models.NcmpServiceCmHandle
  38 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  39 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  40 import org.onap.cps.spi.exceptions.DataValidationException
  41 import org.onap.cps.spi.exceptions.SchemaSetNotFoundException
  42 import org.onap.cps.utils.JsonObjectMapper
  43 import spock.lang.Shared
  44 import spock.lang.Specification
  45
  46 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_DOES_NOT_EXIST
  47 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_ALREADY_EXIST
  48 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.CM_HANDLE_INVALID_ID
  49 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.RegistrationError.UNKNOWN_ERROR
  50 import static org.onap.cps.ncmp.api.models.CmHandleRegistrationResponse.Status
  51 import static org.onap.cps.spi.CascadeDeleteAllowed.CASCADE_DELETE_ALLOWED
  52
  53 class NetworkCmProxyDataServiceImplRegistrationSpec extends Specification {
  54
  55     @Shared
  56     def ncmpServiceCmHandle = new NcmpServiceCmHandle(cmHandleId: 'some-cm-handle-id')
  57
  58     def mockCpsModuleService = Mock(CpsModuleService)
  59     def spiedJsonObjectMapper = Spy(new JsonObjectMapper(new ObjectMapper()))
  60     def mockDmiDataOperations = Mock(DmiDataOperations)
  61     def mockNetworkCmProxyDataServicePropertyHandler = Mock(NetworkCmProxyDataServicePropertyHandler)
  62     def mockInventoryPersistence = Mock(InventoryPersistence)
  63     def mockCmhandleQueries = Mock(CmHandleQueries)
  64     def stubbedNetworkCmProxyCmHandlerQueryService = Stub(NetworkCmProxyCmHandlerQueryService)
  65     def mockLcmEventsCmHandleStateHandler = Mock(LcmEventsCmHandleStateHandler)
  66     def mockCpsDataService = Mock(CpsDataService)
  67     def objectUnderTest = getObjectUnderTest()
  68
  69     def 'DMI Registration: Create, Update & Delete operations are processed in the right order'() {
  70         given: 'a registration with operations of all three types'
  71             def dmiRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
  72             dmiRegistration.setCreatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-1', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  73             dmiRegistration.setUpdatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-2', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  74             dmiRegistration.setRemovedCmHandles(['cmhandle-2'])
  75         when: 'registration is processed'
  76             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiRegistration)
  77             // Spock validated invocation order between multiple then blocks
  78         then: 'cm-handles are removed first'
  79             1 * objectUnderTest.parseAndRemoveCmHandlesInDmiRegistration(*_)
  80         then: 'cm-handles are created'
  81             1 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(*_)
  82         then: 'cm-handles are updated'
  83             1 * mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(*_)
  84     }
  85
  86     def 'DMI Registration: Response from all operations types are in response'() {
  87         given: 'a registration with operations of all three types'
  88             def dmiRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
  89             dmiRegistration.setCreatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-1', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  90             dmiRegistration.setUpdatedCmHandles([new NcmpServiceCmHandle(cmHandleId: 'cmhandle-2', publicProperties: ['publicProp1': 'value'], dmiProperties: [:])])
  91             dmiRegistration.setRemovedCmHandles(['cmhandle-2'])
  92         and: 'update cm-handles can be processed successfully'
  93             def updateResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-2')]
  94             mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(*_) >> updateResponses
  95         and: 'create cm-handles can be processed successfully'
  96             def createdResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-1')]
  97             objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(*_) >> createdResponses
  98         and: 'delete cm-handles can be processed successfully'
  99             def removeResponses = [CmHandleRegistrationResponse.createSuccessResponse('cmhandle-3')]
 100             objectUnderTest.parseAndRemoveCmHandlesInDmiRegistration(*_) >> removeResponses
 101         when: 'registration is processed'
 102             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiRegistration)
 103         then: 'response has values from all operations'
 104             response.getRemovedCmHandles() == removeResponses
 105             response.getCreatedCmHandles() == createdResponses
 106             response.getUpdatedCmHandles() == updateResponses
 107     }
 108
 109     def 'Create CM-handle Validation: Registration with valid Service names: #scenario'() {
 110         given: 'a registration '
 111             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: dmiPlugin, dmiModelPlugin: dmiModelPlugin,
 112                 dmiDataPlugin: dmiDataPlugin)
 113             dmiPluginRegistration.createdCmHandles = [ncmpServiceCmHandle]
 114         when: 'update registration and sync module is called with correct DMI plugin information'
 115             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 116         then: 'create cm handles registration and sync modules is called with the correct plugin information'
 117             1 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(dmiPluginRegistration)
 118         where:
 119             scenario                          | dmiPlugin  | dmiModelPlugin | dmiDataPlugin
 120             'combined DMI plugin'             | 'service1' | ''             | ''
 121             'data & model DMI plugins'        | ''         | 'service1'     | 'service2'
 122             'data & model using same service' | ''         | 'service1'     | 'service1'
 123     }
 124
 125     def 'Create CM-handle Validation: Invalid DMI plugin service name with #scenario'() {
 126         given: 'a registration '
 127             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: dmiPlugin, dmiModelPlugin: dmiModelPlugin,
 128                 dmiDataPlugin: dmiDataPlugin)
 129             dmiPluginRegistration.createdCmHandles = [ncmpServiceCmHandle]
 130         when: 'registration is called with incorrect DMI plugin information'
 131             objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 132         then: 'a DMI Request Exception is thrown with correct message details'
 133             def exceptionThrown = thrown(DmiRequestException.class)
 134             assert exceptionThrown.getMessage().contains(expectedMessageDetails)
 135         and: 'registration is not called'
 136             0 * objectUnderTest.parseAndCreateCmHandlesInDmiRegistrationAndSyncModules(dmiPluginRegistration)
 137         where:
 138             scenario                         | dmiPlugin  | dmiModelPlugin | dmiDataPlugin || expectedMessageDetails
 139             'empty DMI plugins'              | ''         | ''             | ''            || 'No DMI plugin service names'
 140             'blank DMI plugins'              | ' '        | ' '            | ' '           || 'No DMI plugin service names'
 141             'null DMI plugins'               | null       | null           | null          || 'No DMI plugin service names'
 142             'all DMI plugins'                | 'service1' | 'service2'     | 'service3'    || 'Cannot register combined plugin service name and other service names'
 143             '(combined)DMI and Data Plugin'  | 'service1' | ''             | 'service2'    || 'Cannot register combined plugin service name and other service names'
 144             '(combined)DMI and model Plugin' | 'service1' | 'service2'     | ''            || 'Cannot register combined plugin service name and other service names'
 145             'only model DMI plugin'          | ''         | 'service1'     | ''            || 'Cannot register just a Data or Model plugin service name'
 146             'only data DMI plugin'           | ''         | ''             | 'service1'    || 'Cannot register just a Data or Model plugin service name'
 147     }
 148
 149     def 'Create CM-Handle Successfully: #scenario.'() {
 150         given: 'a registration without cm-handle properties'
 151             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
 152             dmiPluginRegistration.createdCmHandles = [new NcmpServiceCmHandle(cmHandleId: 'cmhandle', dmiProperties: dmiProperties, publicProperties: publicProperties)]
 153         when: 'registration is updated'
 154             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 155         then: 'a successful response is received'
 156             response.getCreatedCmHandles().size() == 1
 157             with(response.getCreatedCmHandles().get(0)) {
 158                 assert it.status == Status.SUCCESS
 159                 assert it.cmHandle == 'cmhandle'
 160             }
 161         and: 'state handler is invoked with the expected parameters'
 162             1 * mockLcmEventsCmHandleStateHandler.updateCmHandleStateBatch(_) >> {
 163                 args ->
 164                     {
 165                         def cmHandleStatePerCmHandle = (args[0] as Map)
 166                         cmHandleStatePerCmHandle.each {
 167                             assert (it.key.id == 'cmhandle'
 168                                     && it.key.dmiServiceName == 'my-server'
 169                                     && it.value == CmHandleState.ADVISED)
 170                         }
 171                     }
 172             }
 173         where:
 174             scenario                          | dmiProperties            | publicProperties               || expectedDmiProperties                      | expectedPublicProperties
 175             'with dmi & public properties'    | ['dmi-key': 'dmi-value'] | ['public-key': 'public-value'] || '[{"name":"dmi-key","value":"dmi-value"}]' | '[{"name":"public-key","value":"public-value"}]'
 176             'with only public properties'     | [:]                      | ['public-key': 'public-value'] || '[]'                                       | '[{"name":"public-key","value":"public-value"}]'
 177             'with only dmi properties'        | ['dmi-key': 'dmi-value'] | [:]                            || '[{"name":"dmi-key","value":"dmi-value"}]' | '[]'
 178             'without dmi & public properties' | [:]                      | [:]                            || '[]'                                       | '[]'
 179     }
 180
 181     def 'Create CM-Handle Multiple Requests: All cm-handles creation requests are processed with some failures'() {
 182         given: 'a registration with three cm-handles to be created'
 183             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 184                     createdCmHandles: [new NcmpServiceCmHandle(cmHandleId: 'cmhandle1'),
 185                                        new NcmpServiceCmHandle(cmHandleId: 'cmhandle2'),
 186                                        new NcmpServiceCmHandle(cmHandleId: 'cmhandle3')])
 187         and: 'cm-handle creation is successful for 1st and 3rd; failed for 2nd'
 188             mockLcmEventsCmHandleStateHandler.updateCmHandleStateBatch(*_) >> { throw new RuntimeException("Failed") }
 189         when: 'registration is updated to create cm-handles'
 190             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 191         then: 'a response is received for all cm-handles'
 192             response.getCreatedCmHandles().size() == 1
 193         and: 'all cm-handles creation fails'
 194             with(response.getCreatedCmHandles().get(0)) {
 195                 assert it.status == Status.FAILURE
 196                 assert it.registrationError == UNKNOWN_ERROR
 197                 assert it.errorText == 'Failed'
 198                 def sortedCmHandles = it.cmHandle.split(',').sort()
 199                 assert sortedCmHandles[0] == 'cmhandle1'
 200                 assert sortedCmHandles[1] == 'cmhandle2'
 201                 assert sortedCmHandles[2] == 'cmhandle3'
 202             }
 203     }
 204
 205     def 'Create CM-Handle Error Handling: Registration fails: #scenario'() {
 206         given: 'a registration without cm-handle properties'
 207             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server')
 208             dmiPluginRegistration.createdCmHandles = [new NcmpServiceCmHandle(cmHandleId: cmHandleId)]
 209         and: 'cm-handler registration fails: #scenario'
 210             mockLcmEventsCmHandleStateHandler.updateCmHandleStateBatch(*_) >> { throw exception }
 211         when: 'registration is updated'
 212             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 213         then: 'a failure response is received'
 214             response.getCreatedCmHandles().size() == 1
 215             with(response.getCreatedCmHandles().get(0)) {
 216                 assert it.status == Status.FAILURE
 217                 assert it.cmHandle ==  cmHandleId
 218                 assert it.registrationError == expectedError
 219                 assert it.errorText == expectedErrorText
 220             }
 221         where:
 222             scenario                                        | cmHandleId             | exception                                               || expectedError           | expectedErrorText
 223             'cm-handle already exist'                       | 'cmhandle'             | new AlreadyDefinedException('', new RuntimeException()) || CM_HANDLE_ALREADY_EXIST | 'cm-handle already exists'
 224             'cm-handle has invalid name'                    | 'cm handle with space' | new DataValidationException("", "")                     || CM_HANDLE_INVALID_ID    | 'cm-handle has an invalid character(s) in id'
 225             'unknown exception while registering cm-handle' | 'cmhandle'             | new RuntimeException('Failed')                          || UNKNOWN_ERROR           | 'Failed'
 226     }
 227
 228     def 'Update CM-Handle: Update Operation Response is added to the response'() {
 229         given: 'a registration to update CmHandles'
 230             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 231                 updatedCmHandles: [{}])
 232         and: 'cm-handle updates can be processed successfully'
 233             def updateOperationResponse = [CmHandleRegistrationResponse.createSuccessResponse('cm-handle-1'),
 234                                            CmHandleRegistrationResponse.createFailureResponse('cm-handle-2', new Exception("Failed")),
 235                                            CmHandleRegistrationResponse.createFailureResponse('cm-handle-3', CM_HANDLE_DOES_NOT_EXIST),
 236                                            CmHandleRegistrationResponse.createFailureResponse('cm handle 4', CM_HANDLE_INVALID_ID)]
 237             mockNetworkCmProxyDataServicePropertyHandler.updateCmHandleProperties(_) >> updateOperationResponse
 238         when: 'registration is updated'
 239             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 240         then: 'the response contains updateOperationResponse'
 241             assert response.getUpdatedCmHandles().size() == 4
 242             assert response.getUpdatedCmHandles().containsAll(updateOperationResponse)
 243     }
 244
 245     def 'Remove CmHandle Successfully: #scenario'() {
 246         given: 'a registration'
 247             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 248                 removedCmHandles: ['cmhandle'])
 249         and: '#scenario'
 250             mockCpsModuleService.deleteSchemaSet(_, 'cmhandle', CASCADE_DELETE_ALLOWED) >>
 251                 { if (!schemaSetExist) { throw new SchemaSetNotFoundException("", "") } }
 252         when: 'registration is updated to delete cmhandle'
 253             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 254         then: 'the cmHandle state is updated to "DELETING"'
 255             1 * mockLcmEventsCmHandleStateHandler.updateCmHandleState(_, CmHandleState.DELETING)
 256         and: 'method to delete relevant schema set is called once'
 257             1 * mockInventoryPersistence.deleteSchemaSetWithCascade(_)
 258         and: 'method to delete relevant list/list element is called once'
 259             1 * mockInventoryPersistence.deleteListOrListElement(_)
 260         and: 'successful response is received'
 261             assert response.getRemovedCmHandles().size() == 1
 262             with(response.getRemovedCmHandles().get(0)) {
 263                 assert it.status == Status.SUCCESS
 264                 assert it.cmHandle == 'cmhandle'
 265             }
 266         and: 'the cmHandle state is updated to "DELETED"'
 267             1 * mockLcmEventsCmHandleStateHandler.updateCmHandleState(_, CmHandleState.DELETED)
 268         where:
 269             scenario                                            | schemaSetExist
 270             'schema-set exists and can be deleted successfully' | true
 271             'schema-set does not exist'                         | false
 272     }
 273
 274     def 'Remove CmHandle: All cm-handles delete requests are processed'() {
 275         given: 'a registration with three cm-handles to be deleted'
 276             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 277                 removedCmHandles: ['cmhandle1', 'cmhandle2', 'cmhandle3'])
 278         and: 'cm-handle deletion is successful for 1st and 3rd; failed for 2nd'
 279             mockInventoryPersistence.deleteListOrListElement(_) >> {} >> { throw new RuntimeException("Failed") } >> {}
 280         when: 'registration is updated to delete cmhandles'
 281             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 282         then: 'a response is received for all cm-handles'
 283             response.getRemovedCmHandles().size() == 3
 284         and: '1st and 3rd cm-handle deletes successfully'
 285             with(response.getRemovedCmHandles().get(0)) {
 286                 assert it.status == Status.SUCCESS
 287                 assert it.cmHandle == 'cmhandle1'
 288             }
 289             with(response.getRemovedCmHandles().get(2)) {
 290                 assert it.status == Status.SUCCESS
 291                 assert it.cmHandle == 'cmhandle3'
 292             }
 293         and: '2nd cm-handle deletion fails'
 294             with(response.getRemovedCmHandles().get(1)) {
 295                 assert it.status == Status.FAILURE
 296                 assert it.registrationError == UNKNOWN_ERROR
 297                 assert it.errorText == 'Failed'
 298                 assert it.cmHandle == 'cmhandle2'
 299             }
 300     }
 301
 302     def 'Remove CmHandle Error Handling: Schema Set Deletion failed'() {
 303         given: 'a registration'
 304             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 305                 removedCmHandles: ['cmhandle'])
 306         and: 'schema set deletion failed with unknown error'
 307             mockInventoryPersistence.deleteSchemaSetWithCascade(_) >> { throw new RuntimeException('Failed') }
 308         when: 'registration is updated to delete cmhandle'
 309             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 310         then: 'no exception is thrown'
 311             noExceptionThrown()
 312         and: 'cm-handle is not deleted'
 313             0 * mockInventoryPersistence.deleteListOrListElement(_)
 314         and: 'the cmHandle state is not updated to "DELETED"'
 315             0 * mockLcmEventsCmHandleStateHandler.updateCmHandleState(_, CmHandleState.DELETED)
 316         and: 'a failure response is received'
 317             assert response.getRemovedCmHandles().size() == 1
 318             with(response.getRemovedCmHandles().get(0)) {
 319                 assert it.status == Status.FAILURE
 320                 assert it.cmHandle == 'cmhandle'
 321                 assert it.errorText == 'Failed'
 322                 assert it.registrationError == UNKNOWN_ERROR
 323             }
 324     }
 325
 326     def 'Remove CmHandle Error Handling: #scenario'() {
 327         given: 'a registration'
 328             def dmiPluginRegistration = new DmiPluginRegistration(dmiPlugin: 'my-server',
 329                 removedCmHandles: ['cmhandle'])
 330         and: 'cm-handle deletion throws exception'
 331             mockInventoryPersistence.deleteListOrListElement(_) >> { throw deleteListElementException }
 332         when: 'registration is updated to delete cmhandle'
 333             def response = objectUnderTest.updateDmiRegistrationAndSyncModule(dmiPluginRegistration)
 334         then: 'a failure response is received'
 335             assert response.getRemovedCmHandles().size() == 1
 336             with(response.getRemovedCmHandles().get(0)) {
 337                 assert it.status == Status.FAILURE
 338                 assert it.cmHandle == 'cmhandle'
 339                 assert it.registrationError == expectedError
 340                 assert it.errorText == expectedErrorText
 341             }
 342         and: 'the cm handle state is not updated to "DELETED"'
 343             0 * mockLcmEventsCmHandleStateHandler.updateCmHandleState(_, CmHandleState.DELETED)
 344         where:
 345             scenario                     | cmHandleId             | deleteListElementException                ||  expectedError           | expectedErrorText
 346             'cm-handle does not exist'   | 'cmhandle'             | new DataNodeNotFoundException("", "", "") || CM_HANDLE_DOES_NOT_EXIST | 'cm-handle does not exist'
 347             'cm-handle has invalid name' | 'cm handle with space' | new DataValidationException("", "")       || CM_HANDLE_INVALID_ID     | 'cm-handle has an invalid character(s) in id'
 348             'an unexpected exception'    | 'cmhandle'             | new RuntimeException("Failed")            || UNKNOWN_ERROR            | 'Failed'
 349     }
 350
 351     def getObjectUnderTest() {
 352         return Spy(new NetworkCmProxyDataServiceImpl(spiedJsonObjectMapper, mockDmiDataOperations,
 353             mockNetworkCmProxyDataServicePropertyHandler, mockInventoryPersistence, mockCmhandleQueries,
 354                 stubbedNetworkCmProxyCmHandlerQueryService, mockLcmEventsCmHandleStateHandler, mockCpsDataService))
 355     }
 356 }