cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/mapper/CmHandleStateMapperSpec.groovy

   1 /*
   2  * ============LICENSE_START=======================================================
   3  * Copyright (C) 2022 Nordix Foundation
   4  * ================================================================================
   5  * Licensed under the Apache License, Version 2.0 (the "License");
   6  * you may not use this file except in compliance with the License.
   7  * You may obtain a copy of the License at
   8  *
   9  *       http://www.apache.org/licenses/LICENSE-2.0
  10  *
  11  * Unless required by applicable law or agreed to in writing, software
  12  * distributed under the License is distributed on an "AS IS" BASIS,
  13  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14  * See the License for the specific language governing permissions and
  15  * limitations under the License.
  16  *
  17  * SPDX-License-Identifier: Apache-2.0
  18  * ============LICENSE_END=========================================================
  19  */
  20
  21 package org.onap.cps.ncmp.rest.mapper
  22
  23 import static org.onap.cps.ncmp.api.impl.inventory.LockReasonCategory.MODULE_SYNC_FAILED
  24
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.ncmp.api.impl.inventory.CmHandleState
  27 import org.onap.cps.ncmp.api.impl.inventory.CompositeStateBuilder
  28 import org.onap.cps.ncmp.rest.model.CmHandleCompositeState
  29 import org.onap.cps.ncmp.api.impl.inventory.DataStoreSyncState
  30 import spock.lang.Ignore
  31 import spock.lang.Specification
  32
  33 import java.time.OffsetDateTime
  34 import java.time.ZoneOffset
  35 import java.time.format.DateTimeFormatter
  36
  37 class CmHandleStateMapperSpec extends Specification {
  38
  39     def formattedDateAndTime = DateTimeFormatter.ofPattern("yyyy-MM-dd'T'HH:mm:ss.SSSZ")
  40         .format(OffsetDateTime.of(2022, 12, 31, 20, 30, 40, 1, ZoneOffset.UTC))
  41     def objectUnderTest = Mappers.getMapper(CmHandleStateMapper)
  42
  43     def 'Composite State to CmHandleCompositeState'() {
  44         given: 'a composite state model'
  45             def compositeState = new CompositeStateBuilder()
  46                 .withCmHandleState(CmHandleState.ADVISED)
  47                 .withLastUpdatedTime(formattedDateAndTime.toString())
  48                 .withLockReason(MODULE_SYNC_FAILED, 'locked details')
  49                 .withOperationalDataStores(DataStoreSyncState.SYNCHRONIZED, formattedDateAndTime).build()
  50         compositeState.setDataSyncEnabled(false)
  51         when: 'mapper is called'
  52             def result = objectUnderTest.toCmHandleCompositeStateExternalLockReason(compositeState)
  53         then: 'result is of the correct type'
  54             assert result.class == CmHandleCompositeState.class
  55         and: 'mapped result should have correct values'
  56             assert !result.dataSyncEnabled
  57             assert result.lastUpdateTime == formattedDateAndTime
  58             assert result.lockReason.reason == 'LOCKED_MISBEHAVING'
  59             assert result.lockReason.details == 'locked details'
  60             assert result.cmHandleState == 'ADVISED'
  61             assert result.dataSyncState.operational.getSyncState() != null
  62     }
  63
  64     @Ignore
  65     def 'Handling null state.'() {
  66         expect: 'converting null returns null'
  67             objectUnderTest.toDataStores(null) == null
  68     }
  69
  70     def 'Internal to External Lock Reason Mapping of #scenario'() {
  71         given: 'a LOCKED composite state with locked reason of #scenario'
  72             def compositeState = new CompositeStateBuilder()
  73                 .withCmHandleState(CmHandleState.LOCKED)
  74                 .withLockReason(lockReason, '').build()
  75         when: 'the composite state is mapped to a CMHandle composite state'
  76             def result = objectUnderTest.toCmHandleCompositeStateExternalLockReason(compositeState)
  77         then: 'the composite state contains the expected lock Reason and details'
  78             result.getLockReason().getReason() == expectedExternalLockReason
  79         where:
  80         scenario             | lockReason         || expectedExternalLockReason
  81         'MODULE_SYNC_FAILED' | MODULE_SYNC_FAILED || 'LOCKED_MISBEHAVING'
  82         'null value'         | null               || null
  83     }
  84
  85 }