cps-ncmp-rest/src/test/groovy/org/onap/cps/ncmp/rest/exceptions/NetworkCmProxyRestExceptionHandlerSpec.groovy

   1 /*
   2  *  ============LICENSE_START=======================================================
   3  *  Copyright (C) 2021 highstreet technologies GmbH
   4  *  Modifications Copyright (C) 2021-2022 Nordix Foundation
   5  *  ================================================================================
   6  *  Licensed under the Apache License, Version 2.0 (the "License");
   7  *  you may not use this file except in compliance with the License.
   8  *  You may obtain a copy of the License at
   9  *
  10  *        http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  *  Unless required by applicable law or agreed to in writing, software
  13  *  distributed under the License is distributed on an "AS IS" BASIS,
  14  *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  *  See the License for the specific language governing permissions and
  16  *  limitations under the License.
  17  *
  18  *  SPDX-License-Identifier: Apache-2.0
  19  *  ============LICENSE_END=========================================================
  20  */
  21
  22 package org.onap.cps.ncmp.rest.exceptions
  23
  24 import groovy.json.JsonSlurper
  25 import org.mapstruct.factory.Mappers
  26 import org.onap.cps.TestUtils
  27 import org.onap.cps.ncmp.api.NetworkCmProxyDataService
  28 import org.onap.cps.ncmp.api.impl.exception.DmiRequestException
  29 import org.onap.cps.ncmp.api.impl.exception.HttpClientRequestException
  30 import org.onap.cps.ncmp.api.impl.exception.ServerNcmpException
  31 import org.onap.cps.ncmp.rest.controller.NcmpRestInputMapper
  32 import org.onap.cps.ncmp.rest.controller.handlers.NcmpDatastoreResourceRequestHandlerFactory
  33 import org.onap.cps.ncmp.rest.executor.CpsNcmpTaskExecutor
  34 import org.onap.cps.ncmp.rest.mapper.CmHandleStateMapper
  35 import org.onap.cps.ncmp.rest.util.DeprecationHelper
  36 import org.onap.cps.spi.exceptions.AlreadyDefinedException
  37 import org.onap.cps.spi.exceptions.AlreadyDefinedExceptionBatch
  38 import org.onap.cps.spi.exceptions.CpsException
  39 import org.onap.cps.spi.exceptions.DataNodeNotFoundException
  40 import org.onap.cps.spi.exceptions.DataValidationException
  41 import org.onap.cps.utils.JsonObjectMapper
  42 import org.spockframework.spring.SpringBean
  43 import org.springframework.beans.factory.annotation.Autowired
  44 import org.springframework.beans.factory.annotation.Value
  45 import org.springframework.boot.test.autoconfigure.web.servlet.WebMvcTest
  46 import org.springframework.http.HttpStatus
  47 import org.springframework.http.MediaType
  48 import org.springframework.test.web.servlet.MockMvc
  49 import spock.lang.Shared
  50 import spock.lang.Specification
  51
  52 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMP
  53 import static org.onap.cps.ncmp.rest.exceptions.NetworkCmProxyRestExceptionHandlerSpec.ApiType.NCMPINVENTORY
  54 import static org.springframework.http.HttpStatus.*
  55 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.get
  56 import static org.springframework.test.web.servlet.request.MockMvcRequestBuilders.post
  57
  58 @WebMvcTest
  59 class NetworkCmProxyRestExceptionHandlerSpec extends Specification {
  60
  61     @Autowired
  62     MockMvc mvc
  63
  64     @SpringBean
  65     NetworkCmProxyDataService mockNetworkCmProxyDataService = Mock()
  66
  67     @SpringBean
  68     JsonObjectMapper stubbedJsonObjectMapper = Stub()
  69
  70     @SpringBean
  71     NcmpRestInputMapper ncmpRestInputMapper = Mappers.getMapper(NcmpRestInputMapper)
  72
  73     @SpringBean
  74     CmHandleStateMapper cmHandleStateMapper = Mappers.getMapper(CmHandleStateMapper)
  75
  76     @SpringBean
  77     CpsNcmpTaskExecutor stubbedCpsTaskExecutor = Stub()
  78
  79     @SpringBean
  80     DeprecationHelper stubbedDeprecationHelper = Stub()
  81
  82     @SpringBean
  83     NcmpDatastoreResourceRequestHandlerFactory mockedNcmpDatastoreResourceRequestHandlerFactory = Mock()
  84
  85     @Value('${rest.api.ncmp-base-path}')
  86     def basePathNcmp
  87
  88     @Value('${rest.api.ncmp-inventory-base-path}')
  89     def basePathNcmpInventory
  90
  91     def dataNodeBaseEndpointNcmp
  92     def dataNodeBaseEndpointNcmpInventory
  93
  94     @Shared
  95     def sampleErrorMessage = 'some error message'
  96     @Shared
  97     def sampleErrorDetails = 'some error details'
  98
  99     def setup() {
 100         dataNodeBaseEndpointNcmp = "$basePathNcmp/v1"
 101         dataNodeBaseEndpointNcmpInventory = "$basePathNcmpInventory/v1"
 102     }
 103
 104     def 'Get request with generic #scenario exception returns correct HTTP Status with #scenario'() {
 105         when: 'an exception is thrown by the service'
 106             setupTestException(exception, NCMP)
 107             def response = performTestRequest(NCMP)
 108         then: 'an HTTP response is returned with correct message and details'
 109             assertTestResponse(response, expectedErrorCode, expectedErrorMessage, expectedErrorDetails)
 110         where:
 111             scenario              | exception                                                        || expectedErrorDetails     | expectedErrorMessage        | expectedErrorCode
 112             'CPS'                 | new CpsException(sampleErrorMessage, sampleErrorDetails)         || sampleErrorDetails       | sampleErrorMessage          | INTERNAL_SERVER_ERROR
 113             'NCMP-server'         | new ServerNcmpException(sampleErrorMessage, sampleErrorDetails)  || null                     | sampleErrorMessage          | INTERNAL_SERVER_ERROR
 114             'NCMP-client'         | new DmiRequestException(sampleErrorMessage, sampleErrorDetails)  || null                     | sampleErrorMessage          | BAD_REQUEST
 115             'DataNode Validation' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || null                     | 'DataNode not found'        | NOT_FOUND
 116             'other'               | new IllegalStateException(sampleErrorMessage)                    || null                     | sampleErrorMessage          | INTERNAL_SERVER_ERROR
 117             'Data Node Not Found' | new DataNodeNotFoundException('myDataspaceName', 'myAnchorName') || 'DataNode not found'     | 'DataNode not found'        | NOT_FOUND
 118             'Existing entry'      | new AlreadyDefinedException('name',null)                         || 'name already exists'    | 'Already defined exception' | CONFLICT
 119             'Existing entries'    | new AlreadyDefinedExceptionBatch(["x[@id='abc']"])               || 'Check logs for details' | null                        | CONFLICT
 120     }
 121
 122     def 'Post request with exception returns correct HTTP Status.'() {
 123         given: 'the service throws data validation exception'
 124             def exception = new DataValidationException(sampleErrorMessage, sampleErrorDetails)
 125             setupTestException(exception, NCMPINVENTORY)
 126         when: 'the HTTP request is made'
 127             def response = performTestRequest(NCMPINVENTORY)
 128         then: 'an HTTP response is returned with correct message and details'
 129             assertTestResponse(response, BAD_REQUEST, sampleErrorMessage, sampleErrorDetails)
 130     }
 131
 132     def 'Failing DMI Request - passthrough scenario'() {
 133         given: 'failing DMI request'
 134             setupTestException(new HttpClientRequestException('Error Message Details NCMP', 'Bad Request from DMI', 400), NCMP)
 135         when: 'the DMI request is executed'
 136             def response = performTestRequest(NCMP)
 137         then: 'NCMP service responds with 502 Bad Gateway status'
 138             response.status == HttpStatus.BAD_GATEWAY.value()
 139         and: 'the NCMP response also contains the original DMI response details'
 140             response.contentAsString.contains('400')
 141             response.contentAsString.contains('Bad Request from DMI')
 142     }
 143
 144     def setupTestException(exception, apiType) {
 145         if (NCMP == apiType) {
 146             mockNetworkCmProxyDataService.getYangResourcesModuleReferences(*_) >> { throw exception }
 147         }
 148         mockNetworkCmProxyDataService.updateDmiRegistrationAndSyncModule(*_) >> { throw exception }
 149     }
 150
 151     def performTestRequest(apiType) {
 152         if (NCMP == apiType) {
 153             return mvc.perform(get("$dataNodeBaseEndpointNcmp/ch/testCmHandle/modules")).andReturn().response
 154         }
 155         def jsonData = TestUtils.getResourceFileContent('dmi_registration_all_singing_and_dancing.json')
 156         return mvc.perform(post("$dataNodeBaseEndpointNcmpInventory/ch").contentType(MediaType.APPLICATION_JSON).content(jsonData)).andReturn().response
 157     }
 158
 159     static void assertTestResponse(response, expectedStatus, expectedErrorMessage, expectedErrorDetails) {
 160         assert response.status == expectedStatus.value()
 161         def content = new JsonSlurper().parseText(response.contentAsString)
 162         assert content['status'].toString().contains(expectedStatus.toString())
 163         assert expectedErrorMessage == null || content['message'].toString().contains(expectedErrorMessage)
 164         assert expectedErrorDetails == null || content['details'].toString().contains(expectedErrorDetails)
 165     }
 166
 167     enum ApiType {
 168         NCMP,
 169         NCMPINVENTORY;
 170     }
 171 }